Finding user exit

[Former Member]

Hello frnds,

what are the steps to find the user exit name using SMOD.

regards,

satya

[Former Member]

Hello,

IN SMOD

<b>Utilities -> Find--> give the Dev class name and search.</b>

or

use this report to find the xit for a particular Tcode:

REPORT ZV_FIND_EXIT NO STANDARD PAGE HEADING.
TABLES : TSTC, TADIR, MODSAPT, MODACT, TRDIR, TFDIR, ENLFDIR.
TABLES : TSTCT.
DATA : JTAB LIKE TADIR OCCURS 0 WITH HEADER LINE.
DATA : FIELD1(30).
DATA : V_DEVCLASS LIKE TADIR-DEVCLASS.
PARAMETERS : P_TCODE LIKE TSTC-TCODE OBLIGATORY.

SELECT SINGLE * FROM TSTC WHERE TCODE EQ P_TCODE.
IF SY-SUBRC EQ 0.
  SELECT SINGLE * FROM TADIR WHERE PGMID = 'R3TR'
                   AND OBJECT = 'PROG'
                   AND OBJ_NAME = TSTC-PGMNA.
  MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
  IF SY-SUBRC NE 0.
    SELECT SINGLE * FROM TRDIR WHERE NAME = TSTC-PGMNA.
    IF TRDIR-SUBC EQ 'F'.
      SELECT SINGLE * FROM TFDIR WHERE PNAME = TSTC-PGMNA.
      SELECT SINGLE * FROM ENLFDIR WHERE FUNCNAME =
      TFDIR-FUNCNAME.
      SELECT SINGLE * FROM TADIR WHERE PGMID = 'R3TR'
                         AND OBJECT = 'FUGR'
                         AND OBJ_NAME EQ ENLFDIR-AREA.

      MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
    ENDIF.
  ENDIF.
  SELECT * FROM TADIR INTO TABLE JTAB
                WHERE PGMID = 'R3TR'
                  AND OBJECT = 'SMOD'
                  AND DEVCLASS = V_DEVCLASS.
  SELECT SINGLE * FROM TSTCT WHERE SPRSL EQ SY-LANGU AND
                                   TCODE EQ P_TCODE.
  FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
  WRITE:/(19) 'Transaction Code - ',
       20(20) P_TCODE,
       45(50) TSTCT-TTEXT.
  SKIP.
  IF NOT JTAB[] IS INITIAL.
    WRITE:/(95) SY-ULINE.
    FORMAT COLOR COL_HEADING INTENSIFIED ON.
    WRITE:/1 SY-VLINE,
           2 'Exit Name',
          21 SY-VLINE ,
          22 'Description',
          95 SY-VLINE.
    WRITE:/(95) SY-ULINE.
    LOOP AT JTAB.
      SELECT SINGLE * FROM MODSAPT
             WHERE SPRSL = SY-LANGU AND
                    NAME = JTAB-OBJ_NAME.
      FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
      WRITE:/1 SY-VLINE,
             2 JTAB-OBJ_NAME HOTSPOT ON,
            21 SY-VLINE ,
            22 MODSAPT-MODTEXT,
            95 SY-VLINE.
    ENDLOOP.
    WRITE:/(95) SY-ULINE.
    DESCRIBE TABLE JTAB.
    SKIP.
    FORMAT COLOR COL_TOTAL INTENSIFIED ON.
    WRITE:/ 'No of Exits:' , SY-TFILL.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(95) 'No User Exit exists'.
  ENDIF.
ELSE.
  FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
  WRITE:/(95) 'Transaction Code Does Not Exist'.
ENDIF.

AT LINE-SELECTION.
  GET CURSOR FIELD FIELD1.
  CHECK FIELD1(4) EQ 'JTAB'.
  SET PARAMETER ID 'MON' FIELD SY-LISEL+1(10).
  CALL TRANSACTION 'SMOD' AND SKIP FIRST   SCREEN.

*************************************************************

Vasanth

[Former Member]

Hi,

Check this site for your reference

Regards,

Sreevani

[Former Member]

Hi Satya,

If you are looking for the user exit enhancement name through SMOD then you can search through the application hierarchy tree which pops up on requesting for values on enhancement field.

However a better way (little crude) would be:

1. Get the main program name for the transaction and goto SE37, type EXIT_<main_program_name>_* and requests for values (F4) , it returns the list of customer functions (user exits) called during the transaction

2. Get the package of the transaction you are looking at and goto the package details in SE80 and search for function groups starting with X. Those function groups contain the function modules related to the transaction and others.

Once you have the user exit function module name, goto table MODSAP and retrieve the corresponding enhancement name by entering the MEMBER = user exit function module name.

Hope this helps.

Regards,

Aditya