- SAP Managed Tags
Looks like the WebAs 7.0 Sneak Preview has been released. You can download it in the Dowload Section of SDN under the WebAs.
Regards,
Rich Heilman
- SAP Managed Tags
Yep, you will need a good connection to pull it down, but not impossible.
Regards,
Rich Heilman
- SAP Managed Tags
You can download it. You need to have the lastest SAP gui patches for 6.40 as well as a WebAs 7.0 engine. You can test the editor out in prior releases using Thomas's code, but you must have all of the sap gui patches for 6.40.
/people/thomas.jung3/blog/2005/08/03/new-abap-editor-too-good-to-wait-for
I have converted Thomas's code to a cut/paste solution using only an ABAP report program. Just cut/paste this code in a report program. Yes, you still need the lasted gui 6.40 and newest patches.
report zrich_0002.
*---------------------------------------------------------------------*
* CLASS lcl_abap_editor DEFINTION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class lcl_abap_editor definition inheriting from cl_gui_control.
public section.
methods: constructor importing value(style) type i
parent type ref to cl_gui_container
lifetime type i
name type string
exceptions
error_cntl_create
error_cntl_init
error_cntl_link
error_dp_create
gui_type_not_supported,
add_empty_doc importing str_name type string
b_readonly type i
str_extension type string
str_tooltip type string
exceptions
unable_to_set_doc.
endclass.
*---------------------------------------------------------------------*
* CLASS lcl_abap_editor IMPLEMENTATION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class lcl_abap_editor implementation.
method constructor.
data prog_id(80).
if parent is initial.
raise error_cntl_create.
endif.
class cl_gui_cfw definition load.
* assign prog_id to get the frontend specific control
if not activex is initial.
prog_id = 'SAPGUI.AbapEditor.1'.
elseif not javabean is initial.
raise gui_type_not_supported.
endif.
if prog_id is initial.
raise gui_type_not_supported.
endif.
* Set the window styles of the control when style parameter was not
* set with constructor call.
* For more information on the styles see WIN32 SDK
if style is initial.
* otherwise the control would be invisible and the mistake would be
* hard to find
style = cl_gui_control=>ws_visible
+ cl_gui_control=>ws_child
+ cl_gui_control=>ws_clipsiblings.
endif.
* Create the control
call method super->constructor
exporting
clsid = prog_id
shellstyle = style
parent = parent
lifetime = lifetime
name = name
exceptions
others = 1.
call method cl_gui_cfw=>flush
exceptions
cntl_system_error = 1
cntl_error = 2
others = 3.
if sy-subrc <> 0.
raise error_cntl_create.
endif.
* register instance at framework
call method cl_gui_cfw=>subscribe
exporting
shellid = h_control-shellid
ref = me
exceptions
others = 1.
if sy-subrc <> 0.
raise error_cntl_create.
endif.
endmethod.
method add_empty_doc.
call method call_method
exporting
method = 'AddEmptyDoc'
p_count = 4
p1 = str_name
p2 = b_readonly
p3 = str_extension
p4 = str_tooltip
exceptions
cntl_system_error = 1
cntl_error = 2
others = 3.
if sy-subrc <> 0.
raise unable_to_set_doc.
endif.
endmethod.
endclass.
data: docking_container type ref to cl_gui_docking_container,
abap_editor type ref to lcl_abap_editor,
repid type syrepid.
parameters: p_check type c.
at selection-screen output.
repid = sy-repid.
check docking_container is initial.
create object docking_container
exporting repid = repid
dynnr = sy-dynnr
side = docking_container->dock_at_left
extension = 1500.
create object abap_editor
exporting
style = 0
parent = docking_container
lifetime = space
name = space.
if sy-subrc <> 0.
endif.
call method abap_editor->add_empty_doc
exporting
str_name = 'Test Program'
b_readonly = '0' "Edit Mode
str_extension = 'ABAP'
str_tooltip = 'Tooltip'.
if sy-subrc <> 0.
endif.
call method cl_gui_cfw=>flush( ).Regards,
Rich Heilman
Bluesky