How to add a level in Concur via BADI_CTE_FIN_COBJ_FILL_LEVEL

[dr_ajt]

I need to add profit center to the data sent to Concur. I believe that it needs to be configured via the CTE_SETUP transaction Setting Up the Cost Center Export wizard. Then inserting into the data via the BAdI BADI_CTE_FIN_COBJ_FILL_LEVEL.

Unfortunately I do have an example code to compare it against, even for a different kind of data. Does anyone have any examples of using this BAdI, even for other data elements?

[rfsky]

Hi Adam,

I know you posted the question on BADI_CTE_FIN_COBJ_FILL_LEVEL a while ago but did you ever figure out how to use this badi to populate codes and values for a customer-specific list level within the Concur list ?

Any details or examples much appreciated.

Thanks,

Richard

[dr_ajt]

rfraser,

Yes I think I was able to solve my problem in the end. I will find the code I used and post here, if not I'll confirm I was never able to solve the problem...

dr_ajt

[rfsky]

Ok. Thanks. Much appreciated.

[rfsky]

Thanks Adam. Very useful, so appreciate your input.

[dr_ajt · Accepted solution]

Okay, the documentation from SAP Concur is dire....

In the end we did a lot of debugging, so you create an implementation of the BAdI and then put breakpoints or dummy code for break points in and then run the Concur integration process. When the breakpoint fires you basically have to look at all the data you can see to work out what's going on. It's horribly painful.

In our case we did the following - but it may not apply in all cases - depending on how SAP and Concur are configured...! This code ran with a BADI filter of PC = CUSTOM_FIELD.

  METHOD if_badi_cte_fin_cobj_level~get_level_data.

    FIELD-SYMBOLS: <ls_object> LIKE LINE OF it_cost_object_api_level.

    DATA: ls_csks   TYPE csks,
          ls_prps   TYPE prps,
          ls_cepct  TYPE cepct,
          ls_object LIKE LINE OF et_cost_object_level.

    LOOP AT it_cost_object_api_level ASSIGNING <ls_object>.

      ls_object-cost_object_api_key = <ls_object>-cost_object_api_key.

* . . . Cost Centre or WBS element?
      CASE <ls_object>-cost_object_info-cost_object_type_code.

        WHEN 'CC'.

          SELECT SINGLE *
            FROM csks
            INTO ls_csks
           WHERE kostl EQ <ls_object>-cost_object_info-cost_object_id
             AND datbi EQ <ls_object>-cost_object_info-validity_end_date
             AND datab EQ <ls_object>-cost_object_info-validity_start_date.

          IF sy-subrc EQ 0.
            SELECT SINGLE *
              FROM cepct
              INTO ls_cepct
             WHERE prctr EQ ls_csks-prctr.
          ENDIF.

          ls_object-level_code = ls_csks-prctr.
          ls_object-level_name = ls_cepct-ktext.

        WHEN 'PJ'.

          SELECT SINGLE *
            FROM prps
            INTO ls_prps
           WHERE poski EQ <ls_object>-cost_object_info-cost_object_id.

          IF sy-subrc EQ 0.
            SELECT SINGLE *
              FROM cepct
              INTO ls_cepct
             WHERE prctr EQ ls_prps-prctr.
          ENDIF.

          ls_object-level_code = ls_prps-prctr.
          ls_object-level_name = ls_cepct-ktext.

      ENDCASE.

      CLEAR: ls_csks, ls_cepct, ls_prps.
      APPEND ls_object TO et_cost_object_level.

    ENDLOOP.

  ENDMETHOD.

[jb4444 · Accepted solution]

Thank you for sharing your solution; it was a tremendous help. I was dealing with the exact same situation, needing to add profit center to my Concur export.

[Manuel6 · Accepted solution]

Hi, thank you very much for sharing this solution. Do you know, when this BADI is called?

[Bruno_Dominguez]

Hi, will take the chance and add more information about BADI_CTE_FIN_COBJ_FILL_LEVEL.

First a couple of official documentations that can be found about BADI_CTE_FIN_COBJ_FILL_LEVEL:

- Topic "7.1.2.2 Customer-Specific Hierarchy Level for Concur List" in SAP Concur Integration Setup Guide: SAP Integration with Concur Solutions - Setup Guide.

- Topic "I want to add a custom level to the org structure" in PDF file attached to KBA Comprehensive Guide on Utilizing Business Add-Ins (BAdIs) for SAP Concur Integration with Examples.

In summary BADI_CTE_FIN_COBJ_FILL_LEVEL can be used to fill custom cost object hierarchy levels that are not covered in standard SAP Concur Integration. The SAP standard code fill out data for the following objects: Business Area, Company Code, Controlling Area, Country, Logical System, Cost Object Type and Cost Object ID.

All listed objects above are already filled by ICS and no BADI is required, but in case you need a Profit Center in-between the hierarchy like the image below, this level must be filled through BADI_CTE_FIN_COBJ_FILL_LEVEL.

The List Level / Hierarchy Level is available at CTE_SETUP > Click on the relevant cost object integration, for example Cost Center > Change export > step Cost Object Hierarchy.

The Profit Center field/level above is not available in the standard drop down menu, and it must be created at option "Manage Custom Fields" (button available on same screen) where you are able to assign an ID and Value to the Custom Field:

Click on + to add an extra line to input the ID and Value, and - to remove not desired lines.  Also, option "Show BAdI Implementation" navigate to BADI_CTE_FIN_COBJ_FILL_LEVEL screen.

You can add more fields / levels if required, for example a level for Employee Personnel Number:

Confirm/Enter at "Manage Custom Fields" to make available the new field at Field Name drop-down:

Once the additional custom fields are created, and hierarchy structure is configured as desired, for example:

Complete the wizard to confirm the changes, and implement BADI_CTE_FIN_COBJ_FILL_LEVEL creating different implementations for each custom field, assigning as Filter Value the Custom Field ID created at "Manage Custom Fields".

For Z_BADI_FILL_EE_LEVEL the filter:

And for Z_BADI_FILL_PC_LEVEL:

According to the above, during export of cost objects, system will call each BADI implementation separately where the Profit Center and/or Employee levels are used.

As soon as implementations are active, the column "BAdI Implemented" is true for each field in "Manage Custom Fields". You can double click the line and it will navigate to the relevant BADI implementation.

SAP ERP integration with SAP Concur solutions
 SAP S/4HANA integration with SAP Concur solutions