Community
Application Development and Automation Discussions
Join the discussions or start your own on all things application development, including tools and APIs, programming models, and keeping your skills sharp.
cancel
Turn on suggestions
Auto-suggest helps you quickly narrow down your search results by suggesting possible matches as you type.
Showing results for 
Search instead for 
Did you mean: 
Read only

how to convert table content into html format?

Former Member

‎2008 Nov 14 10:00 AM

0 Likes
6,522

Hi,

Experts,

How to convert internal data into HTML format is there any function module or piece of code to download content into HTML.

Thank u,

Shabeer Ahmed.

Hi,

Experts,

How to convert internal data into HTML format is there any function module or piece of code to download content into HTML.

Thank u,

Shabeer Ahmed.

Reply
7 REPLIES 7
Read only

Former Member

‎2008 Nov 14 10:13 AM

0 Likes
2,783

Hi,

Check this code...


REPORT  ytest_table_html.
*---------------------------------------------------------------------*
*          T Y P E S D E C L A R A T I O N
*---------------------------------------------------------------------*

TYPES:BEGIN OF ty_sflight,
        carrid TYPE s_carr_id,         " Airline Code
        connid TYPE s_conn_id,         " Connection Number
        fldate TYPE s_date,            " Flight Date
        price  TYPE s_price,           " AirFare
        currency TYPE s_currcode,      " Currency
      END OF ty_sflight.

*-ALL related Declarations

DATA:
  t_header TYPE STANDARD TABLE OF w3head WITH HEADER LINE,   "Header
  t_fields TYPE STANDARD TABLE OF w3fields WITH HEADER LINE, "Fields
  t_html TYPE STANDARD TABLE OF w3html,                      "Html
  wa_header TYPE w3head,
  w_head TYPE w3head.

DATA:
  it_sflight TYPE TABLE OF ty_sflight,      " Flights Details

  it_fcat TYPE lvc_t_fcat WITH HEADER LINE. " Fieldcatalog

*---------------------------------------------------------------------*
*        S T A R T - O F - S E L E C T I O N
*---------------------------------------------------------------------*

START-OF-SELECTION.

  SELECT * FROM
    sflight
    INTO CORRESPONDING FIELDS OF TABLE it_sflight
    UP TO 20 ROWS.

*---------------------------------------------------------------------*
*        E N D - O F - S E L E C T I O N
*---------------------------------------------------------------------*
END-OF-SELECTION.

*-Populate Fieldcatalog
  it_fcat-coltext = 'Airline Code'.
  APPEND it_fcat.
  it_fcat-coltext = 'Connection Number'.
  APPEND it_fcat.
  it_fcat-coltext = 'Flight date'.
  APPEND it_fcat.
  it_fcat-coltext = 'Airfare'.
  APPEND it_fcat.
  it_fcat-coltext = 'Currency'.
  APPEND it_fcat.

*-Fill the Column headings and Properties

  LOOP AT it_fcat.
    w_head-text = it_fcat-coltext.
*-Populate the Column Headings
    CALL FUNCTION 'WWW_ITAB_TO_HTML_HEADERS'
      EXPORTING
        field_nr = sy-tabix
        text     = w_head-text
        fgcolor  = 'black'
        bgcolor  = 'green'
      TABLES
        header   = t_header.
*-Populate Column Properties
    CALL FUNCTION 'WWW_ITAB_TO_HTML_LAYOUT'
      EXPORTING
        field_nr = sy-tabix
        fgcolor  = 'black'
        size     = '3'
      TABLES
        fields   = t_fields.

  ENDLOOP.

*-Title of the Display
  wa_header-text = 'Flights Details' .
  wa_header-font = 'Arial'.
  wa_header-size = '2'.

*-Preparing the HTML from Intenal Table
  REFRESH t_html.

  CALL FUNCTION 'WWW_ITAB_TO_HTML'
    EXPORTING
      table_header = wa_header
    TABLES
      html         = t_html
      fields       = t_fields
      row_header   = t_header
      itable       = it_sflight.

*-Download  the HTML into frontend

  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                = 'C:\Flights.htm'
    TABLES
      data_tab                = t_html
    EXCEPTIONS
      file_write_error        = 1
      no_batch                = 2
      gui_refuse_filetransfer = 3
      invalid_type            = 4
      no_authority            = 5
      unknown_error           = 6
      header_not_allowed      = 7
      separator_not_allowed   = 8
      filesize_not_allowed    = 9
      header_too_long         = 10
      dp_error_create         = 11
      dp_error_send           = 12
      dp_error_write          = 13
      unknown_dp_error        = 14
      access_denied           = 15
      dp_out_of_memory        = 16
      disk_full               = 17
      dp_timeout              = 18
      file_not_found          = 19
      dataprovider_exception  = 20
      control_flush_error     = 21
      OTHERS                  = 22.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

*-Display the HTML file

  CALL METHOD cl_gui_frontend_services=>execute
    EXPORTING
      document               = 'C:\Flights.htm'
      operation              = 'OPEN'
    EXCEPTIONS
      cntl_error             = 1
      error_no_gui           = 2
      bad_parameter          = 3
      file_not_found         = 4
      path_not_found         = 5
      file_extension_unknown = 6
      error_execute_failed   = 7
      synchronous_failed     = 8
      not_supported_by_gui   = 9
      OTHERS                 = 10.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

Read only

Former Member
In response to Former Member

‎2008 Nov 14 10:23 AM

0 Likes
2,783

hi,

What ever function modules are used it above code are obsolete so any replacement for this function modules?

Thank u,

Shabeer ahmed.

Read only

Former Member
In response to Former Member

‎2008 Nov 14 10:31 AM

0 Likes
2,783

Then use this code....


REPORT  ytest_table_html1.
*----------------------------------------------------------------*
*        D A T A   D E C L A R A T I O N
*----------------------------------------------------------------*

*-HTML Table
DATA:
  t_html TYPE STANDARD TABLE OF w3html WITH HEADER LINE,
                                       " Html Table

*- Declare Internal table and Fieldcatalog
  it_flight TYPE STANDARD TABLE OF sflight WITH HEADER LINE,
                                       " Flights Details
  it_fcat TYPE lvc_t_fcat WITH HEADER LINE.
                                       " Fieldcatalog
*-Variables
DATA:
  v_lines TYPE i,
  v_field(40).

*-Fieldsymbols
FIELD-SYMBOLS: <fs> TYPE ANY.

*----------------------------------------------------------------*
*        S T A R T - O F - S E L E C T I O N
*----------------------------------------------------------------*
START-OF-SELECTION.

  SELECT *
    FROM sflight
    INTO TABLE it_flight
    UP TO 20 ROWS.
*----------------------------------------------------------------*
*        E N D - O F - S E L E C T I O N
*----------------------------------------------------------------*
END-OF-SELECTION.

*-Fill the Column headings and Properties
* Field catalog is used to populate the Headings and Values of 
* The table cells dynamically 
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name       = 'SFLIGHT'
    CHANGING
      ct_fieldcat            = it_fcat[]
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2.

  DELETE it_fcat WHERE fieldname = 'MANDT'.

  t_html-line = '<html>'.
  APPEND t_html.
  CLEAR t_html.
  t_html-line = '<thead>'.
  APPEND t_html.
  CLEAR t_html.
  t_html-line = '<tr>'.
  APPEND t_html.
  CLEAR t_html.
  t_html-line = '<td><h1>Flights Details</h1></td>'.
  APPEND t_html.
  CLEAR t_html.
  t_html-line = '</tr>'.
  APPEND t_html.
  CLEAR t_html.
  t_html-line = '</thead>'.
  APPEND t_html.
  CLEAR t_html.

  t_html-line = '<table border = "1">'.
  APPEND t_html.
  CLEAR t_html.

  t_html-line = '<tr>'.
  APPEND t_html.
  CLEAR t_html.
*-Populate HTML columns from Filedcatalog
  LOOP AT it_fcat.

    CONCATENATE '<th bgcolor = "green" fgcolor = "black">'
        it_fcat-scrtext_l
        '</th>' INTO t_html-line.
    APPEND t_html.
    CLEAR t_html.

  ENDLOOP.

  t_html-line = '</tr>'.
  APPEND t_html.
  CLEAR t_html.

  DESCRIBE TABLE it_fcat LINES v_lines.
*-Populate HTML table from Internal table data
  LOOP AT it_flight.
    t_html-line = '<tr>'.
    APPEND t_html.
    CLEAR t_html.
*-Populate entire row of HTML table Dynamically
*-With the Help of Fieldcatalog.
    DO v_lines TIMES.

      READ TABLE it_fcat INDEX sy-index.
      CONCATENATE 'IT_FLIGHT-' it_fcat-fieldname INTO v_field.

      ASSIGN (v_field) TO <fs>.

      t_html-line = '<td>'.
      APPEND t_html.
      CLEAR t_html.

      t_html-line = <fs>.
      APPEND t_html.
      CLEAR t_html.

      t_html-line = '</td>'.
      APPEND t_html.
      CLEAR t_html.

      CLEAR v_field.
      UNASSIGN <fs>.

    ENDDO.

    t_html-line = '</tr>'.
    APPEND t_html.
    CLEAR t_html.
  ENDLOOP.
  t_html-line = '</table>'.
  APPEND t_html.
  CLEAR t_html.
*-Download  the HTML into frontend

  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                = 'C:\Flights.htm'
    TABLES
      data_tab                = t_html
    EXCEPTIONS
      file_write_error        = 1
      no_batch                = 2
      gui_refuse_filetransfer = 3
      invalid_type            = 4
      no_authority            = 5
      unknown_error           = 6
      header_not_allowed      = 7
      separator_not_allowed   = 8
      filesize_not_allowed    = 9
      header_too_long         = 10
      dp_error_create         = 11
      dp_error_send           = 12
      dp_error_write          = 13
      unknown_dp_error        = 14
      access_denied           = 15
      dp_out_of_memory        = 16
      disk_full               = 17
      dp_timeout              = 18
      file_not_found          = 19
      dataprovider_exception  = 20
      control_flush_error     = 21
      OTHERS                  = 22.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

*-Display the HTML file

  CALL METHOD cl_gui_frontend_services=>execute
    EXPORTING
      document               = 'C:\Flights.htm'
      operation              = 'OPEN'
    EXCEPTIONS
      cntl_error             = 1
      error_no_gui           = 2
      bad_parameter          = 3
      file_not_found         = 4
      path_not_found         = 5
      file_extension_unknown = 6
      error_execute_failed   = 7
      synchronous_failed     = 8
      not_supported_by_gui   = 9
      OTHERS                 = 10.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

none of the above function modules r obsolete...

Read only

Former Member

‎2008 Nov 14 10:16 AM

0 Likes
2,783

Hi

Following Function Modules are used to convert internal table data to HTML Table.

WWW_ITAB_TO_HTML_HEADERS is used to populate column headings.
   WWW_ITAB_TO_HTML_LAYOUT is used to populate column cell properties.
   WWW_ITAB_TO_HTML is used to convert internal table data to HTML.

Ranga

Read only

Former Member
In response to Former Member

‎2008 Nov 14 10:26 AM

0 Likes
2,783

hello,

Ranga swamy,

Those function modules are obsoleted in Ecc6.0 so any replacement to this?

Thank U,

Shabeer Ahmed.

Read only

Former Member
In response to Former Member

‎2008 Nov 14 10:35 AM

0 Likes
2,783

Hi

Yes

those FM are obsoleted Ecc6.0 . No any replacements I think so.

Read only

Former Member

‎2008 Dec 03 9:20 AM

0 Likes
2,783

Thank u