Printing Dunning Letters using Smartforms

[Former Member]

Hi all,

I have a requirement wherein I need to print dunning letters using smartforms; the dunning data are extracted in program SAPF150D2;I modified the subroutine OFI_DUN_ACT to call function module FI_PRINT_DUNNING_NOTICE_SMARTF.

Now I need to extract the dunning data in program SAPF150D2 to be imported to my new form using GET_SF_DUNN_DATA, my question is where do I code the calling of FM GET_SFG_DUNN_DATA? I'm a little bit confused on the step by step process of the dunning data extraction to printing of the form... Thanks...

[RaymondGiuseppi]

You don't have to change any standard program, there is a business event to use smartforms in dunning procedure :

Call transaction FIBF, Menu Settings, P/S function modules, of an SAP appl. Position at record 00001720, space, FI-FI and change function module name to the value FI_PRINT_DUNNING_NOTICE_SMARTF.

The Function module GET_SF_DUNN_DATA should be called in Global settings, Global definitions, Initialization.

Look at the standard smartforms provided by SAP F150_DUNN_SF and copy the provided code and definitions. (or copy the smartforms)

References :

[ Note 430621 - Delivered print programs and form templates|https://service.sap.com/sap/support/notes/430621]

Regards

[Former Member]

Hi

Call the function module in the SAMRTFORM Initialisation part.

[Former Member]

I see, therefore i do not need to edit standard SAP program SAPF150D2, if i run transaction code F150, it will generate dunning letter in smarform automatically, is this correct?

However, I need to add more details on the dunning form that I will be generating. Since I will not be editing the standard program SAPF150D2, where do I put my code to get the additional details in my form?

[RaymondGiuseppi]

In the INITIALIZATION of the Smartforms, after the call to GET_SF_DUNN_DATA, you have a many informations back, of which the record of MHNK and an internal table of MHND, which you can use to select other informations from database.

So fill or enrich your own internal table in the initialization.

I enclose thereafter a sample to help you

* Load data
  CALL FUNCTION 'GET_SF_DUNN_DATA'
       EXPORTING
            is_sfparam          = is_sfparam
       IMPORTING
            es_mhnk             = mhnk
            es_t001             = t001
            es_knb5             = knb5
            es_lfb5             = lfb5
            es_t047             = t047
            es_t047c            = t047c
            es_t047i            = t047i
            es_t056z            = t056z
            es_f150d            = f150d
            es_fsabe            = fsabe
            es_adrnr            = adrnr
            es_uadrnr           = uadrnr
            es_adrs             = adrs
            es_uadrs            = uadrs
            es_t047b            = t047b
            eb_testprint        = testprint
            e_langu             = langu
            e_lang2             = lang2
            es_f150d_esr        = f150d_esr
            es_paymi            = paymi
            es_paymo            = paymo
       TABLES
            t_mhnd              = th_mhnd
       EXCEPTIONS
            no_parameters_found = 1
            OTHERS              = 2.
IF sy-subrc <> 0.
  sy-msgid = 'FM'.
  sy-msgty = 'E'.
  sy-msgno = 461.
  RAISE others.
ENDIF.
h_t040a-text1 = space.
show_interest = space.
LOOP AT th_mhnd INTO mhnd WHERE xzins = ' '.
  show_interest = 'X'.
  EXIT.
ENDLOOP.

* Load user information
DATA: usr21 LIKE usr21, addr3_sel LIKE addr3_sel.
CLEAR: usr21, addr3_sel, addr3_val, adr6.
* Charger fiche profil
SELECT SINGLE * FROM usr21 WHERE bname = sy-uname.
* Récupérer l'adresse
MOVE-CORRESPONDING usr21 TO addr3_sel.
CALL FUNCTION 'ADDR_PERS_COMP_GET'
     EXPORTING
          address_pers_in_comp_selection = addr3_sel
     IMPORTING
          address_pers_in_comp_value     = addr3_val
     EXCEPTIONS
          OTHERS                         = 1.
* load SMTP address
CLEAR adr6.
SELECT SINGLE * FROM adr6
  WHERE addrnumber = usr21-addrnumber
    AND persnumber = usr21-persnumber.

* date format
SET COUNTRY adrs-land1.

* Group similar posts
DATA: xbseg TYPE bseg,
      xbkpf TYPE bkpf,
      xpost TYPE th_outtab.
REFRESH: t_post, t_cumul_waers.
LOOP AT th_mhnd INTO mhnd.
* Select lines to use
  IF mhnk-gmvdt IS INITIAL.
    IF mhnd-xzalb <> space OR mhnd-mansp <> space.
      CONTINUE.
    ELSEIF t047b-xpost NE 'X' AND mhnd-xfael <> 'X'.
      CONTINUE.
    ENDIF.
  ENDIF.
* Map data
  CLEAR xpost.
  MOVE-CORRESPONDING mhnd TO xpost.
* Load text from bseg
  SELECT SINGLE sgtxt INTO xpost-sgtxt FROM bseg
    WHERE bukrs EQ mhnd-bbukrs AND belnr EQ mhnd-belnr
      AND gjahr EQ mhnd-gjahr  AND buzei EQ mhnd-buzei.
  PERFORM edit_text CHANGING xpost-zuonr mhnd-xblnr xpost-sgtxt.
* if "Payment difference" get the date of original document
  IF mhnd-bschl = '06'.
    SELECT SINGLE bldat INTO xpost-bldat
      FROM bkpf
      WHERE bukrs = mhnd-bukrs
        AND belnr = mhnd-rebzg
        AND gjahr = mhnd-rebzj.
  ENDIF.
* Collect posts to print
  COLLECT xpost INTO t_post.
* Collect amount per currency
  MOVE-CORRESPONDING xpost TO cumul.
  COLLECT cumul INTO t_cumul_waers.
ENDLOOP.
* Load customer information
SELECT SINGLE * FROM kna1 INTO kna1
  WHERE kunnr = mhnk-kunnr.
SELECT SINGLE * FROM knb1 INTO knb1
  WHERE bukrs = mhnk-bukrs
    AND kunnr = mhnk-kunnr.
* Convert date to text
PERFORM convert_date USING control_parameters-langu mhnk-laufd
  CHANGING text_date.
PERFORM convert_date USING control_parameters-langu mhnk-prndt_before
  CHANGING text_prev.
PERFORM convert_date USING control_parameters-langu mhnk-grdat
  CHANGING text_extr.

Regards

[Former Member]

I see, so all other information needed in my form will be coded in initialization part. Is that correct?

[RaymondGiuseppi]

correct. You could select the data just before printing, in the text nodes, but as the data come in one batch, it's better to do the job, once at beginning, with for all entries and this kind of statement.

Regards