output-script

[Former Member]

Hi,

How to view out put for script.I am using f.27 when I execute I am getting spool req number.When I use t.code SP01.I am not getting.How to view print view.

Thanks

[Former Member]

HI rahul,

to get the print preview from script--> utilities --> printing test

then give the output device lp01 or locl depends on ur default printer.

or execute the driver program and give the printer details as lp01 or locl and print priview...

[Former Member]

Create a new program and use this code...<b>Not my code and I found it browsing around.</b>

PARAMETERS:
  SPOOLNO LIKE TSP01-RQIDENT,
  DOWNLOAD AS CHECKBOX DEFAULT 'X',
  P_FILE LIKE RLGRAP-FILENAME DEFAULT 'C:tempfile.pdf'. "#EC NOTEXT
DATA OTF LIKE ITCOO OCCURS 100 WITH HEADER LINE.
DATA CANCEL.
DATA PDF LIKE TLINE OCCURS 100 WITH HEADER LINE.
DATA DOCTAB LIKE DOCS OCCURS 1 WITH HEADER LINE.
DATA: NUMBYTES TYPE I,
      ARC_IDX LIKE TOA_DARA,
      PDFSPOOLID LIKE TSP01-RQIDENT,
      JOBNAME LIKE TBTCJOB-JOBNAME,
      JOBCOUNT LIKE TBTCJOB-JOBCOUNT,
      IS_OTF.
DATA: CLIENT LIKE TST01-DCLIENT,
      NAME LIKE TST01-DNAME,
      OBJTYPE LIKE RSTSTYPE-TYPE,
      TYPE LIKE RSTSTYPE-TYPE.
TABLES: TSP01.

SELECT SINGLE * FROM TSP01 WHERE RQIDENT = SPOOLNO.
IF SY-SUBRC <> 0.
  WRITE: / 'Spoolauftrag existiert nicht'(003)
          COLOR COL_NEGATIVE.
  EXIT.
ENDIF.
CLIENT = TSP01-RQCLIENT.
NAME   = TSP01-RQO1NAME.
CALL FUNCTION 'RSTS_GET_ATTRIBUTES'
       EXPORTING
            AUTHORITY     = 'SP01'
            CLIENT        = CLIENT
            NAME          = NAME
            PART          = 1
       IMPORTING
*           CHARCO        =
*           CREATER       =
*           CREDATE       =
*           DELDATE       =
*           MAX_CREDATE   =
*           MAX_DELDATE   =
*           NON_UNIQ      =
*           NOOF_PARTS    =
*           RECTYP        =
*           SIZE          =
*           STOTYP        =
            TYPE          = TYPE
            OBJTYPE       = OBJTYPE
       EXCEPTIONS
            FB_ERROR      = 1
            FB_RSTS_OTHER = 2
            NO_OBJECT     = 3
            NO_PERMISSION = 4.
IF OBJTYPE(3) = 'OTF'.
  IS_OTF = 'X'.
ELSE.
  IS_OTF = SPACE.
ENDIF.
IF IS_OTF = 'X'.
  CALL FUNCTION 'CONVERT_OTFSPOOLJOB_2_PDF'
      EXPORTING
        SRC_SPOOLID                    = SPOOLNO
        NO_DIALOG                      = ' '
*       DST_DEVICE                     =
*       PDF_DESTINATION                =
      IMPORTING
        PDF_BYTECOUNT                  = NUMBYTES
        PDF_SPOOLID                    = PDFSPOOLID
*       OTF_PAGECOUNT                  =
        BTC_JOBNAME                    = JOBNAME
        BTC_JOBCOUNT                   = JOBCOUNT
      TABLES
        PDF                            = PDF
      EXCEPTIONS
        ERR_NO_OTF_SPOOLJOB            = 1
        ERR_NO_SPOOLJOB                = 2
        ERR_NO_PERMISSION              = 3
        ERR_CONV_NOT_POSSIBLE          = 4
        ERR_BAD_DSTDEVICE              = 5
        USER_CANCELLED                 = 6
        ERR_SPOOLERROR                 = 7
        ERR_TEMSEERROR                 = 8
        ERR_BTCJOB_OPEN_FAILED         = 9
        ERR_BTCJOB_SUBMIT_FAILED       = 10
        ERR_BTCJOB_CLOSE_FAILED        = 11.
  CASE SY-SUBRC.
  WHEN 0.
    WRITE: / 'Funktion CONVERT_OTFSPOOLJOB_2_PDF erfolgreich'(001)
          COLOR COL_POSITIVE.
  WHEN 1.
    WRITE: / 'Kein OTF- und kein ABAP-Spoolauftrag'(002)
          COLOR COL_NEGATIVE.
    EXIT.
  WHEN 2.
    WRITE: / 'Spoolauftrag existiert nicht'(003)
          COLOR COL_NEGATIVE.
    EXIT.
  WHEN 3.
    WRITE: / 'Keine Berechtigung zum Lesen Spoolauftrag'(004)
          COLOR COL_NEGATIVE.
    EXIT.
  WHEN OTHERS.
    WRITE: / 'Fehler bei Funktion CONVERT_OTFSPOOLJOB_2_PDF'(005)
              COLOR COL_NEGATIVE.
    EXIT.
  ENDCASE.
ELSE.
  CALL FUNCTION 'CONVERT_ABAPSPOOLJOB_2_PDF'
      EXPORTING
        SRC_SPOOLID                    = SPOOLNO
        NO_DIALOG                      = ' '
*       DST_DEVICE                     =
*       PDF_DESTINATION                =
      IMPORTING
        PDF_BYTECOUNT                  = NUMBYTES
        PDF_SPOOLID                    = PDFSPOOLID
*       LIST_PAGECOUNT                 =
        BTC_JOBNAME                    = JOBNAME
        BTC_JOBCOUNT                   = JOBCOUNT
      TABLES
        PDF                            = PDF
      EXCEPTIONS
        ERR_NO_ABAP_SPOOLJOB           = 1
        ERR_NO_SPOOLJOB                = 2
        ERR_NO_PERMISSION              = 3
        ERR_CONV_NOT_POSSIBLE          = 4
        ERR_BAD_DESTDEVICE             = 5
        USER_CANCELLED                 = 6
        ERR_SPOOLERROR                 = 7
        ERR_TEMSEERROR                 = 8
        ERR_BTCJOB_OPEN_FAILED         = 9
        ERR_BTCJOB_SUBMIT_FAILED       = 10
        ERR_BTCJOB_CLOSE_FAILED        = 11.
  CASE SY-SUBRC.
  WHEN 0.
    WRITE: / 'Funktion CONVERT_ABAPSPOOLJOB_2_PDF erfolgreich'(006)
          COLOR COL_POSITIVE.
  WHEN 1.
    WRITE: / 'Kein OTF- und kein ABAP-Spoolauftrag'(002)
          COLOR COL_NEGATIVE.
    EXIT.
  WHEN 2.
    WRITE: / 'Spoolauftrag existiert nicht'(003)
          COLOR COL_NEGATIVE.
    EXIT.
  WHEN 3.
    WRITE: / 'Keine Berechtigung zum Lesen Spoolauftrag'(004)
          COLOR COL_NEGATIVE.
    EXIT.
  WHEN OTHERS.
    WRITE: / 'Fehler bei Funktion CONVERT_ABAPSPOOLJOB_2_PDF'(007)
              COLOR COL_NEGATIVE.
    EXIT.
  ENDCASE.
ENDIF.
*************** download PDF file ***********
CHECK DOWNLOAD = 'X'.
IF NOT ( JOBNAME IS INITIAL ).
  WRITE: / 'Konvertierung per Hintergrundjob'(008)
            COLOR COL_NORMAL,
            JOBNAME, JOBCOUNT.
  EXIT.
ENDIF.
CALL FUNCTION 'DOWNLOAD'
     EXPORTING
          BIN_FILESIZE            = NUMBYTES
          FILENAME                = P_FILE
          FILETYPE                = 'BIN'
     IMPORTING
          ACT_FILENAME            = P_FILE
          FILESIZE                = NUMBYTES
          CANCEL                  = CANCEL
     TABLES
          DATA_TAB                = PDF.
IF CANCEL = SPACE.
  WRITE: / NUMBYTES, 'Bytes heruntergeladen in Datei'(009), P_FILE.
ENDIF.

Pass the Spool Number and it should build a PDF -;)

Greetings,

Blag.

[Former Member]

Hi,

yes you are right.I got printview in pdf format.

[Former Member]

Glad to help you Rahul -:)

Greetings,

Blag.

[Former Member]

hi rahul,

if you want to see preview for testing purpose then in debug mode you can change the destination and set the preview = X in print parameters....have you tried in this way.