Based from my code, how do I implement an ALV grid using OO concept...

[aris_hidalgo]

Hello experts,

I am currently practicing ABAP Objects and I would like to use alv in my report. Now, How can I implement ALV in my report in the simplest way possible. Sample codes will be highly appreciated. Thanks guys and take care!

REPORT z_aris_oo_practice_9

NO STANDARD PAGE HEADING

LINE-SIZE 0

LINE-COUNT 0.

TABLES: spfli.

----

---

• Selection screen

----

---

SELECTION-SCREEN BEGIN OF BLOCK box1 WITH FRAME.

SELECTION-SCREEN BEGIN OF BLOCK box2 WITH FRAME.

PARAMETERS: p_carrid TYPE spfli-carrid,

p_connid TYPE spfli-connid.

SELECTION-SCREEN END OF BLOCK box2.

SELECTION-SCREEN BEGIN OF BLOCK box3 WITH FRAME.

PARAMETERS: p_sumdis AS CHECKBOX.

SELECTION-SCREEN END OF BLOCK box3.

SELECTION-SCREEN END OF BLOCK box1.

----

---

• INTERFACE status

----

---

*

----

---

INTERFACE status.

METHODS write.

ENDINTERFACE. "status

----

---

• CLASS main DEFINITION

----

---

*

----

---

CLASS main DEFINITION.

PUBLIC SECTION.

INTERFACES status.

METHODS: get_data,

combine_data.

CLASS-DATA: counter TYPE i.

PRIVATE SECTION.

TYPES: BEGIN OF t_spfli,

carrid TYPE spfli-carrid,

connid TYPE spfli-connid,

countryfr TYPE spfli-countryfr,

cityfrom TYPE spfli-cityfrom,

airpfrom TYPE spfli-airpfrom,

countryto TYPE spfli-countryto,

cityto TYPE spfli-cityto,

airpto TYPE spfli-airpto,

fltime TYPE spfli-fltime,

deptime TYPE spfli-deptime,

arrtime TYPE spfli-arrtime,

END OF t_spfli.

DATA: it_spfli TYPE STANDARD TABLE OF t_spfli.

ENDCLASS. "main DEFINITION

----

---

• CLASS main IMPLEMENTATION

----

---

*

----

---

CLASS main IMPLEMENTATION.

METHOD status~write.

WRITE: / 'The number of records is:', counter.

ENDMETHOD. "status~write

METHOD get_data.

SELECT carrid connid countryfr

cityfrom airpfrom countryto

cityto airpto fltime

deptime arrtime

FROM spfli

INTO TABLE it_spfli

WHERE carrid = p_carrid.

ENDMETHOD. "get_data

METHOD combine_data.

FIELD-SYMBOLS: <fs_spfli> LIKE LINE OF it_spfli.

LOOP AT it_spfli ASSIGNING <fs_spfli>.

ADD 1 TO counter.

WRITE: / <fs_spfli>-carrid,

<fs_spfli>-connid,

<fs_spfli>-countryfr,

<fs_spfli>-cityfrom,

<fs_spfli>-airpfrom,

<fs_spfli>-countryto,

<fs_spfli>-cityto,

<fs_spfli>-airpto,

<fs_spfli>-fltime,

<fs_spfli>-deptime,

<fs_spfli>-arrtime.

ENDLOOP.

ENDMETHOD. "show_data

ENDCLASS. "main IMPLEMENTATION

START-OF-SELECTION.

DATA: main TYPE REF TO main,

status TYPE REF TO status.

CREATE OBJECT main.

CALL METHOD main->get_data.

CALL METHOD main->combine_data.

CALL METHOD main->status~write.

[Former Member]

hello,

Go through the below code..

CONSTANTS: c_custom_container_name(15) TYPE c VALUE 'ZSFK_LISTE'.

DATA: alv_list_nr TYPE i.

DATA: g_f_container TYPE scrfname

VALUE c_custom_container_name,

g_o_grid TYPE REF TO cl_gui_alv_grid,

g_o_custom_container TYPE REF TO cl_gui_custom_container,

g_f_ok_code LIKE sy-ucomm.

• parameters in alv-calls:

DATA: alv_disp_variant TYPE disvariant,

alv_fieldcat TYPE lvc_t_fcat,

alv_sorttab TYPE lvc_t_sort,

alv_sortline TYPE lvc_s_sort,

alv_layout TYPE lvc_s_layo,

alv_print TYPE lvc_s_prnt,

alv_stable TYPE lvc_s_stbl,

alv_excl_func TYPE ui_functions.

FIELD-SYMBOLS: <fcat> TYPE lvc_s_fcat.

• declare object of type eventhandler

DATA: eventhandler_object TYPE REF TO alv_eventhandler.

FORM give_alv_output TABLES $alv_outtab.

g_f_dynpro_nr = sy-dynnr.

alv_stable-row = space.

alv_stable-col = space.

alv_print-print = space.

alv_print-reservelns = 3.

alv_print-prnt_info = 'X'.

*set the ALV Grid

IF g_o_custom_container IS INITIAL.

IF sy-batch IS INITIAL .

• Instantiate the Custom container

CREATE OBJECT g_o_custom_container

EXPORTING container_name = g_f_container.

ENDIF.

• Instantiate the Grid control

CREATE OBJECT g_o_grid

EXPORTING i_parent = g_o_custom_container.

• Events

CREATE OBJECT eventhandler_object.

• register eventhandler

SET HANDLER eventhandler_object->handle_print_top_of_list

eventhandler_object->handle_print_top_of_page

eventhandler_object->handle_print_end_of_page

eventhandler_object->handle_print_end_of_list

FOR g_o_grid.

CALL METHOD g_o_grid->set_table_for_first_display

EXPORTING

is_variant = alv_disp_variant

i_save = 'A'

i_default = 'X'

is_layout = alv_layout

is_print = alv_print

it_toolbar_excluding = alv_excl_func

CHANGING

it_outtab = $alv_outtab[] "because with

it_fieldcatalog = alv_fieldcat

it_sort = alv_sorttab

EXCEPTIONS

invalid_parameter_combination = 1 "header line when density

program_error = 2

too_many_lines = 3

OTHERS = 4.

ENDIF.

ENDFORM. "give_alv_output

Reward if it helps.

Thanks,

Krishna

[Former Member]

Hi,

Give me ur email id and i will send you some good docs on OOABAP.

<b>I have sent u the docs.</b>rgds,

latheesh

Message was edited by: Latheesh Kaduthara

[aris_hidalgo]

Hi,

this is my e-mail id: viraylab@yahoo.com

Thanks a lot!

[Former Member]

Hi,

after you have selected your data and saved it in an internal table, you do the following:

1) create a screen in your program named 0100 with its corresponding pf-status and titlebar.

2) use the coding:

DATA:

okcode LIKE sy-ucomm,

mygrid TYPE REF TO cl_gui_alv_grid,

mycontainer TYPE REF TO cl_gui_custom_container,

field_catal TYPE lvc_t_fcat,

fieldcat_aux TYPE lvc_s_fcat.

CALL SCREEN 0100.

*----

---

• Module PAI INPUT

*----

---

MODULE user_command_0100.

CASE okcode.

WHEN 'CANC' OR 'BACK'.

LEAVE PROGRAM.

WHEN OTHERS.

• do nothing

ENDCASE.

ENDMODULE.

*----

---

• Module PBO OUTPUT

*----

---

MODULE status_0100 OUTPUT.

SET PF-STATUS 'STATUS-100'.

SET TITLEBAR '100'.

PERFORM build_field_catal.

IF mygrid IS INITIAL.

CREATE OBJECT mygrid

EXPORTING i_parent = mycontainer.

CALL METHOD mygrid->set_table_for_first_display

EXPORTING

it_toolbar_excluding = t_fcodes[]

CHANGING

it_outtab = mytable[]

it_fieldcatalog = field_catal[]

EXCEPTIONS

invalid_parameter_combination = 1

program_error = 2

too_many_lines = 3

OTHERS = 4.

IF sy-subrc NE '0'.

MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

STOP.

ENDIF.

CALL METHOD mygrid->set_toolbar_interactive.

CALL METHOD mygrid->refresh_table_display.

ELSE.

CALL METHOD mygrid->refresh_table_display.

ENDIF.

ENDMODULE.

*----

---

• Build the field catalogue

*----

---

FORM build_field_catal.

CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'

EXPORTING

i_structure_name = 'SFLIGHT'

CHANGING

ct_fieldcat = field_catal.

LOOP AT field_catal INTO fieldcat_aux.

CASE fieldcat_aux-fieldname.

WHEN 'CARRID'.

fieldcat_aux-scrtext_l = 'Airline carrier'.

fieldcat_aux-fix_column = 'X'.

WHEN 'CONNID'.

fieldcat_aux-scrtext_l = 'Flight connection'.

fieldcat_aux-fix_column = 'X'.

WHEN 'FLDATE'.

fieldcat_aux-scrtext_l = 'Flight date'.

fieldcat_aux-fix_column = 'X'.

WHEN 'PRICE'.

fieldcat_aux-scrtext_l = 'Airfare'.

fieldcat_aux-do_sum = 'X'.

WHEN 'CURRENCY'.

fieldcat_aux-scrtext_l = 'Local currency'.

fieldcat_aux-outputlen = 10.

ENDCASE.

MODIFY field_catal FROM fieldcat_aux.

ENDLOOP.

ENDFORM.

[Former Member]

Hi,

Check this example..., In this i implemented so many functionalities like top_of_page, drop_down at cell level etc.., also Check the programs BCALVEDIT also

Just check it.

REPORT  ZTEST_ALV_OO    MESSAGE-ID ZZ                           .
DATA: G_GRID TYPE REF TO CL_GUI_ALV_GRID.
DATA: L_VALID TYPE C,
      V_FLAG,
      V_DATA_CHANGE,
      V_ROW TYPE LVC_S_ROW,
      V_COLUMN TYPE LVC_S_COL,
      V_ROW_NUM TYPE LVC_S_ROID.
DATA: IT_ROW_NO TYPE LVC_T_ROID,
      X_ROW_NO TYPE LVC_S_ROID.
DATA:BEGIN OF  ITAB OCCURS 0,
     VBELN LIKE LIKP-VBELN,
     POSNR LIKE LIPS-POSNR,
     CELLCOLOR TYPE LVC_T_SCOL, "required for color
     DROP(10),
     check,
     END OF ITAB.
"The Below Definitions Must.....
DATA:
* Reference to document
       DG_DYNDOC_ID       TYPE REF TO CL_DD_DOCUMENT,
* Reference to split container
       DG_SPLITTER          TYPE REF TO CL_GUI_SPLITTER_CONTAINER,
* Reference to grid container
       DG_PARENT_GRID     TYPE REF TO CL_GUI_CONTAINER,
* Reference to html container
       DG_HTML_CNTRL        TYPE REF TO CL_GUI_HTML_VIEWER,
* Reference to html container
       DG_PARENT_HTML     TYPE REF TO CL_GUI_CONTAINER.
"up to here
*---------------------------------------------------------------------*
*       CLASS lcl_event_handler DEFINITION
*---------------------------------------------------------------------*
CLASS LCL_EVENT_HANDLER DEFINITION .
  PUBLIC SECTION .
    METHODS:
**Hot spot Handler
    HANDLE_HOTSPOT_CLICK FOR EVENT HOTSPOT_CLICK OF CL_GUI_ALV_GRID
                      IMPORTING E_ROW_ID E_COLUMN_ID ES_ROW_NO,
**Double Click Handler
    HANDLE_DOUBLE_CLICK FOR EVENT DOUBLE_CLICK OF CL_GUI_ALV_GRID
                                     IMPORTING E_ROW E_COLUMN ES_ROW_NO,

    TOP_OF_PAGE FOR EVENT TOP_OF_PAGE              "event handler
                         OF CL_GUI_ALV_GRID
                         IMPORTING E_DYNDOC_ID.
*
*        END_OF_LIST FOR EVENT end_of_list              "event handler
*                         OF CL_GUI_ALV_GRID
*                         IMPORTING E_DYNDOC_ID.
ENDCLASS.                    "lcl_event_handler DEFINITION
*---------------------------------------------------------------------*
*       CLASS lcl_event_handler IMPLEMENTATION
*---------------------------------------------------------------------*
CLASS LCL_EVENT_HANDLER IMPLEMENTATION.
*Handle Hotspot Click
  METHOD HANDLE_HOTSPOT_CLICK .
    CLEAR: V_ROW,V_COLUMN,V_ROW_NUM.
    V_ROW  = E_ROW_ID.
    V_COLUMN = E_COLUMN_ID.
    V_ROW_NUM = ES_ROW_NO.
*    MESSAGE I000 WITH V_ROW 'clicked'.
    CLEAR IT_ROW_NO[].
    X_ROW_NO-ROW_ID = V_ROW.
    APPEND X_ROW_NO TO IT_ROW_NO .
    CALL METHOD G_GRID->SET_SELECTED_ROWS
      EXPORTING
        IT_ROW_NO = IT_ROW_NO.

  ENDMETHOD.                    "lcl_event_handler

*Handle Double Click
  METHOD  HANDLE_DOUBLE_CLICK.
    CLEAR: V_ROW,V_COLUMN,V_ROW_NUM.
    V_ROW  = E_ROW.
    V_COLUMN = E_COLUMN.
    V_ROW_NUM = ES_ROW_NO.

    IF E_COLUMN = 'VBELN'.
      SET PARAMETER ID 'VL' FIELD ITAB-VBELN.
      CALL TRANSACTION 'VL03N' AND SKIP FIRST SCREEN.

    ENDIF.
    IF E_COLUMN = 'POSNR'.
      SET PARAMETER ID 'VL' FIELD ITAB-VBELN.
      CALL TRANSACTION 'VL03N' AND SKIP FIRST SCREEN."
    ENDIF.
  ENDMETHOD.                    "handle_double_click

*  METHOD END_OF_LIST.                   "implementation
** Top-of-page event
*    PERFORM EVENT_TOP_OF_PAGE USING DG_DYNDOC_ID.
*  ENDMETHOD.                            "top_of_page

    METHOD TOP_OF_PAGE.                   "implementation
* Top-of-page event
    PERFORM EVENT_TOP_OF_PAGE USING DG_DYNDOC_ID.
  ENDMETHOD.                            "top_of_page
ENDCLASS.                    "LCL_EVENT_HANDLER IMPLEMENTATION

*&---------------------------------------------------------------------*
*&             Global Definitions
*&---------------------------------------------------------------------*
DATA:      G_CUSTOM_CONTAINER TYPE REF TO CL_GUI_CUSTOM_CONTAINER,"Container1
            G_HANDLER TYPE REF TO LCL_EVENT_HANDLER. "handler

DATA: OK_CODE LIKE SY-UCOMM,
      SAVE_OK LIKE SY-UCOMM,
      G_CONTAINER1 TYPE SCRFNAME VALUE 'TEST',
      GS_LAYOUT TYPE LVC_S_LAYO.
data: v_lines type i.
data: v_line(3) type c.
*- Fieldcatalog for First and second Report
DATA: IT_FIELDCAT  TYPE  LVC_T_FCAT,
      X_FIELDCAT TYPE LVC_S_FCAT,
      LS_VARI  TYPE DISVARIANT.
*---------------------------------------------------------------------
*                START-OF_SELECTION
*---------------------------------------------------------------------
START-OF-SELECTION.

  SELECT VBELN
         POSNR
         FROM LIPS
         UP TO 20 ROWS
         INTO CORRESPONDING FIELDS OF TABLE ITAB.
describe table itab lines v_lines.
END-OF-SELECTION.
  IF NOT ITAB[] IS INITIAL.
    CALL SCREEN 100.
  ELSE.
    MESSAGE I002 WITH 'NO DATA FOR THE SELECTION'(004).
  ENDIF.
*&---------------------------------------------------------------------*
*&      Form  CREATE_AND_INIT_ALV
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM CREATE_AND_INIT_ALV .
  DATA: LT_EXCLUDE TYPE UI_FUNCTIONS.
  "attention.....from here
  "split your container here...into two parts

  "create the container
  CREATE OBJECT G_CUSTOM_CONTAINER
           EXPORTING CONTAINER_NAME = G_CONTAINER1.
  "this is for top of page
* Create TOP-Document
  CREATE OBJECT DG_DYNDOC_ID
                   EXPORTING STYLE = 'ALV_GRID'.
* Create Splitter for custom_container
  CREATE OBJECT DG_SPLITTER
             EXPORTING PARENT  = G_CUSTOM_CONTAINER
                       ROWS    = 2
                       COLUMNS = 1.
* Split the custom_container to two containers and move the reference
* to receiving containers g_parent_html and g_parent_grid
  "i am allocating the space for grid and top of page
  CALL METHOD DG_SPLITTER->GET_CONTAINER
    EXPORTING
      ROW       = 1
      COLUMN    = 1
    RECEIVING
      CONTAINER = DG_PARENT_HTML.
  CALL METHOD DG_SPLITTER->GET_CONTAINER
    EXPORTING
      ROW       = 2
      COLUMN    = 1
    RECEIVING
      CONTAINER = DG_PARENT_GRID.
*  CALL METHOD DG_SPLITTER->GET_CONTAINER
*    EXPORTING
*      ROW       = 2
*      COLUMN    = 1
*    RECEIVING
*      CONTAINER = DG_PARENT_HTML.
*  CALL METHOD DG_SPLITTER->GET_CONTAINER
*    EXPORTING
*      ROW       = 1
*      COLUMN    = 1
*    RECEIVING
*      CONTAINER = DG_PARENT_GRID.
  "you can set the height of it
* Set height for g_parent_html
  CALL METHOD DG_SPLITTER->SET_ROW_HEIGHT
    EXPORTING
      ID     = 1
      HEIGHT = 5.
  "from here as usual..you need to specify parent as splitter part
  "which we alloted for grid
  CREATE OBJECT G_GRID
         EXPORTING I_PARENT = DG_PARENT_GRID.
* Set a titlebar for the grid control
  CLEAR GS_LAYOUT.
  GS_LAYOUT-GRID_TITLE = TEXT-003.
  GS_LAYOUT-ZEBRA = SPACE.
  GS_LAYOUT-CWIDTH_OPT = 'X'.
  GS_LAYOUT-NO_ROWMARK = 'X'.
  GS_LAYOUT-CTAB_FNAME = 'CELLCOLOR'.
  CALL METHOD G_GRID->REGISTER_EDIT_EVENT
    EXPORTING
      I_EVENT_ID = CL_GUI_ALV_GRID=>MC_EVT_ENTER.

  CREATE OBJECT G_HANDLER.
  SET HANDLER G_HANDLER->HANDLE_DOUBLE_CLICK FOR G_GRID.
  SET HANDLER G_HANDLER->HANDLE_HOTSPOT_CLICK FOR G_GRID.
*  SET HANDLER G_HANDLER->END_OF_LIST FOR G_GRID.
  SET HANDLER G_HANDLER->TOP_OF_PAGE FOR G_GRID.
  DATA: LS_CELLCOLOR TYPE LVC_S_SCOL. "required for color
  DATA: L_INDEX TYPE SY-TABIX.
  "Here i am changing the color of line 1,5,10...
  "so you can change the color of font conditionally
  LOOP AT ITAB.
    L_INDEX = SY-TABIX.
    IF L_INDEX = 1 OR L_INDEX = 5 OR L_INDEX = 10.
      LS_CELLCOLOR-FNAME = 'VBELN'.
      LS_CELLCOLOR-COLOR-COL = '6'.
      LS_CELLCOLOR-COLOR-INT = '0'.
      LS_CELLCOLOR-COLOR-INV = '1'.
      APPEND LS_CELLCOLOR TO ITAB-CELLCOLOR.
      MODIFY ITAB INDEX L_INDEX TRANSPORTING CELLCOLOR.
      LS_CELLCOLOR-FNAME = 'POSNR'.
      LS_CELLCOLOR-COLOR-COL = '6'.
      LS_CELLCOLOR-COLOR-INT = '0'.
      LS_CELLCOLOR-COLOR-INV = '1'.
      APPEND LS_CELLCOLOR TO ITAB-CELLCOLOR.
      MODIFY ITAB INDEX L_INDEX TRANSPORTING CELLCOLOR.
    ENDIF.
  ENDLOOP.

* setting focus for created grid control
  CALL METHOD CL_GUI_CONTROL=>SET_FOCUS
    EXPORTING
      CONTROL = G_GRID.
* Build fieldcat and set editable for date and reason code
* edit enabled. Assign a handle for the dropdown listbox.
  PERFORM BUILD_FIELDCAT.
  PERFORM  SET_DRDN_TABLE.
* Optionally restrict generic functions to 'change only'.
*   (The user shall not be able to add new lines).
  PERFORM EXCLUDE_TB_FUNCTIONS CHANGING LT_EXCLUDE.
**Vaiant to save the layout
  LS_VARI-REPORT      = SY-REPID.
  LS_VARI-HANDLE      = SPACE.
  LS_VARI-LOG_GROUP   = SPACE.
  LS_VARI-USERNAME    = SPACE.
  LS_VARI-VARIANT     = SPACE.
  LS_VARI-TEXT        = SPACE.
  LS_VARI-DEPENDVARS  = SPACE.

**Calling the Method for ALV output
  CALL METHOD G_GRID->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      IT_TOOLBAR_EXCLUDING = LT_EXCLUDE
      IS_VARIANT           = LS_VARI
      IS_LAYOUT            = GS_LAYOUT
      I_SAVE               = 'A'
    CHANGING
      IT_FIELDCATALOG      = IT_FIELDCAT
      IT_OUTTAB            = ITAB[].
  "do these..{
* Initializing document
  CALL METHOD DG_DYNDOC_ID->INITIALIZE_DOCUMENT.

* Processing events
  CALL METHOD G_GRID->LIST_PROCESSING_EVENTS
    EXPORTING
      I_EVENT_NAME = 'TOP_OF_PAGE'
      I_DYNDOC_ID  = DG_DYNDOC_ID.
  "end }
* Set editable cells to ready for input initially
  CALL METHOD G_GRID->SET_READY_FOR_INPUT
    EXPORTING
      I_READY_FOR_INPUT = 1.

ENDFORM.                               "CREATE_AND_INIT_ALV
*&---------------------------------------------------------------------*
*&      Form  EXCLUDE_TB_FUNCTIONS
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->PT_EXCLUDE text
*----------------------------------------------------------------------*
FORM EXCLUDE_TB_FUNCTIONS CHANGING PT_EXCLUDE TYPE UI_FUNCTIONS.
* Only allow to change data not to create new entries (exclude
* generic functions).
  DATA LS_EXCLUDE TYPE UI_FUNC.

  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_COPY_ROW.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_DELETE_ROW.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_APPEND_ROW.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_INSERT_ROW.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_MOVE_ROW.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_COPY.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_CUT.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_PASTE.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_PASTE_NEW_ROW.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
  LS_EXCLUDE = CL_GUI_ALV_GRID=>MC_FC_LOC_UNDO.
  APPEND LS_EXCLUDE TO PT_EXCLUDE.
ENDFORM.                               " EXCLUDE_TB_FUNCTIONS
*&---------------------------------------------------------------------*
*&      Form  build_fieldcat
*&---------------------------------------------------------------------*
*       Fieldcatalog
*----------------------------------------------------------------------*
FORM BUILD_FIELDCAT .
  DATA: L_POS TYPE I.
  L_POS = L_POS + 1.

  X_FIELDCAT-SCRTEXT_M = 'Check'.
  X_FIELDCAT-FIELDNAME = 'CHECK'.
  X_FIELDCAT-TABNAME = 'IT_FINAL'.
  X_FIELDCAT-COL_POS    = L_POS.
  X_FIELDCAT-CHECKbox   = 'X'.
    X_FIELDCAT-EDIT = 'X'.
  X_FIELDCAT-OUTPUTLEN = '1'.

  APPEND X_FIELDCAT TO IT_FIELDCAT.
  CLEAR X_FIELDCAT.
  L_POS = L_POS + 1.

  X_FIELDCAT-SCRTEXT_M = 'Delivery'(024).
  X_FIELDCAT-FIELDNAME = 'VBELN'.
  X_FIELDCAT-TABNAME = 'IT_FINAL'.
  X_FIELDCAT-COL_POS    = L_POS.
  X_FIELDCAT-NO_ZERO    = 'X'.
  X_FIELDCAT-OUTPUTLEN = '10'.
  X_FIELDCAT-HOTSPOT = 'X'.

  APPEND X_FIELDCAT TO IT_FIELDCAT.
  CLEAR X_FIELDCAT.
  L_POS = L_POS + 1.

  X_FIELDCAT-SCRTEXT_M = 'Item'(025).
  X_FIELDCAT-FIELDNAME = 'POSNR'.
  X_FIELDCAT-TABNAME = 'IT_FINAL'.
  X_FIELDCAT-COL_POS    = L_POS.
  X_FIELDCAT-OUTPUTLEN = '5'.
  APPEND X_FIELDCAT TO IT_FIELDCAT.
  CLEAR X_FIELDCAT.
  L_POS = L_POS + 1.


  X_FIELDCAT-SCRTEXT_M = 'Drop'(025).
  X_FIELDCAT-FIELDNAME = 'DROP'.
  X_FIELDCAT-TABNAME = 'IT_FINAL'.
  X_FIELDCAT-COL_POS    = L_POS.
  X_FIELDCAT-OUTPUTLEN = '5'.
  X_FIELDCAT-EDIT = 'X'.
  X_FIELDCAT-DRDN_HNDL = '1'.
  X_FIELDCAT-DRDN_ALIAS = 'X'.
  APPEND X_FIELDCAT TO IT_FIELDCAT.
  CLEAR X_FIELDCAT.

ENDFORM.                    " build_fieldcat
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE STATUS_0100 OUTPUT.
  SET PF-STATUS 'MAIN100'.
  SET TITLEBAR 'MAIN100'.
  IF G_CUSTOM_CONTAINER IS INITIAL.
**Initializing the grid and calling the fm to Display the O/P
    PERFORM CREATE_AND_INIT_ALV.
  ENDIF.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE USER_COMMAND_0100 INPUT.
  CASE SY-UCOMM.
    WHEN 'BACK'.
      LEAVE TO SCREEN 0.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT

*&---------------------------------------------------------------------*
*&      Form  SET_DRDN_TABLE
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM SET_DRDN_TABLE.

  DATA:LT_DRAL TYPE LVC_T_DRAL,
        LS_DRAL TYPE LVC_S_DRAL.
  LOOP AT ITAB .
* First listbox (handle '1').
    IF SY-INDEX = 1.
      LS_DRAL-HANDLE = '1'.
      LS_DRAL-VALUE =  ' '.
      LS_DRAL-INT_VALUE =  ' '.
    ELSE.
      LS_DRAL-HANDLE = '1'.
      LS_DRAL-VALUE =  ITAB-POSNR.
      LS_DRAL-INT_VALUE =  ITAB-POSNR.
    ENDIF.
    APPEND LS_DRAL TO LT_DRAL.
  ENDLOOP.
**Setting the Drop down table for Reason Code
  CALL METHOD G_GRID->SET_DROP_DOWN_TABLE
    EXPORTING
      IT_DROP_DOWN_ALIAS = LT_DRAL.
ENDFORM.                               " set_drdn_table
*&---------------------------------------------------------------------*
*&      Form  EVENT_TOP_OF_PAGE
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->DG_DYNDOC_ID  text
*----------------------------------------------------------------------*
FORM EVENT_TOP_OF_PAGE USING   DG_DYNDOC_ID TYPE REF TO CL_DD_DOCUMENT.
  "this is more clear.....check it
  "first add text, then pass it to comentry write fm
  DATA : DL_TEXT(255) TYPE C.  "Text
* Populating header to top-of-page
  CALL METHOD DG_DYNDOC_ID->ADD_TEXT
    EXPORTING
      TEXT      = 'Test Report'
      SAP_STYLE = CL_DD_AREA=>HEADING.
* Add new-line
  CALL METHOD DG_DYNDOC_ID->NEW_LINE.

  CLEAR : DL_TEXT.
* Move program ID
  CONCATENATE 'Program Name :' SY-REPID
         INTO DL_TEXT SEPARATED BY SPACE.
* Add Program Name to Document
  PERFORM ADD_TEXT USING DL_TEXT.
* Add new-line
  CALL METHOD DG_DYNDOC_ID->NEW_LINE.

  CLEAR : DL_TEXT.

* Move User ID
  CONCATENATE 'User ID :' SY-UNAME INTO DL_TEXT SEPARATED BY SPACE
.
* Add User ID to Document
  PERFORM ADD_TEXT USING DL_TEXT.
* Add new-line
  CALL METHOD DG_DYNDOC_ID->NEW_LINE.

  CLEAR : DL_TEXT.
* Move count (no of records).
  move v_lines to v_line.
  CONCATENATE 'No of records :' v_line INTO DL_TEXT SEPARATED BY SPACE.
* Add Client to Document
  PERFORM ADD_TEXT USING DL_TEXT.
* Add new-line
  CALL METHOD DG_DYNDOC_ID->NEW_LINE.

  CLEAR : DL_TEXT.
* Move date
  WRITE SY-DATUM TO DL_TEXT.
  CONCATENATE 'Date :' DL_TEXT INTO DL_TEXT SEPARATED BY SPACE.
* Add Date to Document
  PERFORM ADD_TEXT USING DL_TEXT.
* Add new-line
  CALL METHOD DG_DYNDOC_ID->NEW_LINE.

  CLEAR : DL_TEXT.
* Move time
  WRITE SY-UZEIT TO DL_TEXT.
  CONCATENATE 'Time :' DL_TEXT INTO DL_TEXT SEPARATED BY SPACE.
* Add Time to Document
  PERFORM ADD_TEXT USING DL_TEXT.
* Add new-line
  CALL METHOD DG_DYNDOC_ID->NEW_LINE.
* Populating data to html control
  PERFORM HTML.

ENDFORM.                    " EVENT_TOP_OF_PAGE
*&---------------------------------------------------------------------*
*&      Form  ADD_TEXT
*&---------------------------------------------------------------------*
*       To add Text
*----------------------------------------------------------------------*
FORM ADD_TEXT USING P_TEXT TYPE SDYDO_TEXT_ELEMENT.
* Adding text
  CALL METHOD DG_DYNDOC_ID->ADD_TEXT
    EXPORTING
      TEXT         = P_TEXT
      SAP_EMPHASIS = CL_DD_AREA=>HEADING.
ENDFORM.                    " ADD_TEXT
*&---------------------------------------------------------------------*
*&      Form  HTML
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM HTML.
  DATA : DL_LENGTH  TYPE I,                           " Length
         DL_BACKGROUND_ID TYPE SDYDO_KEY VALUE SPACE. " Background_id
* Creating html control
  IF DG_HTML_CNTRL IS INITIAL.
    CREATE OBJECT DG_HTML_CNTRL
         EXPORTING
              PARENT    = DG_PARENT_HTML.
  ENDIF.
* Reuse_alv_grid_commentary_set
  CALL FUNCTION 'REUSE_ALV_GRID_COMMENTARY_SET'
    EXPORTING
      DOCUMENT = DG_DYNDOC_ID
      BOTTOM   = SPACE
    IMPORTING
      LENGTH   = DL_LENGTH.
* Get TOP->HTML_TABLE ready
  CALL METHOD DG_DYNDOC_ID->MERGE_DOCUMENT.
* Set wallpaper
  CALL METHOD DG_DYNDOC_ID->SET_DOCUMENT_BACKGROUND
    EXPORTING
      PICTURE_ID = DL_BACKGROUND_ID.
* Connect TOP document to HTML-Control
  DG_DYNDOC_ID->HTML_CONTROL = DG_HTML_CNTRL.
* Display TOP document
  CALL METHOD DG_DYNDOC_ID->DISPLAY_DOCUMENT
    EXPORTING
      REUSE_CONTROL      = 'X'
      PARENT             = DG_PARENT_HTML
    EXCEPTIONS
      HTML_DISPLAY_ERROR = 1.
  IF SY-SUBRC NE 0.
    MESSAGE I999 WITH 'Error in displaying top-of-page'(036).
  ENDIF.

ENDFORM.                    " HTML

Regards

vijay

[aris_hidalgo]

Hi again guys,

I noticed in your examples that you have statements such as

MODULE...ENDMODULE. Where will I put it?in the screen? or can I include it directly in my report code?Thanks a lot.

[Former Member]

Hi Viray,

first you need to create the Screen, inside the screen need to place the custom control inside the screen and then use that screen and proceed.

create the conatiner object using the custom control, and then assign the grid reference to the container object and then create the GRID object and call the method to show your data.Check this small demo example <b>BCALV_EDIT_01</b>

Regards

vijay

[RichHeilman]

I guess you want to implement the CL_GUI_ALV_GRID, right? If not, here is an easy solution to put your data in ALV grid.

report zrich_0001.


tables: spfli.

*----------------------------------------------*
* Selection screen
*----------------------------------------------*
selection-screen begin of block box1 with frame.
selection-screen begin of block box2 with frame.
parameters: p_carrid type spfli-carrid,
p_connid type spfli-connid.
selection-screen end of block box2.

selection-screen begin of block box3 with frame.
parameters: p_sumdis as checkbox.
selection-screen end of block box3.
selection-screen end of block box1.

*----------------------------------------------------------------------*
* INTERFACE status
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
interface status.
  methods write.
endinterface. "status
*----------------------------------------------------------------------*
* CLASS main DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
class main definition.
  public section.
    interfaces status.
    methods: get_data,
    combine_data.
    class-data: counter type i.
  private section.
    types: begin of t_spfli,
    carrid type spfli-carrid,
    connid type spfli-connid,
    countryfr type spfli-countryfr,
    cityfrom type spfli-cityfrom,
    airpfrom type spfli-airpfrom,
    countryto type spfli-countryto,
    cityto type spfli-cityto,
    airpto type spfli-airpto,
    fltime type spfli-fltime,
    deptime type spfli-deptime,
    arrtime type spfli-arrtime,
    end of t_spfli.

    data: it_spfli type standard table of t_spfli.
endclass. "main DEFINITION

*----------------------------------------------------------------------*
* CLASS main IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
class main implementation.
  method status~write.
    write: / 'The number of records is:', counter.
  endmethod. "status~write

  method get_data.
    select carrid connid countryfr
    cityfrom airpfrom countryto
    cityto airpto fltime
    deptime arrtime
    from spfli
    into table it_spfli
    where carrid = p_carrid.
  endmethod. "get_data

  method combine_data.
<b>*    field-symbols: <fs_spfli> like line of it_spfli.
*
*    loop at it_spfli assigning <fs_spfli>.
*      add 1 to counter.
*      write: / <fs_spfli>-carrid,
*      <fs_spfli>-connid,
*      <fs_spfli>-countryfr,
*      <fs_spfli>-cityfrom,
*      <fs_spfli>-airpfrom,
*      <fs_spfli>-countryto,
*      <fs_spfli>-cityto,
*      <fs_spfli>-airpto,
*      <fs_spfli>-fltime,
*      <fs_spfli>-deptime,
*      <fs_spfli>-arrtime.
*    endloop.
    call function 'REUSE_ALV_GRID_DISPLAY'
         exporting
              i_structure_name = 'SPFLI'
         tables
              t_outtab         = it_spfli.</b>

  endmethod. "show_data
endclass. "main IMPLEMENTATION

start-of-selection.

  data: main type ref to main,
  status type ref to status.

  create object main.
  call method main->get_data.
  call method main->combine_data.
*  call method main->status~write.

By this way, this would be the <u>simplest way possible</u>.

Regards,

Rich Heilman

[Former Member]

simplest way possible? what about this...

   data scarr_list type standard table of scarr.
   data alv_ref type ref to cl_salv_table.


**************************************************************************
START-OF-SELECTION.
**************************************************************************

  select * 
    from scarr
    into table scarr_list.

   cl_salv_table=>factory( exporting list_display   = if_salv_c_bool_sap=>false
                                     importing r_salv_table  = alv_ref
                                     changing t_table          = scarr_list ).

   alv_ref->display( ).

[Former Member]

Hi Viray,

Have a look at these good links-

<b>ALV all Imp</b>

http://www.geocities.com/mpioud/Abap_programs.html

http://www.sapdevelopment.co.uk/reporting/alvhome.htm

http://www.sapdevelopment.co.uk/reporting/alv/alvgrid_events.htm

<b>ALVGRID with refresh</b>

http://www.geocities.com/mpioud/Z_DEMO_ALV_REFRESH_BUTTON.html

<b>ALV Group Heading</b>

http://www.sap-img.com/fu037.htm

http://www.sap-img.com/abap/test-alv-display-with-header-footer.htm

http://www.sap-img.com/abap/sample-alv-heading-in-alv.htm

<b>ALV Documentation for Field</b>

http://www.mpls.k12.mn.us/sites/f7071225-9844-4da6-96c0-996b9c74b221/uploads/SAP_Navigation_Training...

http://www.geocities.com/mpioud/Z_ALV_CELL_COLOR.html

http://www.sap-img.com/abap/line-color-in-alv-example.htm

http://www.sapdevelopment.co.uk/reporting/alv/alvgrid_color.htm

<b>1. Please give me general info on ALV.</b>

http://www.sapfans.com/forums/viewtopic.php?t=58286

http://www.sapfans.com/forums/viewtopic.php?t=76490

http://www.sapfans.com/forums/viewtopic.php?t=20591

http://www.sapfans.com/forums/viewtopic.php?t=66305 - this one discusses which way should you use - ABAP Objects calls or simple function modules.

<b>2. How do I program double click in ALV?</b>

http://www.sapfans.com/forums/viewtopic.php?t=11601

http://www.sapfans.com/forums/viewtopic.php?t=23010

<b>3. How do I add subtotals (I have problem to add them)...</b>

http://www.sapfans.com/forums/viewtopic.php?t=20386

http://www.sapfans.com/forums/viewtopic.php?t=85191

http://www.sapfans.com/forums/viewtopic.php?t=88401

http://www.sapfans.com/forums/viewtopic.php?t=17335

<b>4. How to add list heading like top-of-page in ABAP lists?</b>

http://www.sapfans.com/forums/viewtopic.php?t=58775

http://www.sapfans.com/forums/viewtopic.php?t=60550

http://www.sapfans.com/forums/viewtopic.php?t=16629

<b>5. How to print page number / total number of pages X/XX in ALV?</b>

http://www.sapfans.com/forums/viewtopic.php?t=29597 (no direct solution)

<b>6. ALV printing problems. The favourite is: The first page shows the number of records selected but I don't need this.</b>

http://www.sapfans.com/forums/viewtopic.php?t=64320

http://www.sapfans.com/forums/viewtopic.php?t=44477

<b>7. How can I set the cell color in ALV?</b>

http://www.sapfans.com/forums/viewtopic.php?t=52107

<b>8. How do I print a logo/graphics in ALV?</b>

http://www.sapfans.com/forums/viewtopic.php?t=81149

http://www.sapfans.com/forums/viewtopic.php?t=35498

http://www.sapfans.com/forums/viewtopic.php?t=5013

<b>9. How do I create and use input-enabled fields in ALV?</b>

http://www.sapfans.com/forums/viewtopic.php?t=84933

http://www.sapfans.com/forums/viewtopic.php?t=69878

<b>10. How can I use ALV for reports that are going to be run in background?</b>

http://www.sapfans.com/forums/viewtopic.php?t=83243

http://www.sapfans.com/forums/viewtopic.php?t=19224

<b>11. How can I display an icon in ALV? (Common requirement is traffic light icon).</b>

http://www.sapfans.com/forums/viewtopic.php?t=79424

http://www.sapfans.com/forums/viewtopic.php?t=24512

<b>12. How can I display a checkbox in ALV?</b>

http://www.sapfans.com/forums/viewtopic.php?t=88376

http://www.sapfans.com/forums/viewtopic.php?t=40968

http://www.sapfans.com/forums/viewtopic.php?t=6919

<b>For language setting and decimal separator</b>

/people/horst.keller/blog/2004/11/16/abap-geek-7-150-babylonian-confusion

Mark useful answers.

Regards,

Tanuja.

[dhorions]

This document helped me a lot, <a href="https://www.sdn.sap.comhttp://www.sdn.sap.comhttp://www.sdn.sap.com/irj/sdn/go/portal/prtroot/docs/library/uuid/e8a1d690-0201-0010-b7ad-d9719a415907">An Easy Reference For ALV Grid Control</a>