ALV coloring help

[Former Member]

Hi all,

Hi I have 2 requirements in ALV.

1) my third field is Sales Organisation.I have to make the column heading of this column intesified.

2)In the top of page I have to color a particular line.

Please suggest some solution as soon as possible as I need it very urgently...

Thanks

Nazmul

[Former Member]

Hi all,

Hi I have 2 requirements in ALV.

1) my third field is Sales Organisation.I have to make the column heading of this column intesified.

2)In the top of page I have to color a particular line.

Please suggest some solution as soon as possible as I need it very urgently...

Thanks

Nazmul

[Former Member]

Hi,

Check out the column options in the layout which u r using like

in slis u have many options for color and for column headings.

Hope this helps.

Regds

Seema

[Former Member]

you can show the color in the Top of page .

Check this..

and also check this

report  ztest_page.

tables: sflight.
data : it_flight type table of sflight with header line.
data begin of it_sel_opt occurs 0.
        include structure rsparams.
data end   of it_sel_opt.
select-options: s_carrid for sflight-carrid.

start-of-selection.

  select * from sflight into table it_flight
   where carrid in s_carrid.

end-of-selection.

  call function 'RS_REFRESH_FROM_SELECTOPTIONS'
    exporting
      curr_report     = sy-repid
    tables
      selection_table = it_sel_opt
    exceptions
      not_found       = 01
      no_report       = 02.

  call function 'REUSE_ALV_GRID_DISPLAY'
    exporting
      i_callback_program          = sy-repid
      i_callback_html_top_of_page = 'TOP_OF_PAGE'
      i_structure_name            = 'SFLIGHT'
    tables
      t_outtab                    = it_flight
    exceptions
      program_error               = 1
      others                      = 2.

*&---------------------------------------------------------------------*
*&      Form  top_of_page
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->DOCUMENT   text
*----------------------------------------------------------------------*
form top_of_page using document type ref to cl_dd_document.
  data : dl_text(255) type c.  "Text

* Add new-line
  call method document->new_line.

  call method document->new_line.

  clear : dl_text.
* program ID
  dl_text = 'Program Name :'.
  call method document->add_gap.
  call method document->add_text
    exporting
      text         = dl_text
      sap_emphasis = cl_dd_area=>heading
      sap_color    = cl_dd_area=>list_heading_int.

  clear dl_text.
  dl_text = sy-repid.
  call method document->add_text
    exporting
      text         = dl_text
      sap_emphasis = cl_dd_area=>heading
      sap_color    = cl_dd_area=>list_negative_inv.

* Add new-line
  call method document->new_line.
  clear : dl_text.

  dl_text = 'Selection Criteria'.
  call method document->add_gap
    exporting
      width = 34.
  call method document->add_text
    exporting
      text         = dl_text
      sap_emphasis = cl_dd_area=>heading
      sap_color    = cl_dd_area=>list_negative_inv.

* Add new-line
  call method document->new_line.

  clear : dl_text.
  concatenate 'SELECT Option' 'SIGN' 'OPTION' 'LOW' 'HIGH'
  into dl_text separated by cl_abap_char_utilities=>horizontal_tab.

  call method document->add_gap
    exporting
      width = 34.
  call method document->add_text
    exporting
      text         = dl_text
      sap_emphasis = cl_dd_area=>heading
      sap_color    = cl_dd_area=>list_negative_inv.

* Add new-line
  call method document->new_line.
  loop at it_sel_opt.

    clear : dl_text.
    concatenate it_sel_opt-selname  it_sel_opt-sign
     it_sel_opt-option it_sel_opt-low it_sel_opt-high
    into dl_text separated by cl_abap_char_utilities=>horizontal_tab.

    call method document->add_gap
      exporting
        width = 34.
    call method document->add_text
      exporting
        text         = dl_text
        sap_emphasis = cl_dd_area=>heading
        sap_color    = cl_dd_area=>list_negative_inv.
* Add new-line
    call method document->new_line.

  endloop.

endform.                    "top_of_page