submit statement and populating select options.

[Former Member]

Hi to all experts.

My requirement to call the program RSWUWFML2 in my zreport with selection option (task) from zreport should be populated into the standard program selection screen.I know this can be done using submit report how to populate the select options .

[Former Member]

Hi,

you can make use of addition

SUBMIT report1 WITH SELECTION-TABLE rspar_tab.

Do F1 on SUBMIT statement to see the example.

Regards,

Ankur Parab

[viquar_iqbal]

Hi

here is a small example taken from help.sap.com

Program accessed 

REPORT report1. 

DATA text TYPE c LENGTH 10. 

SELECTION-SCREEN BEGIN OF SCREEN 1100. 
  SELECT-OPTIONS: selcrit1 FOR text, 
                  selcrit2 FOR text. 
SELECTION-SCREEN END OF SCREEN 1100. 

... 



Calling program 

REPORT report2. 

DATA: text       TYPE c LENGTH 10, 
      rspar_tab  TYPE TABLE OF rsparams, 
      rspar_line LIKE LINE OF rspar_tab, 
      range_tab  LIKE RANGE OF text, 
      range_line LIKE LINE OF range_tab. 

... 

rspar_line-selname = 'SELCRIT1'. 
rspar_line-kind    = 'S'. 
rspar_line-sign    = 'I'. 
rspar_line-option  = 'EQ'. 
rspar_line-low     = 'ABAP'. 
APPEND rspar_line TO rspar_tab. 

range_line-sign   = 'E'. 
range_line-option = 'EQ'. 
range_line-low    = 'H'. 
APPEND range_line TO range_tab. 

range_line-sign   = 'E'. 
range_line-option = 'EQ'. 
range_line-low    = 'K'. 
APPEND range_line TO range_tab. 

SUBMIT report1 USING SELECTION-SCREEN '1100' 
               WITH SELECTION-TABLE rspar_tab 
               WITH selcrit2 BETWEEN 'H' AND 'K' 
               WITH selcrit2 IN range_tab 
               AND RETURN.

Hope this would resolve the issue.

Viquar Iqbal

[Former Member]

Hi,

here is the link... just go through this..

http://help.sap.com/saphelp_nw04/Helpdata/EN/9f/dba51a35c111d1829f0000e829fbfe/content.htm

Thanks

Ashu

[venkat_o]

Hi Abdul, Try this way.

DATA  : it_selection TYPE TABLE OF rsparams.
DATA  : wa_selection LIKE LINE OF it_selection.

wa_selection-selname = 'S_WERKS'.
wa_selection-kind    = 'S'.  "S-Select-options P-Parameters
wa_selection-sign    = 'I'.
wa_selection-option  = 'EQ'.
wa_selection-low     = '1000'.
APPEND wa_selection TO it_selection.

wa_selection-selname = 'S_MATNR'.
wa_selection-kind    = 'S'. "S-Select-options P-Parameters
wa_selection-sign    = 'I'.
wa_selection-option  = 'EQ'.
wa_selection-low     = '00001551'.
APPEND wa_selection TO it_selection.

SUBMIT RSWUWFML2 WITH SELECTION-TABLE it_selection AND
RETURN.

Thanks Venkat.O

[Former Member]

Hi,

The screen elements of the called program must be declaredd as ranges in the calling program as shown..

RANGES: seltab1 FOR spfli-carrid,
        seltab2 FOR spfli-connid.
          
          seltab1-sign = 'I'.
          seltab1-option = 'EQ'.
          seltab1-low = 'AA'.
          APPEND seltab1.

          seltab2-sign = 'I'.
          seltab2-option = 'EQ'.
          seltab2-low = '0017'.
          APPEND seltab2.


 SUBMIT <called prog> VIA SELECTION-SCREEN
                            WITH s_carrid IN seltab1
                            WITH s_connid IN seltab2
                            AND RETURN.

to call report RSWUWFML2.....

in zreport declare ranges as:
RANGES: seltab1 for swwwihead-wi_rh_task.
        
          seltab1-sign = 'I'.
          seltab1-option = 'EQ'.
          seltab1-low = '<value>'.
          APPEND seltab1.

          seltab2-sign = 'I'.
          seltab2-option = 'EQ'.
          seltab2-high = '<value>'.
          APPEND seltab1.

 SUBMIT RSWUWFML2 VIA SELECTION-SCREEN
                            WITH p_tasks  IN seltab1
                           AND RETURN.

                         

Hope it helps.....

Regards,

Mdi.Deeba

Edited by: Mdi.Deeba on Aug 3, 2009 10:59 AM