File Attachment using gateway

[#1]

Hi Everyone,

     New scenario: uploading and downloading file using SAP Netweaver Gateway .

Dont know how to solve this  one .

I like to have ur valuable suggestion and Advice for this requirement.

Thanks in Advance,

Regards,

Jibin JOy

[jibin_joy]

Please find code to get the file content if file is uploaded by Form

FUNCTION ZFM_GW_STREAM_READER.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     VALUE(IV_FILE_CONTENT) TYPE  XSTRING
*"     VALUE(IV_CONTENT_TYPE) TYPE  STRING OPTIONAL
*"  EXPORTING
*"     VALUE(EV_FILE_CONTENT) TYPE  XSTRING
*"     VALUE(ET_REQUEST_HEADER) TYPE  TIHTTPNVP
*"  EXCEPTIONS
*"      INVALID_FILE_CONTENT
*"----------------------------------------------------------------------
  CONSTANTS : lc_boundary    TYPE string VALUE 'boundary=',
              lc_new_line    TYPE string VALUE '0D0A',
              lc_srt_file    TYPE string VALUE '0D0A0D0A',
              lc_key_val_sep TYPE string VALUE ':'.
  DATA:
        lv_xlen            TYPE int4,
        lv_bolen           TYPE int4,
        lv_bvalue          TYPE string,
        lv_cufile_content  TYPE string,
        lv_bxs             TYPE string,
        lv_header          TYPE string,
        lv_content_footer  TYPE string,
        lv_content         TYPE string,
        lv_footer          TYPE string,
        lv_end_file1       TYPE string,
        lv_end_file2       TYPE string,
        lv_bxvalue         TYPE xstring,
        lt_fnd_boundary    TYPE match_result_tab,
        lt_fnd_temp        TYPE match_result_tab,
        ls_fnd_boundary    TYPE match_result,
        ls_headers         TYPE ihttpnvp,
        lv_xsheaders       TYPE xstring,
        lv_sheaders        TYPE string,
        ls_xsheaders       TYPE string,
        lt_xsheaders       TYPE TABLE OF string.

  DATA : lv_contant_final_val TYPE string,
         lv_contant_temp_val  TYPE string,
         lv_content_type      TYPE string,
         lv_content_type_xstr TYPE xstring.

  lv_cufile_content = iv_file_content.
  lv_content_type   = iv_content_type.

  " In SP5 Server the content type might be empty. So,This if condition is used to fetch
  " the file name/content type from xstring content
  IF lv_content_type IS INITIAL.
  " To split the xstring where new line occurs.
    SPLIT lv_cufile_content AT lc_new_line INTO lv_contant_final_val lv_contant_temp_val .
  " Remove two dash from the the xstring content
    SHIFT lv_contant_final_val BY 4 PLACES LEFT.
    lv_content_type_xstr = lv_contant_final_val.
    CLEAR lv_contant_final_val.
  " Convert Xstring to string
    CALL FUNCTION 'ECATT_CONV_XSTRING_TO_STRING'
      EXPORTING
        im_xstring       = lv_content_type_xstr
       IM_ENCODING       = 'UTF-8'
     IMPORTING
       EX_STRING         = lv_contant_final_val .

    " Add prefix data to the string value.
    IF sy-subrc = 0.
      CONCATENATE 'multipart/form-data; boundary=' lv_contant_final_val INTO lv_content_type.
    ENDIF.

  ENDIF.

  "Finding the Boundary value from content type
  FIND FIRST OCCURRENCE OF lc_boundary IN
     lv_content_type
     RESULTS lt_fnd_boundary.
  CHECK sy-subrc EQ 0 .
  READ TABLE lt_fnd_boundary INTO ls_fnd_boundary INDEX 1 .
  lv_bolen = ls_fnd_boundary-offset + ls_fnd_boundary-length.
  "Creating body boundary value for body with extra -- ( --<Boundary value> )
  CONCATENATE '--' lv_content_type+lv_bolen INTO lv_bvalue.
  CALL FUNCTION 'ECATT_CONV_STRING_TO_XSTRING'
    EXPORTING
      im_string  = lv_bvalue
    IMPORTING
      ex_xstring = lv_bxvalue.
  lv_bxs     = lv_bxvalue.
  lv_xlen = strlen( lv_bxs ).
  "Verify whether Boundary key in Request Body with new line (ODOA)
  IF lv_cufile_content+0(lv_xlen) EQ lv_bxvalue AND lv_cufile_content+lv_xlen(4) EQ lc_new_line.
    "Split the Header from body request from the body boundary key
    SPLIT lv_cufile_content AT lc_srt_file INTO lv_header  lv_content_footer.
    "Split the footer from body request from the body boundary key
    "footer start with two format
    "one is just <body boundary value> with new line (ODOA)
    "and another is <body boundary value>--
    CONCATENATE lc_new_line lv_bxs lc_new_line INTO lv_end_file1.
    FIND FIRST OCCURRENCE OF lv_end_file1 IN
     lv_content_footer .
    IF sy-subrc EQ 0  .
      SPLIT lv_content_footer AT lv_end_file1 INTO lv_content lv_footer.
    ELSE.
      CONCATENATE lc_new_line lv_bxs '2D2D' INTO lv_end_file2.
      CLEAR lt_fnd_temp.
      FIND FIRST OCCURRENCE OF lv_end_file2 IN
        lv_content_footer.
      IF sy-subrc EQ 0 .
        SPLIT lv_content_footer AT lv_end_file2 INTO lv_content lv_footer.
      ELSE.
        RAISE invalid_file_content. "No Ending body boundary key
      ENDIF.
    ENDIF.
    ev_file_content = lv_content.
  ELSE.
    RAISE invalid_file_content. "No starting body boundary key
  ENDIF.
  "Fetch the request information from the Request
  SPLIT lv_header AT lc_new_line INTO TABLE  lt_xsheaders.
  LOOP AT lt_xsheaders INTO ls_xsheaders FROM 2.
    lv_xsheaders = ls_xsheaders.
    CALL FUNCTION 'ECATT_CONV_XSTRING_TO_STRING'
      EXPORTING
        im_xstring = lv_xsheaders
      IMPORTING
        ex_string  = lv_sheaders.
    SPLIT lv_sheaders AT lc_key_val_sep INTO ls_headers-name  ls_headers-value .
    IF sy-subrc EQ 0.
      CONDENSE : ls_headers-name , ls_headers-value.
      APPEND ls_headers TO et_request_header.
    ENDIF.
  ENDLOOP.
ENDFUNCTION.

[thorsten_rams]

This was exactly what I needed. It works perfectly! Thanks for the code.

We are getting the file from the frontend application via put REST service and were not able to open it after storing it ("file corrupt"). After removing the WebKitFormBoundary using this function module it works!