Report

[Former Member]

Can someone please let me know the difference between hierarchial report and non-hierarchial report, preferably with some examples.

Thanks.

[Former Member]

HI.

Pls ref this prog for non-hierarchial :BCALV_GRID_DEMO

or REPORT Z_ALV_SIMPLE_EXAMPLE_WITH_ITAB .

************************************************************************

*Simple example to use ALV and to define the ALV data in an internal

*table

************************************************************************

• Martin Schlegel, BearingPoint, December 2004

*

• Thanks to Madhusudhan Sonee and Rama Krishna Kommineni for testing

• and feedback

*

************************************************************************

************************************************************************

*For a very long time, people gave me the feeling that ALV is a

*complicated tool that is difficult to understand and to use.

*Lately I had to use it and I discovered that ALV is easy to use and

*saves a lot of work:

*ALV will generate the column headings on its own, so one does not need

*to work on headlines and transalation.

*ALV allows the user to select the columns he wants to see, so the user

*does not need to contact a developer for every change he likes to have.

*ALV allows the user to create his own sums, so …

*ALV has a simple way to work with internal tables.

*If you really want to save time, use ALV instead of write!

************************************************************************

*

*Please take 30 minutes to explore the following example and see how

*easy it is to use ALV!

*

************************************************************************

*data definition

tables:

marav. "Table MARA and table MAKT

----

---

• Data to be displayed in ALV

• Using the following syntax, REUSE_ALV_FIELDCATALOG_MERGE can auto-

• matically determine the fieldstructure from this source program

Data:

begin of imat occurs 100,

matnr like marav-matnr, "Material number

maktx like marav-maktx, "Material short text

matkl like marav-matkl, "Material group (so you can test to make

" intermediate sums)

ntgew like marav-ntgew, "Net weight, numeric field (so you can test to

"make sums)

gewei like marav-gewei, "weight unit (just to be complete)

end of imat.

----

---

• Other data needed

• field to store report name

data i_repid like sy-repid.

• field to check table length

data i_lines like sy-tabix.

----

---

• Data for ALV display

TYPE-POOLS: SLIS.

data int_fcat type SLIS_T_FIELDCAT_ALV.

----

---

select-options:

s_matnr for marav-matnr matchcode object MAT1.

----

---

start-of-selection.

• read data into table imat

select * from marav

into corresponding fields of table imat

where

matnr in s_matnr.

• Check if material was found

clear i_lines.

describe table imat lines i_lines.

if i_lines lt 1.

• Using hardcoded write here for easy upload

write: /

'No materials found.'.

exit.

endif.

end-of-selection.

----

---

*

• Now, we start with ALV

*

----

---

*

*

• To use ALV, we need a DDIC-structure or a thing called Fieldcatalogue.

• The fieldcatalouge can be generated by FUNCTION

• 'REUSE_ALV_FIELDCATALOG_MERGE' from an internal table from any

• report source, including this report.

• The only problem one might have is that the report and table names

• need to be in capital letters. (I had it )

*

*

----

---

• Store report name

i_repid = sy-repid.

• Create Fieldcatalogue from internal table

CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'

EXPORTING

I_PROGRAM_NAME = i_repid

I_INTERNAL_TABNAME = 'IMAT' "capital letters!

I_INCLNAME = i_repid

CHANGING

CT_FIELDCAT = int_fcat

EXCEPTIONS

INCONSISTENT_INTERFACE = 1

PROGRAM_ERROR = 2

OTHERS = 3.

*explanations:

• I_PROGRAM_NAME is the program which calls this function

*

• I_INTERNAL_TABNAME is the name of the internal table which you want

• to display in ALV

*

• I_INCLNAME is the ABAP-source where the internal table is defined

• (DATA....)

• CT_FIELDCAT contains the Fieldcatalouge that we need later for

• ALV display

IF SY-SUBRC <> 0.

write: /

'Returncode',

sy-subrc,

'from FUNCTION REUSE_ALV_FIELDCATALOG_MERGE'.

ENDIF.

*This was the fieldcatlogue

----

---

*

• And now, we are ready to display our list

• Call for ALV list display

CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'

EXPORTING

• I_CALLBACK_PROGRAM = 'Z_ALV_SIMPLE_EXAMPLE_WITH_ITAB'

I_CALLBACK_PROGRAM = i_repid

IT_FIELDCAT = int_fcat

I_SAVE = 'A'

TABLES

T_OUTTAB = imat

EXCEPTIONS

PROGRAM_ERROR = 1

OTHERS = 2.

*

*explanations:

• I_CALLBACK_PROGRAM is the program which calls this function

*

• IT_FIELDCAT (just made by REUSE_ALV_FIELDCATALOG_MERGE) contains

• now the data definition needed for display

*

• I_SAVE allows the user to save his own layouts

*

• T_OUTTAB contains the data to be displayed in ALV

IF SY-SUBRC <> 0.

write: /

'Returncode',

sy-subrc,

'from FUNCTION REUSE_ALV_LIST_DISPLAY'.

ENDIF.

*

----

---

*

• yes, it is that simple. Go ahead and try yourself!

*

----

---

hierarchial report :BCALV_TEST_HIERSEQ_LIST_EVENTS

Regards.

Jay

[Former Member]

hi,

if u want hader and its item detail on same page...then u can use Hierarchical ALV.....

means u want to display material number , plant, material doc and their quantity....

now its possible that one material having more than one material doc.....so if u display all in simple alv all time material number and plant will get repeated.....

but if u use hierarchical u can do like....

in header u can put material and plant so it will come once and in item u can put all material doc and quantity assosiated to that material.....

here is example of hierarchical ALV.....

TYPE-POOLS : slis.

TABLES : mseg.

DATA : BEGIN OF itab_head OCCURS 0,
        matnr LIKE mseg-matnr,
        werks LIKE mseg-werks,
       END OF itab_head.

DATA : BEGIN OF itab_item OCCURS 0,
        matnr LIKE mseg-matnr,
        werks LIKE mseg-werks,
        mblnr LIKE mseg-mblnr,
        menge LIKE mseg-menge,
       END OF itab_item.

DATA : t_fcat TYPE slis_t_fieldcat_alv,
       key_info TYPE slis_keyinfo_alv,
       t_eve TYPE slis_t_event,
       gt_subtot TYPE slis_t_sortinfo_alv,
       subtot LIKE LINE OF gt_subtot,
       t_listhead TYPE slis_t_listheader,
       st_line TYPE slis_listheader.

DATA : lin_no TYPE i.

DATA : t_mtdoc LIKE mseg-mblnr.

SELECT-OPTIONS : mat FOR mseg-matnr.

INITIALIZATION.
  PERFORM build_cat USING t_fcat.
  PERFORM build_eve.

START-OF-SELECTION.
  PERFORM get_data.
  PERFORM dis_data.


*&---------------------------------------------------------------------*
*&      Form  build_cat
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->TEMP_FCAT  text
*----------------------------------------------------------------------*
FORM build_cat USING temp_fcat TYPE slis_t_fieldcat_alv.

  DATA : wa_fcat TYPE slis_fieldcat_alv.

  wa_fcat-tabname = 'ITAB_HEAD'.
  wa_fcat-fieldname = 'MATNR'.
  wa_fcat-seltext_m = 'Material'.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

  wa_fcat-tabname = 'ITAB_HEAD'.
  wa_fcat-fieldname = 'WERKS'.
  wa_fcat-seltext_m = 'Plant'.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

  wa_fcat-tabname = 'ITAB_ITEM'.
  wa_fcat-fieldname = 'MBLNR'.
  wa_fcat-seltext_m = 'Material Doc.'.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

  wa_fcat-tabname = 'ITAB_ITEM'.
  wa_fcat-fieldname = 'MENGE'.
  wa_fcat-seltext_m = 'Quantity'.

  wa_fcat-do_sum = 'Y'.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

  subtot-spos = 1.
  subtot-fieldname = 'MATNR'.
  subtot-tabname = 'ITAB_HEAD'.
  subtot-up = 'X'.
  subtot-group = 'X'.
  subtot-subtot = 'X'.
  subtot-expa = 'X'.
  APPEND subtot TO gt_subtot.

ENDFORM.                    "build_cat

*&---------------------------------------------------------------------*
*&      Form  build_eve
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM build_eve.

  DATA : wa_eve TYPE slis_alv_event.

  CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
   EXPORTING
     i_list_type           = 0
   IMPORTING
     et_events             = t_eve
*   EXCEPTIONS
*     LIST_TYPE_WRONG       = 1
*     OTHERS                = 2
            .
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.

  READ TABLE t_eve INTO wa_eve WITH KEY name = 'TOP_OF_PAGE'.
  IF sy-subrc = 0.
    wa_eve-form = 'TOP_OF_PAGE'.
    MODIFY t_eve FROM wa_eve INDEX sy-tabix.
  ENDIF.


ENDFORM.                    "build_eve
*&---------------------------------------------------------------------*
*&      Form  get_data
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM get_data.

  SELECT matnr werks mblnr menge FROM mseg INTO CORRESPONDING FIELDS OF TABLE itab_item
  WHERE matnr IN mat.

ENDFORM.                    "get_data

*&---------------------------------------------------------------------*
*&      Form  dis_data
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM dis_data.

  key_info-header01 = 'MATNR'.
  key_info-item01 = 'MATNR'.
  key_info-header02 = 'WERKS'.
  key_info-item02 = 'WERKS'.

  REFRESH itab_head.
  LOOP AT itab_item.
    ON CHANGE OF itab_item-matnr OR itab_item-werks.
      MOVE-CORRESPONDING itab_item TO itab_head.
      APPEND itab_head.
    ENDON.
  ENDLOOP.

  CALL FUNCTION 'REUSE_ALV_HIERSEQ_LIST_DISPLAY'
    EXPORTING
      i_callback_program             = 'ZALV_PRDS'
      it_fieldcat                    = t_fcat
      it_sort                        = gt_subtot
      it_events                      = t_eve[]
      i_tabname_header               = 'ITAB_HEAD'
      i_tabname_item                 = 'ITAB_ITEM'
      is_keyinfo                     = key_info
    TABLES
      t_outtab_header                = itab_head
      t_outtab_item                  = itab_item
* EXCEPTIONS
*   PROGRAM_ERROR                  = 1
*   OTHERS                         = 2
            .
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.


ENDFORM.                    "dis_data


*&---------------------------------------------------------------------*
*&      Form  top_of_page
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM top_of_page.

  CLEAR st_line.
  st_line-typ = 'H'.
  st_line-info = 'Dhwani Shah'.
  APPEND st_line TO t_listhead.

  CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
    EXPORTING
      it_list_commentary       = t_listhead
            .


ENDFORM.                    "top_of_page

this is the example of simple ALV

TYPE-POOLS : slis.

TABLES : mara,
         makt,
         marc.

DATA : BEGIN OF itab OCCURS 0,
        matnr LIKE mara-matnr,
        maktx LIKE makt-maktx,
        werks LIKE marc-werks,
       END OF itab.

DATA : t_fcat TYPE slis_t_fieldcat_alv,
       t_eve TYPE slis_t_event,
       st_line TYPE slis_listheader,
       t_list_top_page TYPE slis_t_listheader,
       t_list_end_page TYPE slis_t_listheader.

DATA : t_mat LIKE mara-matnr.



SELECTION-SCREEN : BEGIN OF BLOCK blk1 WITH FRAME TITLE text-001.
SELECT-OPTIONS : mat FOR mara-matnr.
SELECTION-SCREEN : END OF BLOCK blk1.

INITIALIZATION.

  PERFORM build_cat USING t_fcat.
  PERFORM build_eve.


START-OF-SELECTION.
  PERFORM get_data.
  PERFORM build_header USING t_list_top_page[].
  PERFORM build_footer USING t_list_end_page[].
  PERFORM dis_data.

*&---------------------------------------------------------------------*
*&      Form  buils_cat
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->TEMP_FCAT  text
*----------------------------------------------------------------------*
FORM build_cat USING temp_fcat TYPE slis_t_fieldcat_alv.

  DATA : wa_fcat TYPE slis_fieldcat_alv.

  wa_fcat-tabname = 'ITAB'.
  wa_fcat-fieldname = 'MATNR'.
  wa_fcat-seltext_m = 'Material'.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

  wa_fcat-tabname = 'ITAB'.
  wa_fcat-fieldname = 'MAKTX'.
  wa_fcat-seltext_m = 'Material Description'.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

  wa_fcat-tabname = 'ITAB'.
  wa_fcat-fieldname = 'WERKS'.
  wa_fcat-seltext_m = 'Plant'.
*  wa_fcat-row_pos = 2.
  APPEND wa_fcat TO temp_fcat.
  CLEAR wa_fcat.

ENDFORM.                    "build_cat

*&---------------------------------------------------------------------*
*&      Form  build_eve
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM build_eve.

  DATA : wa_eve TYPE slis_alv_event.

  CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
   EXPORTING
     i_list_type           = 0
   IMPORTING
     et_events             = t_eve
* EXCEPTIONS
*   LIST_TYPE_WRONG       = 1
*   OTHERS                = 2
            .
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.

  READ TABLE t_eve INTO wa_eve WITH KEY name = 'END_OF_LIST'.
  IF sy-subrc = 0.
    wa_eve-form = 'END_OF_PAGE'.
    MODIFY t_eve FROM wa_eve INDEX sy-tabix.
  ENDIF.

ENDFORM.                    "build_eve

*&---------------------------------------------------------------------*
*&      Form  get_data
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM get_data.

  SELECT mara~matnr makt~maktx marc~werks INTO CORRESPONDING FIELDS OF TABLE itab
  FROM mara INNER JOIN makt ON
  mara~matnr = makt~matnr
  INNER JOIN marc ON
  mara~matnr = marc~matnr
  WHERE mara~matnr IN mat.

ENDFORM.                    "get_data

*&---------------------------------------------------------------------*
*&      Form  dis_data
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM dis_data.

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
   EXPORTING
     i_callback_program                = 'ZALV_PRDS'
      i_callback_top_of_page            = 'TOP_OF_PAGE'
     it_fieldcat                       = t_fcat
     i_save                            = 'A'
     it_events                         = t_eve
   TABLES
      t_outtab                          = itab
* EXCEPTIONS
*   PROGRAM_ERROR                     = 1
*   OTHERS                            = 2
            .
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.


ENDFORM.                    "dis_data

*&---------------------------------------------------------------------*
*&      Form  build_header
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->TEMP_LIST          text
*      -->TTYPE              text
*      -->SLIS_T_LISTHEADER  text
*----------------------------------------------------------------------*
FORM build_header USING temp_list TYPE slis_t_listheader.


  CLEAR st_line.
  st_line-typ = 'H'.
  st_line-info = 'Material Info'.
  APPEND st_line TO temp_list.

  
ENDFORM.                    "build_header

*&---------------------------------------------------------------------*
*&      Form  build_footer
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->TEMP_LIST  text
*----------------------------------------------------------------------*
FORM build_footer USING temp_list TYPE slis_t_listheader.

  CLEAR st_line.
  st_line-typ = 'H'.
  st_line-info = 'Dhwani Shah'.
  APPEND st_line TO temp_list.


ENDFORM.                    "build_header

*&---------------------------------------------------------------------*
*&      Form  top_Of_page
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM top_of_page.

  CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
    EXPORTING
      it_list_commentary = t_list_top_page.

ENDFORM.                    "top_Of_page

*&---------------------------------------------------------------------*
*&      Form  end_of_page
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM end_of_page.

  CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
    EXPORTING
      it_list_commentary = t_list_end_page.

ENDFORM.                    "end_of_page

reward if usefull.....

[Former Member]

we can have three types of reports:

1. Simple Report

2. Block Report

3. Hierarchical Sequential Report

Hierarchical display is used for displaying data that are related. Like sales order and item details. Here sales order details can be the header data whereas them items in the sales order can be the item data

The function module used for this is

REUSE_ALV_HIERSEQ_LIST_DISPLAY

Export:

a. I_CALLBACK_PROGRAM

b. I_CALLBACK_PF_STATUS_SET

c. I_CALLBACK_USER_COMMAND

d. IS_LAYOUT

e. It_fieldcat

f. It_events

g. I_tabname_header : Name of the internal table in the program

containing the output data of the highest hierarchy level.

h. I_tabname_item : Name of the internal table in the program containing

the output data of the lowest hierarchy level.

i. Is_keyinfo : This structure contains the header and item table field

names which link the two tables (shared key).

Tables

i. t_outtab_header : Header table with data to be output

ii. t_outtab_item : Name of the internal table in the program containing the output data of the lowest hierarchy level.

Criteria to choose between the grid and list display.

Grid cannot handle high volumes. Functions like sort, scrolling down consumes a lot of resources / time if the volume of data to be displayed is high. There is no clear cut definition that if so much data then go for list or vise versa but the developer has to take a call based on his experience. If not sure, then list is the better option

reward if useful

regards

Palak