Bopf annotation did not successfully generate BO object, how to check the error?

[former_member595718]

Hi:

My system info:NetWeaver 753 OP1809

Development Tools info :

Eclipse 2019-09 (Eclipse IDE for Java Developers),

ADT:For Eclipse 2019-09 (4.13), add the URL https://tools.hana.ondemand.com/2019-09

Follow this tutorial https://help.sap.com/viewer/cc0c305d2fab47bd808adcad3ca7ee9d/1709.004/en-US/fc2bab778312480a8bc0d982...

However, following the tutorial I cannot create my BO.

Bopf annotation did not successfully generate BO object, how to check the error?

[maheshpalavalli]

Could you share us the code screenshot? Or paste the code..

[former_member595718]

the code at :https://help.sap.com/viewer/cc0c305d2fab47bd808adcad3ca7ee9d/1709.004/en-US/fc2bab778312480a8bc0d982...

@AbapCatalog.sqlViewName: 'ZDEMO_I_SOH_V'
				
@AccessControl.authorizationCheck: #NOT_REQUIRED
				
@EndUserText.label: 'Sales order for transactional app'
				
@Search.searchable: true
				
@ObjectModel: {
				
	-- Annotations for transactional processing
	semanticKey: 'SalesOrder',
	compositionRoot: true,  
	transactionalProcessingEnabled: true, 
	createEnabled: true,
	deleteEnabled: true,
	updateEnabled: true,
	writeActivePersistence: 'ZDEMO_SOH',
				
	-- Additional annotations for draft enablement    
	draftEnabled: true,
	writeDraftPersistence: 'ZDEMO_SOH_D', 
	
	-- Additional ETag annotation (time stamp)
	entityChangeStateId: 'ChangedAt' 
}
				
define view ZDEMO_I_SalesOrder_TP_D
				
	as select from zdemo_soh as SalesOrder  -- the sales order table is the data source for this view
				
	/* Cross BO associations       */
	association [0..1] to SEPM_I_BusinessPartner            as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
				
	/* Associations for value help */
	association [0..1] to Sepm_I_SalesOrdOverallStatus      as _OverallStatus   on $projection.OverallStatus    = _OverallStatus.SalesOrderOverallStatus    
				
{        
	-- UUID-based key is required to enable draft capabilities
	@ObjectModel.readOnly: true
	key SalesOrder.salesorderuuid      as SalesOrderUUID,
				
	@Search.defaultSearchElement: true
	@ObjectModel.readOnly: true
	SalesOrder.salesorder               as SalesOrder, 
				
	@ObjectModel.foreignKey.association: '_BusinessPartner'
	SalesOrder.businesspartner          as BusinessPartner,       
						
	@Search.defaultSearchElement: true
	@ObjectModel.foreignKey.association: '_OverallStatus'
	SalesOrder.overallstatus            as OverallStatus,
	
	@Semantics.systemDateTime.lastChangedAt: true
	SalesOrder.changedat                as ChangedAt,
    
    @Semantics.systemDateTime.createdAt: true
    SalesOrder.createdat                as CreatedAt,
    @Semantics.user.createdBy: true
    SalesOrder.createdby                as CreatedBy,
    @Semantics.user.lastChangedBy: true
    /*SalesOrder.changedby                as ChangedeBy,   error: One more letter e at  ChangedeBy */
    SalesOrder.changedby                as ChangedBy, 
				
	/* Associations */ 
	_BusinessPartner,
	_OverallStatus     
				
} 

[kochs123]

I got exactly the same issue, does anyone have an idea?

System: SAP NetWeaver AS ABAP Developer Edition 7.52 SP04

Thanks.

[ivo_vollrath]

You could check if you find some information in the BOPF BO generation log. You find it in transaction SLG1. Select Options:

Object: /BOBF/

Subobject: CDS_BO_SYNC

External ID: <your BO name>

[former_member531973]

Hi,

try applying the following notes:

1. 2912964 - No error message if constants interface cannot be generated

2. 2922978 - Note containing BOPF object changes cannot be applied due to timestamp differences

3. 2948149 BOPF objects are not generated from CDS view

Giulia

[former_member983279]

Hi,

had the same issue when trying out SAP NW 7.52 Trial Version. Via debugging I found out that the root cause was the wrong transport layer of the CDS' transport request. /The layer is used to determin that your system is a dev system and not a production system.) In my case, the layer was SAP as I did not configure any transport queues. There is a check method called /BOBF/CL_CONF_CDS_LINK->_in_dev_or_correction_system( ) which fails in this constellation, see the attached screenshots.

Maybe this helps.

Cheers,

Chris

[ivo_vollrath]

Great Hint! Note that SAP Note 2948149 - BOPF objects are not generated from CDS view provides a correction of the piece of code that you highlighted. Maybe it helps in your case, as well.

[former_member983279]

My fault, I've missed this SAP Note, although Ms. Modugno had already mentioned it.