i want use multiple read statement in for loop

[rishi_kulkarni123]

hello All,

I am looking for some help in understanding the concept of for loop.

I am using a for loop where i am read the value from table if the value is not present then i want to take from other table 

 old code 
  LOOP AT IT_VBRK_VBRP ASSIGNING <WA_VBRK_VBRP>.
      CLEAR: WA_VBKD_A.
      READ TABLE I_VBKD_A INTO WA_VBKD_A WITH KEY VBELN = <WA_VBRK_VBRP>-AUBEL
                                                  POSNR = <WA_VBRK_VBRP>-AUPOS .
      IF SY-SUBRC <> 0.
        READ TABLE I_VBKD_A INTO WA_VBKD_A WITH KEY VBELN = <WA_VBRK_VBRP>-AUBEL
                                                    POSNR = '000000'.
        IF SY-SUBRC = 0.
          <WA_VBRK_VBRP>-BSTKD = WA_VBKD_A-BSTKD.
        ENDIF.
      ELSE.
        <WA_VBRK_VBRP>-BSTKD = WA_VBKD_A-BSTKD.
      ENDIF.
endloop.



New code which i want to optimize 
 IT_VBRK_VBRP_1[] = VALUE #( FOR <WA_VBRK_VBRP> IN IT_VBRK_VBRP[] (
        BSTKD = COND #( LET WA_VBKD_A = VALUE #( I_VBKD_A[ VBELN = <WA_VBRK_VBRP>-AUBEL
                                                           POSNR = <WA_VBRK_VBRP>-AUPOS  ] ) IN
                      WHEN WA_VBKD_A IS NOT INITIAL
                      THEN WA_VBKD_A-BSTKD
                      ELSE I_VBKD_A[ VBELN = <WA_VBRK_VBRP>-AUBEL
                                     POSNR = '00000'  ]-BSTKD ) ) ) .

For Above code i am getting dump ITAB_LINE_NOT_FOUND even though the line is there so i need to know how to handle if the line does not exists. 

@Sandra_Rossi 

@SAPSupport 

@RaymondGiuseppi 

[Sandra_Rossi]

First of all, why are you rewriting it? It's not clearer than before, it's not faster than before, it's just using syntax 7.40.

The new way is even slower in your case.

I'd say that you should not use a Constructor Expression if you "update". Such expressions are used to "create", not to update (hence the name "Constructor Expression").

[Sandra_Rossi]

To avoid the exception "line not found" for a Table Expression, you have to add OPTIONAL (or DEFAULT, or TRY cx_sy_itab_line_not_found outside constructor expressions). See the ABAP Keyword documentation for more information. In your case, you may use a statement like

... LET ref_to_line = REF #( I_VBKD_A[ VBELN = '...' ] OPTIONAL ) 
    IN
    ... = COND #( WHEN ref_to_line IS BOUND 
                  THEN ref_to_line->bstkd ... )

[rishi_kulkarni123]

Hi @Sandra_Rossi i want to know is it possible that if first read statement is failed in above code then it should read the second read statement

[Sandra_Rossi]

I guess you understood my answer, and you can adapt it to solve your issue

[rishi_kulkarni123]

@Sandra_Rossi  I have done some R&D and found the solution to make code work according to requirement

    IT_VBRK_VBRP_1[] = VALUE #( FOR <WA_VBRK_VBRP> IN IT_VBRK_VBRP[] (
    """""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
        BSTKD = COND #( LET WA_VBKD_A = VALUE #( I_VBKD_A[ VBELN = <WA_VBRK_VBRP>-AUBEL
                                                           POSNR = <WA_VBRK_VBRP>-AUPOS  ] OPTIONAL )
                             WA_FALLBACK = VALUE #( I_vbkd_a[ VBELN = <WA_VBRK_VBRP>-AUBEL
                                             POSNR = '000000' ] OPTIONAL ) IN
                      WHEN WA_VBKD_A IS NOT INITIAL
                      THEN WA_VBKD_A-BSTKD
                      ELSE WA_FALLBACK-BSTKD )
    """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
                      ) ) .

[Sandra_Rossi]

Good to know. I hope that you also understood that this statement will be slower than the classic form, and so it was not a good candidate to use a constructor expression.