DATA MANAGER PACKAGE TAKING HOURS TO SUCCEED

[Former Member]

Data Manager package taking 9 hours to succeed. We have recently upgraded system from BPC standard 10.0 to 10.1. Before upgrade it used to take 2-3 minutes. We have multiple packages but facing issue with only one package. Package is based on Logic script. Logic script is performing simple multiplications. Logic script is hardly generating 300 records. In logs query processing time is very high.

System info

/CPMBPC : Release- 810 Release -10 SP15

/BW: Release- 7.40, SP 15

I have cleared LOG files, Audit archived files, Light Optimization

[former_member34]

Thank you for visiting SAP Community to get answers to your questions. Since this is your first question, I recommend that you familiarize yourself with our Q&A Tutorial: https://developers.sap.com/tutorials/community-qa.html, as it provides tips for preparing questions that draw responses from our members. Should you wish, you can revise your question by selecting Actions, then Edit.

By adding a picture to your profile you encourage readers to respond: https://www.youtube.com/watch?v=46bt1juWUUM

Many thanks!

[former_member186338]

How it's possible to help you without script text and detailed explanation???

[former_member186338]

Sorry, but you decided to stop participating in SAP Community...

[former_member186338]

I recommend to remove all COMMIT's from this script and use scoping only for changes!

The resulting script will be:

//This logic script will be used to calculate closing net worth in INRC
//This logic script will be used to convert Final Consolidated USD amounts into INR

//Fetch Exchange rate from Rate Model
*LOOKUP EX_RATES
*DIM INR_CLO:R_ACCOUNT = "CLO"
*DIM INR_CLO:R_ENTITY = "GLOBAL"
*DIM INR_CLO:INPUTCURRENCY = "INR"
*ENDLOOKUP

*XDIM_MEMBERSET CATEGORY = %CATEGORY_SET%
*XDIM_MEMBERSET SCOPE = S_SCOPE
*XDIM_MEMBERSET TIME = %TIME_SET%
*XDIM_MEMBERSET SEGMENT = BAS(ALL_SEG)
*XDIM_MEMBERSET INTERCO = BAS(TotalInterco)
*XDIM_MEMBERSET ENTITY = BAS(V_SUBSIDIARY),BAS(X_SUBSIDIARY),BAS(VL)
*XDIM_MEMBERSET AUDITTRAIL = BAS(AUDITTOTAL)

//Multiply FLOWS with Closing rate
*XDIM_MEMBERSET ACCOUNT = BAS(BS2127),BAS(BS2128),BAS(BS2129),S_BS2124,S_BS2125
*XDIM_MEMBERSET RPTCURRENCY = USD
*XDIM_MEMBERSET FLOW = BAS(F_MOVEMENT)

*WHEN ACCOUNT
*IS *
*REC(EXPRESSION = %VALUE%*LOOKUP(INR_CLO), RPTCURRENCY = INRC)
*ENDWHEN

//Calculation of closing net worth in INRC
*XDIM_MEMBERSET ACCOUNT = BAS(BS2127),BAS(BS2128),BAS(BS2129)
*XDIM_MEMBERSET RPTCURRENCY = INRC
*XDIM_MEMBERSET FLOW = BAS(F_TOTAL)

*WHEN ACCOUNT
*IS *
*REC(FACTOR = 1, RPTCURRENCY = INRC, FLOW = F_CLO)
*ENDWHEN

//Eliminations of Dividend
*XDIM_MEMBERSET AUDITTRAIL =DIVIDENDADJ

*XDIM_MEMBERSET ACCOUNT = S_BS2124_4,S_BS2125_5
*XDIM_MEMBERSET RPTCURRENCY = USD
*XDIM_MEMBERSET FLOW = F_CLO

*WHEN ACCOUNT
*IS *
*REC(EXPRESSION = %VALUE%*LOOKUP(INR_CLO),RPTCURRENCY = INRC)
*ENDWHEN

//General Reserve Calculation
//Calculation of Opening Genaral Reserve in INRC
*XDIM_MEMBERSET AUDITTRAIL = BAS(AUDITTOTAL)
*XDIM_MEMBERSET FLOW = F_OPE
*XDIM_MEMBERSET RPTCURRENCY = INRC

*XDIM_MEMBERSET ACCOUNT = BAS(BS2124)

*WHEN RPTCURRENCY
*IS *
*REC(FACTOR = 1,ACCOUNT = S_BS2124_6, FLOW = F_CLO)
*ENDWHEN

//Calculation of Closing Transfer to DRR for XYZ (Genaral Reserve) in INRC
*XDIM_MEMBERSET ENTITY = XYZ

*XDIM_MEMBERSET ACCOUNT = S_BS2124_2,S_BS2124_6

*WHEN RPTCURRENCY
*IS *
*REC(FACTOR = 1,ACCOUNT = S_BS2124_6, FLOW = F_CLO)
*ENDWHEN

//Conversion of  Genaral Reserve movements during the year to closing in INRC
*XDIM_MEMBERSET ENTITY = BAS(V_SUBSIDIARY),BAS(X_SUBSIDIARY),BAS(VL)
*XDIM_MEMBERSET FLOW = BAS(F_MOVEMENT)

*XDIM_MEMBERSET ACCOUNT = BAS(BS2124)

*WHEN ACCOUNT
*IS *
*REC(FACTOR = 1, FLOW = F_CLO)
*ENDWHEN

//Retained Earning Calculation
//Calculation of Opening Retained Earning in INRC
*XDIM_MEMBERSET ENTITY = BAS(TOP_GRP)

*XDIM_MEMBERSET ACCOUNT = BAS(BS2125)
*XDIM_MEMBERSET FLOW = F_OPE

*WHEN RPTCURRENCY
*IS *
*REC(FACTOR = 1,ACCOUNT = S_BS2125_10, FLOW = F_CLO)
*ENDWHEN

//Copy Movements of XYZ INR Consol trial to INRC
*XDIM_MEMBERSET ENTITY = XYZ 
*XDIM_MEMBERSET FLOW = BAS(F_MOVEMENT)

*XDIM_MEMBERSET ACCOUNT = BAS(BS2125)
*XDIM_MEMBERSET RPTCURRENCY = INR

*WHEN ACCOUNT
*IS *
*REC(FACTOR = 1, RPTCURRENCY = INRC)
*ENDWHEN

//Conversion of  Retained Earnings movements during the year to closing in INRC
*XDIM_MEMBERSET ENTITY = BAS(V_SUBSIDIARY),BAS(X_SUBSIDIARY),BAS(VL)

*XDIM_MEMBERSET ACCOUNT = BAS(BS2125)
*XDIM_MEMBERSET RPTCURRENCY = INRC

*WHEN ACCOUNT
*IS *
*REC(FACTOR = 1, FLOW = F_CLO)
*ENDWHEN

[Former Member]

Thanks Vadim but the original script was earlier working fine with 3-4 minutes time. Why does it giving trouble now as per your understanding ?