Table name for 'Program name of method' and 'Method name'

[naveen_inuganti2]

As we know, each method method contains different program name with ext. like "====CM0001" etc., Where can I find this program name of method in database tables?

Note: Program names are in REPOSRC with type as 'I' and name as "CLASS NAME======CMXYZ". But here we can not decide with program name belongs to which class!

Thanks,

Naveen.I

[naimesh_patel]

Use FM SEO_CLASS_GET_METHOD_INCLUDES. Provide your class name and you will get the method names with include name.

Regards,

Naimesh Patel

[EdwarSoto]

Using FM SEO_CLASS_GET_METHOD_INCLUDES as this program you can get relationship between Class-Method and Program.

creates a se38 programa, copy & paste , modify 🙂 with yours classes, compile and run. happy coding

*&---------------------------------------------------------------------*
*& Report ZPRUEBA_ES
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT zprueba_es.

CLASS lc_includes DEFINITION.
  PUBLIC SECTION.
    DATA: gt_seoclskey TYPE STANDARD TABLE OF seoclskey.
    DATA: gt_data_includes_all  TYPE  seop_methods_w_include.
    METHODS:
      get_method_programs,
      set_class_names,
      display_result,
      main.
ENDCLASS.

CLASS lc_includes IMPLEMENTATION.
  METHOD get_method_programs.
    DATA: lt_data_includes  TYPE  seop_methods_w_include.
    LOOP AT gt_seoclskey INTO DATA(ls).
      CALL FUNCTION 'SEO_CLASS_GET_METHOD_INCLUDES'
        EXPORTING
          clskey                       = ls
        IMPORTING
          includes                     = lt_data_includes[]
        EXCEPTIONS
          _internal_class_not_existing = 1
          OTHERS                       = 2.
      IF sy-subrc = 0.
        APPEND LINES OF lt_data_includes TO gt_data_includes_all.
      ENDIF.
    ENDLOOP.
  ENDMETHOD.
  METHOD set_class_names.
    APPEND 'Z10CL_BAPI_ACC_DOCUMENT_POST_I' TO gt_seoclskey .
    APPEND 'Z22CL_RESPUESTAS_LIBERACION_IN' TO gt_seoclskey .
  ENDMETHOD.
  METHOD display_result.
    DATA: lo_table TYPE REF TO cl_salv_table.
    DATA: lo_functions TYPE REF TO cl_salv_functions_list.
    DATA: lo_display TYPE REF TO cl_salv_display_settings.
    DATA: lo_layout TYPE REF TO cl_salv_layout.
    DATA: lv_key TYPE salv_s_layout_key.
    TRY .
        cl_salv_table=>factory( IMPORTING
          r_salv_table = lo_table
        CHANGING
          t_table =  me->gt_data_includes_all[] ).
      CATCH cx_salv_msg.

    ENDTRY.
    lo_functions = lo_table->get_functions( ).
    lo_functions->set_all( abap_true ).
    lo_display = lo_table->get_display_settings( ).
    lo_display->set_striped_pattern( cl_salv_display_settings=>true ).
    lo_display->set_list_header( 'Result' ).

    lo_layout = lo_table->get_layout( ).
    lv_key-report = sy-repid.
    lo_layout->set_key( lv_key ).
    lo_layout->set_save_restriction( cl_salv_layout=>restrict_none ).
    lo_table->display( ).
  ENDMETHOD.
  METHOD main.
    me->set_class_names( ).
    me->get_method_programs( ).
    me->display_result( ) .
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.

  NEW lc_includes( )->main( ).

[matt]

I love the consistent naming convention. L and G variables defined in the same data block...

[FredericGirod]

🙂

You stay in the dark to check Hungarian notation ? 🙂

And do you know when the Camel notation will arrive ? it was anounced some times ago

[EdwarSoto]

Sorry guys, 1 am programing code no always is the better, but run! 🙂

[keremkoseoglu]

Check the table SEOCOMPO for all class method definitions.