I am using a standard search help to display all existing ALV variants for a report. However I only want the user to be able to see variants created by him, therefore I need to restrict the selection displayed in the search help. Since I do not want to modify the search help by adding a search help exit, I manipulate the search help interface before I call it:
*&---------------------------------------------------------------------*
*& Form GET_VARIANT_LIST
*&---------------------------------------------------------------------*
FORM get_variant_list CHANGING xy_vari TYPE slis_vari.
DATA: lt_return TYPE TABLE OF ddshretval,
ls_return TYPE ddshretval,
ls_shlp TYPE shlp_descr,
ls_if TYPE ddshiface.
* we need to call the F4 help and make sure that we pass in the
* report name and the current user name => get search help attributes
CALL FUNCTION 'F4IF_GET_SHLP_DESCR'
EXPORTING
shlpname = gc_search_help
IMPORTING
shlp = ls_shlp.
* now we have to set the input values
READ TABLE ls_shlp-interface
INTO ls_if
WITH KEY shlpfield = gc_field_report.
IF sy-subrc EQ 0.
ls_if-value = sy-repid.
MODIFY ls_shlp-interface
FROM ls_if
INDEX sy-tabix
TRANSPORTING value.
ENDIF.
READ TABLE ls_shlp-interface
INTO ls_if
WITH KEY shlpfield = gc_field_user.
IF sy-subrc EQ 0.
ls_if-value = sy-uname.
MODIFY ls_shlp-interface
FROM ls_if
INDEX sy-tabix
TRANSPORTING value.
ENDIF.
* set the field for the return value
READ TABLE ls_shlp-interface
INTO ls_if
WITH KEY shlpfield = gc_field_variant.
IF sy-subrc EQ 0.
ls_if-valfield = gc_field_variant.
MODIFY ls_shlp-interface
FROM ls_if
INDEX sy-tabix
TRANSPORTING valfield.
ENDIF.
* Now call the search help
CALL FUNCTION 'F4IF_START_VALUE_REQUEST'
EXPORTING
shlp = ls_shlp
TABLES
return_values = lt_return.
* get the value the user selected and pass it back
READ TABLE lt_return INTO ls_return INDEX 1.
IF sy-subrc EQ 0.
xy_vari = ls_return-fieldval.
ENDIF.
ENDFORM. " GET_VARIANT_LIST
That way you can restrict any input parameter that is passed into the search help.
Hope that helps,
Michael
Bluesky
