Dynamic assignment variant for Field-symbols not allowed

[Juwin]

I have a class in which I have defined various Text elements.
For eg.
H01=Title1
H02=Title2
H03=Title3
H04=Title4
etc.
I am trying to print all the titles in my class. I have a loop in my class and I am building the text element name dynamically.

lv_title = `TEXT-H` && conv ty_n2( sy-tabix ).

Now, I use this variable to dynamically access the text element in the program

assign (lv_title) to <title>.

Class is syntactically correct and executes fine with expected results.

But, I get a warning saying: "The old variant of "<dynamic-object>" should not be used in the current ABAP language version."

If this is considered the "old" variant, what is the equivalent "new" variant to access variables by name?

I am on ABAP Cloud version, so that limits the commands available to me (for eg. READ TEXTPOOL isn't available to me)

[Sandra_Rossi]

Read the ABAP Cloud documentation to see the latest dynamic variants available. I currently see: "This syntax is only supported temporarily in the current ABAP language version and must be replaced with valid syntax for that version [...] This variant should not be used any more. Especially for accessing structure components, other variants are preferable." So, it means, use: ASSIGN COMPONENT OF STRUCTURE.

ABAP Cloud - ABAP Keyword Documentation

[Juwin]

@Sandra_Rossi  I did read the documentation. There is nothing in it suggested as an alternative.

https://help.sap.com/doc/abapdocu_cp_index_htm/CLOUD/en-US/ABAPASSIGN_MEM_AREA_DYNAMIC_DOBJ.html

[Sandra_Rossi]

The documentation is clear on ASSIGN for normal variables, but your issue is about accessing Text Symbols dynamically. Your way of programming is not clean code, you'd better explicitly code the conditions. A condition based on a number should not refer to a text symbol with same number. Instead, use a case condition or whatever is best for legibility.

[Juwin]

@Sandra_Rossi The code may be oversimplified in the original post and that may be the reason why you think it is coded without conditions. That's not the real case. In any case, since I haven't received any answers, I would have to assume that there isn't an alternative to this dynamic assign option.

[Juwin]

@Sandra_Rossi @RaymondGiuseppi 

I recently came across another use of this dynamic assignment. This syntax is used to access Object Attributes in the well-known ABAP2XLSX, in zCl_Excel_Common Class and that also throws the same warning.

[Sandra_Rossi]

The warning is about ASSIGN (variable_containing_variable_name) TO <field_symbol>, so technically speaking it's exactly the same case. For this one, the replacement is ASSIGN instance->(variable_containing_attribute_name) TO <field_symbol>. Note that, for now, abap2xlsx contains code which compiles in all versions since ABAP 7.02, so it cannot contain the latter form, maybe in the future there will be some arbitration if ABAP loses its ascending compatibility.

[Sandra_Rossi · Accepted solution]

No pragma exists to remove the warning but you may rewrite your code to avoid field symbols.

As per the ABAP Cloud - ABAP Keyword Documentation: "This syntax is only supported temporarily in the current ABAP language version and must be replaced with valid syntax for that version [...] This variant should not be used any more. Especially for accessing structure components, other variants are preferable."

If you have a structure, use ASSIGN COMPONENT ... OF STRUCTURE ...

That's not possible for the pseudo structure TEXT of Symbol Texts, but you may rewrite this way which is more clean code (of course, I don't know what your real case is, so I use a dummy example):

CLASS zcl_test DEFINITION
  PUBLIC FINAL
  CREATE PUBLIC.

  PUBLIC SECTION.
    INTERFACES if_oo_adt_classrun.
ENDCLASS.

CLASS zcl_test IMPLEMENTATION.
  METHOD if_oo_adt_classrun~main.
    TYPES:
      BEGIN OF ty_month,
        astrological_sign TYPE string,
      END OF ty_month.
    TYPES ty_n2 TYPE n LENGTH 2.

    DATA months   TYPE TABLE OF ty_month.
    DATA lv_title TYPE string.

    " Original code
    DATA(month) = months[ astrological_sign = 'Lion' ].
    lv_title = `TEXT-H` && CONV ty_n2( sy-tabix ).
    ASSIGN (lv_title) TO FIELD-SYMBOL(<title>).

    " Suggested clean code
    DATA(month_number) = line_index( months[ astrological_sign = 'Lion' ] ).
    DATA(month_name) = SWITCH string( month_number
                                      WHEN 1 THEN 'January'(H01)
                                      WHEN 2 THEN 'February'(H02)
                                      " Etc.
                                    ).
  ENDMETHOD.
ENDCLASS.

[RaymondGiuseppi]

Why don't you use RS_TEXTPOOL_READ 

    lv_classn = iv_class.
    lv_classn+30(2) = 'CP'.
    TRANSLATE lv_classn USING ' ='.
    lv_programm = lv_classn.

    CALL FUNCTION 'RS_TEXTPOOL_READ'
      EXPORTING
        objectname           = lv_programm
        action               = 'SHOW'
        language             = iv_langu
      TABLES
        tpool                = lt_table
      EXCEPTIONS
        object_not_found     = 1
        permission_failure   = 2
        invalid_program_type = 3
        error_occured        = 4
        action_cancelled     = 5.

Or you could use the READ TEXTPOOL statement followed by some clean ASSIGN syntax for the type 'I' (text symbols)

[Sandra_Rossi]

It's fine for classic ABAP but it's not accepted in ABAP Cloud, the function module is not released and the ABAP statement is not ported to Cloud. XCO doesn't currently permit working with text pools as far as I can see.

[RaymondGiuseppi]

Is the utility class CL_FDT_SERVICES available?

[Sandra_Rossi]

No, CL_FDT_SERVICES is not released either. I checked in BTP ABAP environment trial. I guess it's the same status in S/4HANA Cloud.

[Mar91]

Ciao Juwin.

The problem is that TEXT is not a structure so these suggested  variants cannot be used.

... { struc-(comp) } 
  | { dref->(comp_name) } 
  | { COMPONENT comp OF STRUCTURE struc } ...

I suggest to declare a proper structure like my_text and to put or duplicate the text symbol's values there as subcomponents.

[Juwin]

I don't want to duplicate the text symbol values. I want to just access the existing values.

[shantraj]

You can use left = right 

something like this -----   <title> = lv_title.

[Juwin]

Probably you didn't understand my question. Please read through once more.