backup

[Former Member]

Hi guys i need to download Customized text id (sap script). Can ypu help me wih this? i dont ve any idea how to perform that!

Moderator Message: If you need your thread to be noticed and get good suggestions, please provide a valid subject and a brief explanation of what is required.

Message was edited by: Kesavadas Thekkillath

[FredericGirod]

Hi,

try program RSTXSCRP

regards

Fred     

[Former Member]

Hello Kaushik

Refer standard program RSTXSCRP download/upload .It will help you.

or

Refer following link

http://saptechnical.com/Tips/SmartForms/Download/Script.htm

Katrice

[Former Member]

i know this program works only for standard text . But we have a customized text-id ? is there any way to download CUSTOMIZED TEXT-ID ?

[Former Member]

I need to do backup for those custom text-id? is there any way..help men out

[FredericGirod]

write your own program .. the function READ_TEXT is not so hard to use.

Fred

[Former Member]

Hi Frederic

           Can you give some idea about that ot logic  How to do that i am new to ABAP?

[Former Member]

Hi Kaushik,

For customized Text-ID go to transaction SO10.

Put the name & Text ID display the text -> TEXT-> Download

All the Standard and Custom TEXTID are stored in table STXH.

You can also display READ_TEXT function modules. Check all the FM in FG STXD.

Hope this helps.

Thanks,

Tooshar Bendale

[Former Member]

Hi fred,

        do you have any other solutions.

[FredericGirod]

I think Tooshar gives you all the informations

here an example code for standard text :

REPORT zsd_extr_vd52
       NO STANDARD PAGE HEADING
       LINE-SIZE 1023.

*------------------------------ TABLES -------------------------------*

TABLES : knmt ,
         makt ,
         kna1 ,
         stxh .

*------------------------------- DATA --------------------------------*

DATA : BEGIN OF itg_id OCCURS 0 ,
         tdid TYPE tdid ,
       END   OF itg_id ,

       BEGIN OF itg_data OCCURS 0 ,
         vkorg TYPE vkorg ,
         vtweg TYPE vtweg ,
         kunnr TYPE kunnr ,
         matnr TYPE matnr ,
         spart TYPE spart ,
       END   OF itg_data ,

       BEGIN OF itg_text OCCURS 0 ,
         vkorg    TYPE vkorg ,
         vtweg    TYPE vtweg ,
         kunnr    TYPE kunnr ,
         matnr    TYPE matnr ,
         spart    TYPE spart ,
         tdobject TYPE tdobject ,
         tdname   TYPE tdobname ,
         tdid     TYPE tdid ,
         tdspras  TYPE spras ,
       END   OF itg_text .

*------------------------- SELECTION - SCREEN ------------------------*

SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-t01.
SELECT-OPTIONS : s_vkorg FOR knmt-vkorg ,
                 s_vtweg FOR knmt-vtweg ,
                 s_kunnr FOR knmt-kunnr ,
                 s_matnr FOR knmt-matnr .
SELECTION-SCREEN SKIP 1.
SELECT-OPTIONS : s_tdid FOR stxh-tdid .
PARAMETERS : p_object TYPE tdobject
                      DEFAULT 'KNMT' ,
             p_spras  TYPE spras
                      DEFAULT sy-langu .
SELECTION-SCREEN END OF BLOCK b1.

*------------------------------- MAIN --------------------------------*

START-OF-SELECTION.

* Extraction des données.

  PERFORM p_get_data.

* Edition.

  PERFORM p_edition.

END-OF-SELECTION.

*---------------------------------------------------------------------*
*   Form P_GET_DATA.                                                  *
*---------------------------------------------------------------------*
*---------------------------------------------------------------------*

FORM p_get_data.

  DATA : w_tdname TYPE tdobname ,
       BEGIN OF it_stxh OCCURS 0 ,
         tdobject TYPE tdobject ,
         tdname   TYPE tdobname ,
         tdid     TYPE tdid ,
         tdspras  TYPE spras ,
       END   OF it_stxh .

* Extraction.

  CASE p_object.
    WHEN 'KNMT'.
      SELECT vkorg vtweg kunnr matnr
             INTO TABLE itg_data
             FROM knmt
             WHERE vkorg IN s_vkorg
             AND   vtweg IN s_vtweg
             AND   kunnr IN s_kunnr
             AND   matnr IN s_matnr.
      SORT itg_data BY vkorg vtweg kunnr matnr.

*     Recherche des textes.

      LOOP AT itg_data.
        CONCATENATE itg_data-vkorg
                    itg_data-vtweg
                    itg_data-kunnr
                    itg_data-matnr
                    INTO w_tdname.
        SELECT tdobject tdname tdid tdspras
               INTO TABLE it_stxh
               FROM stxh
               WHERE tdobject EQ p_object
               AND   tdname   EQ w_tdname
               AND   tdid     IN s_tdid
               AND   tdspras  EQ p_spras.
        LOOP AT it_stxh.
          MOVE-CORRESPONDING : itg_data TO itg_text ,
                               it_stxh TO itg_text.
          APPEND itg_text.
        ENDLOOP.
      ENDLOOP.
      SORT itg_text BY tdname tdid.
    WHEN 'KNA1'.
      SELECT kunnr
           INTO CORRESPONDING FIELDS OF TABLE itg_data
           FROM kna1
           WHERE kunnr IN s_kunnr.
      SORT itg_data BY kunnr.

*     Recherche des textes.

      LOOP AT itg_data.
        MOVE itg_data-kunnr TO w_tdname.
        SELECT tdobject tdname tdid tdspras
               INTO TABLE it_stxh
               FROM stxh
               WHERE tdobject EQ p_object
               AND   tdname   EQ w_tdname
               AND   tdid     IN s_tdid
               AND   tdspras  EQ p_spras.
        LOOP AT it_stxh.
          MOVE-CORRESPONDING : itg_data TO itg_text ,
                               it_stxh TO itg_text .
          APPEND itg_text.
        ENDLOOP.
      ENDLOOP.
      SORT itg_text BY tdname tdid.
    WHEN 'KNVV'.
      SELECT vkorg vtweg kunnr spart
             INTO CORRESPONDING FIELDS OF TABLE itg_data
             FROM knvv
             WHERE kunnr IN s_kunnr
             AND   vkorg IN s_vkorg
             AND   vtweg IN s_vtweg.
      SORT itg_data BY vkorg vtweg kunnr matnr.

*     Recherche des textes.

      LOOP AT itg_data.
        CONCATENATE itg_data-kunnr
                    itg_data-vkorg
                    itg_data-vtweg
                    itg_data-spart
                    INTO w_tdname.
        SELECT tdobject tdname tdid tdspras
               INTO TABLE it_stxh
               FROM stxh
               WHERE tdobject EQ p_object
               AND   tdname   EQ w_tdname
               AND   tdid     IN s_tdid
               AND   tdspras  EQ p_spras.
        LOOP AT it_stxh.
          MOVE-CORRESPONDING : itg_data TO itg_text ,
                               it_stxh TO itg_text .
          APPEND itg_text.
        ENDLOOP.
      ENDLOOP.
      SORT itg_text BY tdname tdid.
  ENDCASE.

* Extraction des IDs.

  LOOP AT itg_text.
    MOVE itg_text-tdid TO itg_id-tdid.
    APPEND itg_id.
  ENDLOOP.
  SORT itg_id BY tdid.
  DELETE ADJACENT DUPLICATES FROM itg_id COMPARING tdid.

ENDFORM. " P_GET_DATA

*---------------------------------------------------------------------*
*   Form P_EDITION.                                                   *
*---------------------------------------------------------------------*
*---------------------------------------------------------------------*

FORM p_edition.

  DATA :

*        w_tdname TYPE tdobname ,

         w_buff   TYPE string ,
         w_buff2  TYPE string ,

         is_line  TYPE tline ,

         it_lines TYPE tline_tab.

  SORT itg_text BY vkorg vtweg kunnr matnr tdid.
  SORT itg_data BY vkorg vtweg kunnr matnr .

* En-tete.

  CONCATENATE 'Orga. Comm.'
              'Client'
              'Article'
              INTO w_buff
              SEPARATED BY ';'.
  LOOP AT itg_id.
    CONCATENATE w_buff
                itg_id-tdid
                INTO w_buff
                SEPARATED BY ';'.
  ENDLOOP.
  WRITE : /1 w_buff.

* Boucle.

  LOOP AT itg_data.
    CLEAR w_buff.

    CONCATENATE itg_data-vkorg
                itg_data-kunnr
                itg_data-matnr
                INTO w_buff
                SEPARATED BY ';'.

*   Boucle sur les types de textes.

    LOOP AT itg_id.

*     Recherche si texte correspondant.

      READ TABLE itg_text
           WITH KEY vkorg = itg_data-vkorg
                    vtweg = itg_data-vtweg
                    kunnr = itg_data-kunnr
                    matnr = itg_data-matnr
                    tdid  = itg_id-tdid
           BINARY SEARCH.
      IF sy-subrc EQ space.
        REFRESH it_lines.
        CLEAR : is_line, w_buff2.
        CALL FUNCTION 'READ_TEXT'
          EXPORTING
            id       = itg_text-tdid
            language = itg_text-tdspras
            name     = itg_text-tdname
            object   = itg_text-tdobject
          TABLES
            lines    = it_lines
          EXCEPTIONS
            OTHERS   = 8.
        LOOP AT it_lines
             INTO is_line.
          CONCATENATE w_buff2
                      is_line-tdline
                      INTO w_buff2
                      SEPARATED BY ' '.
        ENDLOOP.
        CONCATENATE w_buff
                    w_buff2
                    INTO w_buff
                    SEPARATED BY ';'.
      ENDIF.
    ENDLOOP.
    WRITE /1 w_buff.
  ENDLOOP.

ENDFORM. " P_EDITION.