Bluesky
- SAP Managed Tags
Hi Sylviani
This most likely occurred as the query is created in the 'Standard Query Area' and the generated ABAP program linked to a transaction code. so when the query is exported to a pc/laptop and imported into a QA system the target system, so when running the transaction code, the system cannot find the program.
Basically, a query should not be accessed using the name of the report generated by it (for example, by 'submit') because the name may change (for example, when upgrading from Release 3.x to 4.x), and also because the code generated may not necessarily correspond to the current query definition (the code may not be available in the system at all, even though the definition of the query is available in the system).
Below is a comparison between a Development and Production system, for the SAP Query, the generated program names:
The program is broken down as follows:
- 1st 2 characters indicate it is a query, i.e. ‘AQ’
- 2nd 2 characters indicate a generated ID, i.e. ‘CS’ = DEV and ‘IC’ = PRD (note global queries use a different identifier)
- 3rd group of characters indicates the User Group with ‘=’ included to pad the group, i.e. ‘ZSD=========’
- 4th group of characters indicates the Query Name, i.e. ‘ZSDCONTLINKORD’
The solution is to apply the guideline as given in the SAP OSS Note 393160 - SAP Query: Using queries.
Basically it can be broken down into 4 steps:
1. Create a custom table
2. Create a custom program
*&---------------------------------------------------------------------*
*& Report ZBW_GEN_CALL_QUERY
*&
*&---------------------------------------------------------------------*
*&
*& Version 2.0
*&---------------------------------------------------------------------*
REPORT ZBW_GEN_CALL_QUERY.
INCLUDE RSAQCOMC.
INCLUDE RSAQCOM1.
* Reference to tables
TABLES: ZBW_GEN_QRY.
* Declaration of internal tables
DATA: BEGIN OF itab_QUERY OCCURS 0.
INCLUDE STRUCTURE ZBW_GEN_QRY.
DATA: END OF itab_QUERY.
* Declaration of variables
DATA: p_wsid TYPE C LENGTH 1,
p_ugroup TYPE bgname,
p_query TYPE quname,
p_vari TYPE vari.
* call via IQAPI_QCALL (as of Release 6.10 )
DATA: qid TYPE AQLQID.
* Get the query linked to the transaction
SELECT *
INTO CORRESPONDING FIELDS OF TABLE itab_QUERY
FROM ZBW_GEN_QRY
WHERE ZTCODE = SY-TCODE.
IF SY-SUBRC = 0.
READ TABLE itab_QUERY
WITH KEY ZTCODE = SY-TCODE.
IF SY-SUBRC = 0.
CASE itab_QUERY-ZWSID.
* Global Query Area
WHEN 'X'.
qid-workspace = ws_global.
p_wsid = itab_QUERY-ZWSID.
p_ugroup = itab_QUERY-ZUGROUP.
p_query = itab_QUERY-ZQUERY.
IF itab_QUERY-ZVARI = ''.
p_vari = SPACE.
ELSE.
p_vari = itab_QUERY-ZVARI.
ENDIF.
* Standard Query Area
WHEN OTHERS.
qid-workspace = ws_standard.
p_wsid = SPACE.
p_ugroup = itab_QUERY-ZUGROUP.
p_query = itab_QUERY-ZQUERY.
IF itab_QUERY-ZVARI = ''.
p_vari = SPACE.
ELSE.
p_vari = itab_QUERY-ZVARI.
ENDIF.
ENDCASE.
ENDIF.
ENDIF.
* User Group and Query to QID
qid-usergroup = p_ugroup.
qid-query = p_query.
* Call the Query
CALL FUNCTION 'IQAPI_QCALL'
EXPORTING
OLD_QID = qid
VARIANT = p_vari
EXCEPTIONS
OTHERS = 1.
IF SY-SUBRC <> 0.
MESSAGE ID sy-msgid TYPE 'I' number sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
CLEAR: itab_QUERY.
REFRESH: itab_QUERY.
FREE: itab_QUERY.
3. Create a custom transaction code
4. Link the custom transaction to the custom program
Then maintain the custom table
- Insert with the transaction code that will call the SAP Query
- Mark whether the query is from the Global or Standard Query Area
- ‘X’ = Global
- ‘ ‘ = Standard
- Indicate which user group the query is in
- Indicate the query name
- Optionally if a variant is to be used this can be also maintained
Example:
and then execute the custom transaction code.
So far we have been using this solution for the last 5 years.
Regards
Derek
| User | Count |
|---|---|
| 3 | |
| 1 | |
| 1 | |
| 1 | |
| 1 | |
| 1 | |
| 1 | |
| 1 | |
| 1 | |
| 1 |
