Table containing Program Texts(Text Symbols, SelectionTexts, List Heading)

[Former Member]

Hi All,

I would like to know which is the standard SAP std. table which stores the data regarding Text Symbols, SelectionTexts, and List Heading of every program we create. There should definitly be a table where it is stored (otherwise we will not be able to retrieve it each time).

I have found out a structure RS38M which has all the required fields. But since it is a structure, it doesnt contain data.

So please inform if any body knows any standard SAP table which stores Program Texts. A quick, correct reply would be highly appreciated.

[Former Member]

These wouldn't get stored in SAP tables which can be viewed in se11.

these are stored in raw format.

you can use READ TEXTPOOL statement to read

READ_TEXTELEMENT_FROM_REPORT FM might be useful.

[Former Member]

Hi

All these texts are stored in text pool not in any std. table.

To retrieve these info u have to use statement like:

READ TEXTPOOL <prog_name> INTO itab LANGUAGE <language> [STATE state].

This statement reads the text elements of the text pool of the language specified in lang and the program specified in prog from the Repository and places them into the internal table itab. The previous content of itab is deleted. If the text elements cannot be read, then the content of itab remains unchanged.

For prog, you must specify a flat character-like data object, which contains the name of the program of the text elements to be read; the name is case-independent. The internal table can have any table type and its row type must correspond to structure TEXTPOOL from the ABAP Dictionary.

For lang, you must specify a flat character-like data object, which contains a language key of up to one character, whose value must be contained in the SPRAS column of database table T002. If lang contains a blank, the behavior is undefined.

After a successful read, itab contains in the ENTRY column the texts of the text symbols, the selection texts, the list headers and the title from the program attributes. Every text element that exists for the specified language occupies one row of the internal table and is identified uniquely by the columns ID and KEY. The column LENGTH contains the length of the text element. The table below shows the possible values of the columns ID and KEY and their meaning:

ID KEY ENTRY

H 001 to 004 List header: Column headings

I Text symbol identifier Text symbol text

R - Program title

S Name of a parameter or selection criterion Selection text

T - List Title: Titlebar

[Former Member]

HI....

probably you can check out tables starting with 'TVAR'..

in se11 check out all tables starting with TVARV*...

you will find the necessary info.

[Former Member]

use this ..fm

WB2B_GET_REPORT_TEXTELEMENT

[Former Member]

Hi!!,

you can try with these tables:

DYNPREAD

DYNPTXTLD

DYNPFIELDS

Regards,

Ana

[former_member571357]

REPORT  zrtext.

TABLES :rs38m,textpool.

DATA : BEGIN OF i_tab OCCURS 0,

         name TYPE  progname.

         INCLUDE STRUCTURE textpool.

DATA :  END OF i_tab.

DATA : texts  LIKE textpool OCCURS 50 WITH HEADER LINE,

        w_text LIKE textpool.

DATA : it LIKE LINE OF i_tab OCCURS 0,

        lines TYPE i,

        myalv TYPE REF TO cl_salv_table,

        myfunctions TYPE REF TO cl_salv_functions_list,

        mycolumns TYPE REF TO cl_salv_columns_table.

SELECTION-SCREEN : BEGIN OF BLOCK b WITH FRAME TITLE text-001.

SELECT-OPTIONS : zprg FOR rs38m-programm.

SELECTION-SCREEN : END OF BLOCK b.

START-OF-SELECTION.

   SELECT progname FROM reposrc INTO i_tab-name WHERE progname IN zprg.

     READ TEXTPOOL i_tab-name INTO texts LANGUAGE 'E'.

     LOOP AT texts INTO w_text . "WHERE id EQ 'I'.

       MOVE-CORRESPONDING w_text TO i_tab.

       APPEND i_tab TO i_tab.

     ENDLOOP.

   ENDSELECT.

   it[] = i_tab[].

   TRY.

       CALL METHOD cl_salv_table=>factory

         IMPORTING

           r_salv_table = myalv

         CHANGING

           t_table      = it[].

     CATCH cx_salv_msg.

   ENDTRY.

   DESCRIBE TABLE i_tab LINES lines.

   MESSAGE s375(po) WITH lines '' 'records found..'.

   mycolumns = myalv->get_columns( ).

   mycolumns->set_optimize( ).

   myfunctions = myalv->get_functions( ).

   myfunctions->set_all( ).

   CALL METHOD myalv->display.

This Code will show you the All Text Symbols & Selection Text & Report Title..

Give Like and Reward ..

[lcl1964]

just a small integration to manage text in more languages…:-)

REPORT zrtext.

TABLES :rs38m,textpool.
DATA : BEGIN OF i_tab OCCURS 0,
name TYPE progname,
spras like sy-langu.
INCLUDE STRUCTURE textpool.
DATA : END OF i_tab.
DATA : texts LIKE textpool OCCURS 50 WITH HEADER LINE,
w_text LIKE textpool.
DATA : it LIKE LINE OF i_tab OCCURS 0,
lines TYPE i,
myalv TYPE REF TO cl_salv_table,
myfunctions TYPE REF TO cl_salv_functions_list,
mycolumns TYPE REF TO cl_salv_columns_table.

SELECTION-SCREEN : BEGIN OF BLOCK b WITH FRAME TITLE text-001.
SELECT-OPTIONS : S_prg FOR rs38m-programm.
SELECT-OPTIONS : S_spras for sy-langu no INTERVALS.
SELECTION-SCREEN : END OF BLOCK b.


data: tb_langu like t002 occurs 0 WITH HEADER LINE.

INITIALIZATION.


s_spras-sign = 'I'.
s_spras-option = 'EQ'.

s_spras-low = 'I'. "Italian
append s_spras.

s_spras-low = 'E'. "English
append s_spras.

s_spras-low = 'S'. "Spanish
append s_spras.

START-OF-SELECTION.

clear tb_langu.

select * from t002 into table tb_langu where spras in s_spras.


check tb_langu[] is not INITIAL.

select progname FROM reposrc INTO i_tab-name WHERE progname IN s_prg.
loop at tb_langu.
READ TEXTPOOL i_tab-name INTO texts LANGUAGE tb_langu-spras.
LOOP AT texts INTO w_text .
MOVE-CORRESPONDING w_text TO i_tab.
i_tab-spras = tb_langu-spras.
APPEND i_tab TO i_tab.
ENDLOOP.
ENDLOOP.
ENDSELECT.

sort i_tab by name id key spras.

it[] = i_tab[].
TRY.
CALL METHOD cl_salv_table=>factory
IMPORTING
r_salv_table = myalv
CHANGING
t_table = it[].
CATCH cx_salv_msg.
ENDTRY.

DESCRIBE TABLE i_tab LINES lines.
MESSAGE s375(po) WITH lines '' 'records found..'.
mycolumns = myalv->get_columns( ).
mycolumns->set_optimize( ).
myfunctions = myalv->get_functions( ).
myfunctions->set_all( ).
CALL METHOD myalv->display.