find OBJ_ID

[Former Member]

Hi,

How i can find the object OBJ_ID to Fm ECATT_OBJ_PAR_VALS_GET?

Regards

[Former Member]

Hi,

How i can find the object OBJ_ID to Fm ECATT_OBJ_PAR_VALS_GET?

Regards

[uwe_schieferstein]

Hello Michael

If you had just looked around the function group ECATT_API you would have found the solution yourself.

*&---------------------------------------------------------------------*
*& Report  ZUS_SDN_ECATT_READ_RUNTIME
*&
*&---------------------------------------------------------------------*
*& Thread: find OBJ_ID
*& <a class="jive_macro jive_macro_thread" href="" __jive_macro_name="thread" modifiedtitle="true" __default_attr="1204557"></a>
*&---------------------------------------------------------------------*

REPORT  zus_sdn_ecatt_read_runtime.

DATA: gs_key            TYPE etobj_key2,
      gs_obj            TYPE etapi_obj,
      gt_return         TYPE bapirettab,
      gd_varid          TYPE etvar_id,
      gd_par            TYPE etpar_name,
      gt_vari_values    TYPE etpar_vari_streams_tabtype,
      gs_values         LIKE LINE OF gt_vari_values,
      gs_stream         LIKE LINE OF gs_values-par_values_streams.

START-OF-SELECTION.

  BREAK-POINT.

  gs_key-type = 'ECTD'. " test data container
  gs_key-name = 'ZUS_SDN_SU01_CHANGE_USER'.
*  gs_key-VERSION =

  CALL FUNCTION 'ECATT_OBJ_LOAD'
    EXPORTING
      is_key                = gs_key
*     I_MAINTAIN_MODE       = 'SHOW'
    IMPORTING
      es_object_key         = gs_obj
    TABLES
      return                = gt_return.

  MESSAGE gs_obj-obj_id TYPE 'I'.  " NOTE: This is a runtime ID.


  gd_varid = '100228_MS'.
  gd_par   = 'ID_BNAME'.

  CALL FUNCTION 'ECATT_OBJ_PAR_VALS_GET'
    EXPORTING
      is_key                  = gs_obj
      i_var_id                = gd_varid
      i_par_name              = gd_par
*     I_PATH                  =
    IMPORTING
      et_variant_values       = gt_vari_values
    TABLES
      return                  = gt_return.

  BREAK-POINT.
  LOOP AT gt_vari_values INTO gs_values.
    LOOP AT gs_values-par_values_streams INTO gs_stream.
      WRITE: / gs_stream-pname,
                gs_stream-ptyp,
                gs_stream-pindex,
                gs_stream-value,
                gs_stream-val_type.
    ENDLOOP.
  ENDLOOP.


END-OF-SELECTION.

Regards

Uwe