dynamic variant for report

[Former Member]

Hi,

I want to create a dynamic variant for my report. Every time when user inputs some data on the selection screen, I want to create a variant.

Regards,

Sudhakar Rayala

[former_member156446]

Check[ this WIKI|http://wiki.sdn.sap.com/wiki/x/0oDZAg] if this help's you..

[Former Member]

Hi Mahi,

There are many links in SDN which will be answering your query,

out of which one of them is this link below which will lead you to create

the dynamic variants.

/message/5514554#5514554 [original link is broken]

Cheers!!

VEnk@

[venkat_o]

Hi Sudhakar, <li> Use RS_CREATE_VARIANT function module to create variant dynamically. <li>Try this way.

   REPORT  ZTEST_PROGRAM.
   PARAMETERS :P_NAME   TYPE CHAR15.

   AT SELECTION-SCREEN.
     DATA:
          G_REPORT      LIKE  RSVAR-REPORT VALUE SY-REPID,
          G_VARIANT     LIKE  RSVAR-VARIANT VALUE 'TEST_VAR1',
          G_VARI_DESC   LIKE  VARID.
     DATA:
          IT_RSPARAMS   TYPE STANDARD TABLE OF  RSPARAMS,
          WA_RSPARAMS   LIKE LINE OF IT_RSPARAMS,
          IT_VARI_TEXT  TYPE STANDARD TABLE OF VARIT,
          WA_VARI_TEXT  LIKE LINE OF IT_VARI_TEXT.
     IF SY-UCOMM = 'ONLI'."Variant is created when you press EXECUTE button on selection-screen.
       WA_VARI_TEXT-LANGU     =  'EN'.
       WA_VARI_TEXT-REPORT    =  G_REPORT.
       WA_VARI_TEXT-VARIANT   =  G_VARIANT.
       WA_VARI_TEXT-VTEXT     =  'Test variant'.
       APPEND WA_VARI_TEXT TO IT_VARI_TEXT.
       CLEAR WA_VARI_TEXT.

       G_VARI_DESC-REPORT     = G_REPORT.
       G_VARI_DESC-VARIANT    =  G_VARIANT.
       G_VARI_DESC-ENVIRONMNT = 'A'.
       G_VARI_DESC-AEDAT      = SY-DATUM.
       G_VARI_DESC-AETIME     = SY-UZEIT.

       WA_RSPARAMS-SELNAME    = 'P_NAME'.
       WA_RSPARAMS-KIND       = 'P'.
       WA_RSPARAMS-LOW        = P_NAME.
       APPEND WA_RSPARAMS TO IT_RSPARAMS.
       CLEAR WA_RSPARAMS.

       CALL FUNCTION 'RS_CREATE_VARIANT'
         EXPORTING
           CURR_REPORT   = G_REPORT
           CURR_VARIANT  = G_VARIANT
           VARI_DESC     = G_VARI_DESC
         TABLES
           VARI_CONTENTS = IT_RSPARAMS
           VARI_TEXT     = IT_VARI_TEXT.
     ENDIF.

   START-OF-SELECTION.
     WRITE 'Variant created'.

Thanks Venkat.O