code for RFIDITCVL

[Former Member]

Hello,

I am working on OSS note 1090857. I am trying to find the program code for RFIDITCVL and I am not sure where to look. it looks like it did not come with this note.

I am pretty sure that our BASIS person (who has now since left) does some of this note and I am not sure where he wopuld have gotten the code.

does anyone have an idea where that code would be or does some have the code that they could cut and paste into the thread.

thanks in advance for the help

[Former Member]

Hi

I'm implemented the notes for RFIDITCVL for several customer in Italy: there are severals notes to be implemented:

0001090857 Customer/Vendor List for Italy:New Legal Requirement (2007)

0001093216 RFIDITCVL enhancement for tax data selection

0001095449 Recomandations about report RFIDITCVL for IS-U customer

0001097105 RFIDITCVL : General corrections ( refer long text)

0001100383 RFIDITCVL: Foreign BP with Italy VAT not selected

0001100629 RFIDITCVL : Incorrect file for cust/vend with same tax no (Manually).

0001102046 RFIDITCVL:Document with 2 diff tax code displayed in error

0001102898 enhancement of report RFIDITCVL, change of BAdI calls

0001102969 RFIDITCVL : General corrections II (refer long text)

0001103523 RFIDITCVL enhancement: Change of domain (Manually)

0001107782 RFIDITCVL : General corrections (refer long text)

0001108212 RFIDITCVL : General corrections ( refer long text )

0001120042 Prequisite note of 1108749 (To be implemented before impleting the note

0001120042 1108749)

0001108749 RFIDITCVL Few fields not managed for record 0 and 9

0001113575 RFIDITCVL Report corrections

0001115511 Performance Improvement : RFIDITCVL (Please read long text)

0001120216 RFIDITCVL : File format not proper

0001128154 Credit notes referred to previous yerar fields and RFIDITCVL

0001128530 RFIDITCVL : F4 help is not working.

-

---

0000715957 DMEE: Rounding of amounts

0001099387 DMEE: Rounding error

-

---

0001114130 RFIDITCVL Report corrections for lower release

Anyway some notes have SAR files have to be uploaded: in this case you need an help fpr your basis.

The note 1090857 is the first one to be implemented: here you need to create some dictionary objects manually and copy all abap code from Correction Instructions section.

Anyway before implementing the abap code from the notes you need to create the program RFIDITCVL manually.

Max

[Former Member]

Hi Timothy,

OSNote 1090857 and 1097105 needs to be applied to get the code for the program RFIDITCVL .

<REMOVED BY MODERATOR>

Regards,

Padmasri.

Edited by: Alvaro Tejada Galindo on Apr 28, 2008 12:35 PM

[Former Member]

thank you all for the responses. we have applied the four notes that the functional analyst for this project has identified. 1090857, 1097105, 1100626, and 1100383. we have done all of the work for all of the notes listed above and we run the program, we are getting the report but when we green arrow back, we are getting the "no files generated" message. if have looked at the program and it looks like it is moving lt_outtab TO err_outtab and then deleteing lt_outtab. it than calls FORM dmee_file and loops at lt_outtab. this table is blank.

has anybody run into this issue when you are ruinning the report?

I am not sure if there are more notes that I have to apply in order to get this to work. I tried to copy the program to a Z program so that I could change the table but I erroring on the field BR_BUKRS being unknown. this field is in a include DBBRFSEL but for some reason it is not reconizing it.

thanks for the help

[Former Member]

Hi

I think you haven't fill the table to aasign the tax codes to the groups for filling the fields of the file.

If the report print only the error table it means no tax code is not assigned yet.

So have you fill the table T007R to create the groups and T007K to assign the tax code to the groups?

Max

[Former Member]

Max

thanks for the reply. the program RFIDITCVL has code that looks like

LOOP AT lt_outtab WHERE user_field_4 = ''.

MOVE-CORRESPONDING lt_outtab TO err_outtab.

DELETE TABLE lt_outtab.

APPEND err_outtab.

ENDLOOP.

IF sy-batch NE 'X'.

PERFORM display_alv.

IF NOT file IS INITIAL.

PERFORM dmee_file.

FORM dmee_file .

DATA : t_count(15) TYPE n.

DATA : t_num(15) TYPE n. "1102969

LOOP AT lt_outtab.

• Note 1097105 Start

CLEAR : fl_outtab.

MOVE: lt_outtab-bukrs TO fl_outtab-bukrs, "Comp code

the table lt_outtab is empty becaue it has been deleted before the call to dmee_tree. I have created a custom program and commented the edlete statement in order to get the file to generate.

I have some questions in that

1) what is this file used for? is this a error file or the file that contains valid tax data to be sent to the gov.

2) it looks like this program would never generate the file due to the fact that the table that it is using for the data is blank

[Former Member]

Hi

The file contains all base amounts and tax amounts of all italian vendor/customer: this file has to be sent to italian goverment for fiscal controls.

The file has a certain structure and it has to be filled correctly.

Every field of this file means a certain type of amount: there are about 5 type for customer an 5 for vendor.

Every type of amount is represented by a group: the group is defined in the table T007X.

In order to fill the file the tax code and its operation key has to be assigned to a certain group: u assign it by the table T007K.

Not all tax code has to be used, so the documents using these tax code are transfered in error log (but u can exclude these tax codes by selection-screen).

Anyway only your accounting key user can say wich tax codes has to be used.

*Note 1115511 Performance END
* Fetch the group number and processing key
  IF NOT lt_outtab-mwskz IS INITIAL.
    SELECT SINGLE basgruno
    FROM t007k
    INTO (lt_outtab-user_field_4) <----------- GET THE GROUP
    WHERE land1 = t001-land1
    AND version = version
    AND mwskz = lt_outtab-mwskz
    AND ktosl = lt_outtab-ktosl.
  ENDIF.
  IF sy-subrc <> 0.
    flag_no_grp_assign = 'X'.
    err_flg = 'X'.  "1115511 Performance
  ELSE.
* Text for Tax Group
    CLEAR lt_outtab-text1.
    SELECT SINGLE text30
    FROM t007x
    INTO (lt_outtab-text1)
    WHERE land1 = t001-land1
    AND version = version
    AND stegruno = lt_outtab-user_field_4
    AND spras = sy-langu.                                   "1107782
  ENDIF.

In the piece of code above, the report fill the field USER_FIELD_4, here the report read the table T007K using the tax code ( MWSKZ) and operation (KTOSL).

I think the problem is here and probably because the table T007K is empty or filled in wrong way.

Max

[Former Member]

Max thanks for the reply

I will send this to the functional analyst to check. does you RFIDITCVL program contain the same logic as the piece that is sent. does you program delete the outtab file and then use it in the DMEE_TREE perform

[Former Member]

Hi

Yes of course... I hope.

The logic should be the same, perhaps your release is different of mine (4.6C). Anyway your code for deleting the records where field user_field_4 is blank and transfering it to the error table should be old.

The note 1097105 should be replace that piece of code

* Note 1097105 Start
*  CLEAR err_outtab.
*  REFRESH err_outtab.
*  LOOP AT lt_outtab WHERE user_field_4 = ''.
*    MOVE-CORRESPONDING lt_outtab TO err_outtab.
*    DELETE TABLE lt_outtab.
*    APPEND err_outtab.
*  ENDLOOP.
* Note 1097105 End

In my version the report move the record to the error table in routine scrivi-fileout:

FORM scrivi-fileout.
  CLEAR : lt_outtab, land1.
  Data : err_flg.  "1115511 Performance

*  t-ivabt = t-ivabt + t-navhw.         "SAPINEW

  ctr-write = ctr-write + 1.

  MOVE : bkpf-bukrs      TO lt_outtab-bukrs,
         bkpf-belnr      TO lt_outtab-belnr,
         bkpf-budat      TO lt_outtab-budat,
         bkpf-bldat      TO lt_outtab-bldat,
         wgjahr          TO lt_outtab-gjahr,
         wkonto          TO lt_outtab-nummr,
         t-mwskz         TO lt_outtab-mwskz,
         t-ktosl         TO lt_outtab-ktosl,
         t001-waers      TO lt_outtab-hwaer,
         t-satz          TO lt_outtab-psatz,
         t-netto         TO lt_outtab-hwbas,
         t-ivabt         TO lt_outtab-hwsteaa,
         t-navhw         TO lt_outtab-hwnaf,
         wszart          TO lt_outtab-mwart.

* Fetch the business partner details
* Note 1102969 Start
  IF cpd-kz EQ 1.
    SELECT SINGLE * FROM bsec
    WHERE bukrs = lt_outtab-bukrs
    AND   belnr = bkpf-belnr
    AND   gjahr = lt_outtab-gjahr.
    IF sy-subrc = 0.
      MOVE: bsec-stcd1 TO lt_outtab-stcd1,
            bsec-stcd2 TO lt_outtab-stcd2,
            bsec-land1 TO land1,
            bsec-name1 TO lt_outtab-user_field_3,
            bsec-name2 TO lt_outtab-user_field_b.
    ENDIF.
  ELSEIF NOT lt_outtab-nummr IS INITIAL.
    IF wszart EQ 'K' AND cpd-kz NE 1.
      SELECT SINGLE * FROM lfa1
      WHERE lifnr = lt_outtab-nummr.
      IF sy-subrc EQ 0.
        IF lfa1-stcd2 IS INITIAL
        AND NOT lfa1-fiskn IS INITIAL.
          SELECT SINGLE * FROM lfa1
          WHERE lifnr = lfa1-fiskn.
        ENDIF.
        MOVE: lfa1-stcd1 TO lt_outtab-stcd1,
              lfa1-stcd2 TO lt_outtab-stcd2,
              lfa1-land1 TO land1,
              lfa1-name1 TO lt_outtab-user_field_3,
              lfa1-name2 TO lt_outtab-user_field_b.
      ENDIF.
    ELSEIF wszart EQ 'D' AND cpd-kz NE 1.
      SELECT SINGLE * FROM kna1
      WHERE kunnr = lt_outtab-nummr.
      IF sy-subrc EQ 0.
        IF kna1-stcd2 IS INITIAL
        AND NOT kna1-fiskn IS INITIAL.
          SELECT SINGLE * FROM kna1
          WHERE kunnr = kna1-fiskn.                         "1108212
        ENDIF.
        MOVE: kna1-stcd1 TO lt_outtab-stcd1,
              kna1-stcd2 TO lt_outtab-stcd2,
              kna1-land1 TO land1,
              kna1-name1 TO lt_outtab-user_field_3,
              kna1-name2 TO lt_outtab-user_field_b.
      ENDIF.
    ENDIF.
  ENDIF.
* Note 1102969 End
* Note 1100383 Start
* Check for foreign business partner
* having Italian VAT
  IF t001-land1 NE land1.
* Note 1108212 Start
    IF t001-land1 NE 'IT'.
      SELECT SINGLE * FROM t001n
      WHERE bukrs = lt_outtab-bukrs
      AND   land1 = 'IT'.
      IF sy-subrc EQ 0.
        t001-stceg = t001n-stceg.
        t001-land1 = 'IT'.
      ENDIF.
    ENDIF.
* Note 1108212 End
    CLEAR stceg.
    IF lt_outtab-mwart EQ 'K'.
      SELECT SINGLE stceg INTO stceg
      FROM lfas
      WHERE lifnr = lt_outtab-nummr
      AND   land1 = t001-land1.
    ELSEIF lt_outtab-mwart EQ 'D'.
      SELECT SINGLE stceg INTO stceg
      FROM knas
      WHERE kunnr = lt_outtab-nummr
      AND   land1 = t001-land1.
    ENDIF.
    IF sy-subrc EQ 0.
      lt_outtab-stcd2 = stceg+2(16).
    ELSE.
      CHECK t001-land1 = land1.
    ENDIF.
  ENDIF.
* Note 1100383 End
  IF p_stcd1 EQ '' AND lt_outtab-stcd2 IS INITIAL.
    CHECK 1 = 2.
  ELSEIF p_stcd1 = 'X' AND lt_outtab-stcd2 IS INITIAL
                       AND lt_outtab-stcd1 IS INITIAL.
    CHECK 1 = 2.
  ENDIF.

*Note 1115511 Performance START
  err_flg = ''.
*Note 1115511 Performance END
* Fetch the group number and processing key
  IF NOT lt_outtab-mwskz IS INITIAL.
    SELECT SINGLE basgruno
    FROM t007k
    INTO (lt_outtab-user_field_4)
    WHERE land1 = t001-land1
    AND version = version
    AND mwskz = lt_outtab-mwskz
    AND ktosl = lt_outtab-ktosl.
  ENDIF.
  IF sy-subrc <> 0.
    flag_no_grp_assign = 'X'.
    err_flg = 'X'.  "1115511 Performance
  ELSE.
* Text for Tax Group
    CLEAR lt_outtab-text1.
    SELECT SINGLE text30
    FROM t007x
    INTO (lt_outtab-text1)
    WHERE land1 = t001-land1
    AND version = version
    AND stegruno = lt_outtab-user_field_4
    AND spras = sy-langu.                                   "1107782
  ENDIF.
  lt_outtab-name1 = adrc-name1.
  lt_outtab-name2 = adrc-name2.
  lt_outtab-user_field_1 = adrc-city1.
  lt_outtab-user_field_2 = adrc-region.
  lt_outtab-stceg = t001-stceg.
  lt_outtab-user_field_a = t001z-paval(40).
  lt_outtab-hwste = lt_outtab-hwsteaa + lt_outtab-hwnaf.
  lt_outtab-hwgross = lt_outtab-hwbas + lt_outtab-hwste.
*Note 1115511 Performance START
  if err_flg = 'X'.
    APPEND lt_outtab to err_outtab.
  else.
    APPEND lt_outtab.
  endif.
*Note 1115511 Performance END
ENDFORM.                    "SCRIVI-FILEOUT

Are you sure you've implemented all notes?

If you want I send you my version.

Max

[Former Member]

Max

the problem has been solved. the fuunctional analyst had the t007k table set correctly but with the vat codes were not set up in the client. He has since set up the client correctly and the file is being generated.

I want to thank you for all of time that you spent with me and all of the advice that you shared with me in clearing this up.