Field symbol has not been assigned yet in ALV

[former_member2492]

I have the following code:

  CLEAR: go_t1.

  SELECT *
    FROM mara
    INTO TABLE @DATA(gt_mara)
    UP TO 10 ROWS.

  CREATE OBJECT go_t1
    EXPORTING
      container_name = 'CONTAINER'.

  CREATE OBJECT go_splitter
    EXPORTING
      parent  = go_t1
      rows    = 2
      columns = 1.

  CALL METHOD go_splitter->get_container
    EXPORTING
      row       = 1
      column    = 1
    RECEIVING
      container = o_grid.

  CALL METHOD go_splitter->get_container
    EXPORTING
      row       = 2
      column    = 1
    RECEIVING
      container = o_grid1.
  TRY.
      cl_salv_table=>factory(
          EXPORTING
          r_container = o_grid
          IMPORTING
          r_salv_table = alv
          CHANGING
          t_table = gt_mara ).

    CATCH cx_salv_msg
         cx_salv_not_found
         cx_salv_data_error
         cx_salv_existing
         cx_salv_wrong_call INTO DATA(lo_x).
      MESSAGE lo_x TYPE 'E'.
  ENDTRY.

        alv->display( ).

and I am getting the the following error : Field symbol has not been assigned yet.
and I have no idea why this is happening...

[FredericGirod]

could you give the call stack of the dump ?

[former_member2492]

frdric.girod is this what you mean?

FUNCTION LVC_FILL_DATA_TABLE.
*"--------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(I_VIEW) TYPE  UI_FUNC OPTIONAL
*"     REFERENCE(I_GUI_TYPE) TYPE  INT4 OPTIONAL
*"     REFERENCE(I_START_INDEX) TYPE  I
*"     REFERENCE(I_END_INDEX) TYPE  I

[FredericGirod]

no, when the error occurs, you should have a dump --> trans ST22. In this dump, you have a part : Call Stack

this is the stack of the successive call (method/program/form) that put you in this specific line of code that dump

[former_member2492]

frdric.girod I only have this Active Calls events, cant find a Call Stack in my dump

23 FUNCTION     SAPLSLVC                            LSLVCU26                                1
   LVC_FILL_DATA_TABLE
22 METHOD       CL_SALV_GUI_GRID_FACADE=======CP    CL_SALV_GUI_GRID_FACADE=======CM00Z     9
   CL_SALV_GUI_GRID_FACADE=>DO_PAGING_OPTIMIZED
21 METHOD       CL_SALV_GUI_GRID_FACADE=======CP    CL_SALV_GUI_GRID_FACADE=======CM00X    22
   CL_SALV_GUI_GRID_FACADE=>IF_SALV_GUI_GRID_LVC_DATA~GET_DATA_PACKAGE

[FredericGirod]

it's a good beginning, but you need to have more than level 23, 22, 21 with this, you will understand which action is creating an issu in your ALV grid

your container is

TYPE REF TO cl_gui_container. 

[former_member2492]

frdric.girod yes it is. do you think this is the problem? but how should it be?

[former_member2492]

  12 METHOD       CL_DATAPTABLECACHE============CP    CL_DATAPTABLECACHE============CM00F    32
     CL_DATAPTABLECACHE=>IF_DATAPONDEMAND~ON_REQUEST_DATA
  11 METHOD       CL_GUI_DATAPONDEMAND==========CP    CL_GUI_DATAPONDEMAND==========CM003    16
     CL_GUI_DATAPONDEMAND=>DATAREQUEST
  10 METHOD       CL_GUI_DATAMANAGER============CP    CL_GUI_DATAMANAGER============CL      992
     LCL_MYDATAREQUESTCONSUMER=>ONEXECUTE
   9 METHOD       CL_GUI_DATAMANAGER============CP    CL_GUI_DATAMANAGER============CL      215
     LCL_MYXMLCONSUMER=>ONTAGEND
   8 METHOD       CL_GUI_DATAMANAGER============CP    CL_GUI_DATAMANAGER============CL     2178
     LCL_MYXMLPARSER=>ABAP_PARSE
   7 METHOD       CL_GUI_DATAMANAGER============CP    CL_GUI_DATAMANAGER============CL     1422
     LCL_MYXMLPARSER=>PARSE
   6 METHOD       CL_GUI_DATAMANAGER============CP    CL_GUI_DATAMANAGER============CM002     3
     CL_GUI_DATAMANAGER=>PARSE_INPUT
   5 METHOD       CL_GUI_DATAMANAGER============CP    CL_GUI_DATAMANAGER============CM001    46
     CL_GUI_DATAMANAGER=>ON_INPUT
   4 FORM         SAPFGUICNTL                         SAPFGUICNTL                           348
     HANDLE_DIAG_INPUT_DATA
   3 FORM         SAPMSSYD                            SAPMSSYD                              588
     DIAG_XML_HANDLING
   2 FORM         SAPMSSYD                            SAPMSSYD                              324
     %_CTL_INPUT
   1 MODULE (PAI) SAPMSSYD                            SAPMSSYD                              290
     %_CTL_INPUT1

[Sandra_Rossi]

Thank you for posting that minimal reproducible example, people rarely do that in SAP community.

[former_member2492]

sandra.rossi please test it from your side and let me know how it works...

[Sandra_Rossi]

In fact, your code was not completely "minimal reproducible" (syntax errors), so I posted one in an answer below.

[Sandra_Rossi · Accepted solution]

Be careful to NOT declare the ALV internal table as local, otherwise you will have a short dump (it may not be immediate, it depends on the global quantity of data (total number of bytes/characters of all cells displayed / versus given amount of bytes/characters buffered on frontend); if not immediate, it may happen after a number of ALV page scrolling, when the frontend needs to acquire more data of the internal table from the backend).

I don't reproduce the bug with this minimal reproducible program:

REPORT.
DATA: go_splitter TYPE REF TO cl_gui_splitter_container,
      o_grid      TYPE REF TO cl_gui_container,
      alv         TYPE REF TO cl_salv_table,
      gt_mara     TYPE TABLE OF mara.

PARAMETERS dummy.

AT SELECTION-SCREEN OUTPUT.
  CHECK go_splitter IS NOT BOUND.
  SELECT *
    FROM mara
    INTO TABLE gt_mara
  UP TO 10 ROWS.

  CREATE OBJECT go_splitter
    EXPORTING
      parent  = cl_gui_container=>screen0
      rows    = 2
      columns = 1.

  CALL METHOD go_splitter->get_container
    EXPORTING
      row       = 1
      column    = 1
    RECEIVING
      container = o_grid.

  TRY.
      cl_salv_table=>factory(
          EXPORTING
          r_container = o_grid
          IMPORTING
          r_salv_table = alv
          CHANGING
          t_table = gt_mara ).

    CATCH cx_salv_msg
         cx_salv_not_found
         cx_salv_data_error
         cx_salv_existing
         cx_salv_wrong_call INTO DATA(lo_x).
      MESSAGE lo_x TYPE 'I' DISPLAY LIKE 'E'.
  ENDTRY.

  alv->display( ).

[former_member2492 · Accepted solution]

thank you, it solved my problem

[aoyang]

Is the program trying to display 2 ALV in one screen? If so, custom dynpro needs to be defined and container needs to be embedded there.

(1) Define a custom dynpro 9xxx and click on custom control button. Then enter each containers name there. Sample screen in screenshot.

(2) Call screen 9xxx in the program.

(3) In PBO module, create field catalog, get data from MARA, instatiate container and grid object. Then call method SET_TABLE_FOR_FIRST_DISPLAY for each container.

I made a demo so please take a look at below code and screenshots.

Please mark this as answer if it solved your requirement.

REPORT YDEMO.

DATA:GO_T     TYPE REF TO CL_GUI_CUSTOM_CONTAINER,
     GO_T1    TYPE REF TO CL_GUI_CUSTOM_CONTAINER,
     O_GRID   TYPE REF TO CL_GUI_ALV_GRID,
     O_GRID1  TYPE REF TO CL_GUI_ALV_GRID,
     X_LAYOUT TYPE LVC_S_LAYO.

X_LAYOUT-SEL_MODE = 'A'.


CALL SCREEN 9000.

BREAK-POINT.
*&---------------------------------------------------------------------*
*& Module STATUS_9000 OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE STATUS_9000 OUTPUT.

  DATA: LS_FIELDCAT TYPE LVC_S_FCAT,
        LT_FIELDCAT TYPE LVC_T_FCAT.

  LS_FIELDCAT-FIELDNAME = 'MATNR'.
  LS_FIELDCAT-SCRTEXT_S = 'Material'.                       "#EC NOTEXT
  LS_FIELDCAT-SCRTEXT_M = 'Material'.                       "#EC NOTEXT
  LS_FIELDCAT-SCRTEXT_L = 'Material'.                       "#EC NOTEXT
  LS_FIELDCAT-COL_POS   = 1.
  APPEND LS_FIELDCAT TO LT_FIELDCAT.

  LS_FIELDCAT-FIELDNAME = 'ERNAM'.
  LS_FIELDCAT-SCRTEXT_S = 'User name'.                      "#EC NOTEXT
  LS_FIELDCAT-SCRTEXT_M = 'User name'.                      "#EC NOTEXT
  LS_FIELDCAT-SCRTEXT_L = 'User name'.                      "#EC NOTEXT
  LS_FIELDCAT-COL_POS   = 2.
  APPEND LS_FIELDCAT TO LT_FIELDCAT.

  CLEAR: GO_T, GO_T1.

  SELECT MATNR, ERNAM
    FROM MARA
    INTO TABLE @DATA(GT_MARA)
    UP TO 10 ROWS.

  GO_T = NEW #( CONTAINER_NAME = 'CONTAINER' ).
  O_GRID = NEW #( I_PARENT = GO_T ).

  GO_T1 = NEW #( CONTAINER_NAME = 'CONTAINER1' ).
  O_GRID1 = NEW #( I_PARENT = GO_T1 ).

  CALL METHOD O_GRID->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      I_SAVE          = 'A'
      IS_LAYOUT       = X_LAYOUT
    CHANGING
      IT_OUTTAB       = GT_MARA
      IT_FIELDCATALOG = LT_FIELDCAT.

  CALL METHOD O_GRID1->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      I_SAVE          = 'A'
      IS_LAYOUT       = X_LAYOUT
    CHANGING
      IT_OUTTAB       = GT_MARA
      IT_FIELDCATALOG = LT_FIELDCAT.

ENDMODULE.
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_9000  INPUT
*&---------------------------------------------------------------------*
MODULE USER_COMMAND_9000 INPUT.

  DATA: LT_ROWS TYPE LVC_T_ROW,
        LT_ROID TYPE LVC_T_ROID.

  O_GRID->CHECK_CHANGED_DATA( ).

  CALL METHOD O_GRID->GET_SELECTED_ROWS
    IMPORTING
      ET_INDEX_ROWS = LT_ROWS
      ET_ROW_NO     = LT_ROID.

ENDMODULE.

[former_member2492]

Hi,I need to use cl_salv_table due to the functionality(need to get the selected rows)

[aoyang]

It's possible to get the selected row with GET_SELECTED_ROWS method. I've updated the code. The returned selected rows are visible in PAI in LT_ROWS and LT_ROID.