Application Development Discussions
Join the discussions or start your own on all things application development, including tools and APIs, programming models, and keeping your skills sharp.
cancel
Showing results for 
Search instead for 
Did you mean: 

How to put colours for a column in ALV

Former Member
0 Kudos

Dear All,

I need to put green colour for 1 column in an ALV report.

Can anybody tell me how we can do that ...

Thanking you in advance,

Shankar

1 ACCEPTED SOLUTION

Former Member
0 Kudos

Hi,

Use field <b>emphasize</b> of field catalog structure.

emphasize (highlight columns in color)

value set: SPACE, 'X' or 'Cxyz' (x:'1'-'9'; y,z: '0'=off '1'=on)

'X' = column is colored with the default column highlight color.

'Cxyz' = column is colored with a coded color:

C: Color (coding must begin with C)

x: color number

y: bold

z: inverse

Svetlin

6 REPLIES 6

Former Member
0 Kudos

Hi,

Check this link,

http://www.sap-img.com/abap/line-color-in-alv-example.htm

This example shows how u can colr a column or row or a single cell.

Hope this helps u.

Thanks&Regards,

Ruthra.R

Former Member
0 Kudos

A) Insert the field for in your output table:

DATA: BEGIN OF MY_TABLE,

......

TCOLOR TYPE SLIS_T_SPECIALCOL_ALV,

END OF MY_TABLE.

B) Set the field name for color in you layout structure:

GT_LAYOUT-coltab_fieldname = 'TCOLOR'.

C) While you are appending a record in your output table, you define cell color:

DATA WA_COLOR TYPE SLIS_SPECIALCOL_ALV.

  • Inser new record in output table

MY_TABLE-FIELD1 =....

MY_TABLE-FIELD2 =....

MY_TABLE-FIELD3 =....

REFRESH MY_TABLE-TCOLOR.

WA_COLOR-FIELDNAME = 'FIELD1'.

WA_COLOR-COLOR-COL = 4.

APPEND WA_COLOR TO MY_TABLE.

APPEN MY_TABLE.

Former Member
0 Kudos

Hi,

Use field <b>emphasize</b> of field catalog structure.

emphasize (highlight columns in color)

value set: SPACE, 'X' or 'Cxyz' (x:'1'-'9'; y,z: '0'=off '1'=on)

'X' = column is colored with the default column highlight color.

'Cxyz' = column is colored with a coded color:

C: Color (coding must begin with C)

x: color number

y: bold

z: inverse

Svetlin

0 Kudos

Here's a little sample program..... this illistrates coloring at the column, row, and cell level.



report zrich_0002 .

*****************************************************************
* Use of colours in ALV grid (cell, line and column)            *
*****************************************************************

* Table
tables : mara.

* Type
types : begin of ty_mara,
          matnr         like mara-matnr,
          matkl         like mara-matkl,
          counter(4)    type n,
          free_text(15) type c,
          color_line(4) type c,           " Line color
          color_cell    type lvc_t_scol,  " Cell color
end of ty_mara.

* Structures
data  : wa_mara     type ty_mara,
        wa_fieldcat type lvc_s_fcat,
        is_layout   type lvc_s_layo,
        wa_color    type lvc_s_scol.

* Internal table
data : it_mara     type standard table of ty_mara,
       it_fieldcat type standard table of lvc_s_fcat,
       it_color    type table          of lvc_s_scol.

* Variables
data : okcode like sy-ucomm,
       w_alv_grid          type ref to cl_gui_alv_grid,
       w_docking_container type ref to cl_gui_docking_container.


parameters : p_column as checkbox,
             p_line   as checkbox,
             p_cell   as checkbox.

at selection-screen output.

  perform get_data.
  perform fill_catalog.

  if w_docking_container is initial.
    perform create_objects.
  endif.

*&--------------------------------------------------------------*
*&      Form  create_objects
*&--------------------------------------------------------------*
form create_objects.

  create object w_docking_container
    exporting
      ratio                       = 60
    exceptions
      cntl_error                  = 1
      cntl_system_error           = 2
      create_error                = 3
      lifetime_error              = 4
      lifetime_dynpro_dynpro_link = 5
      others                      = 6.

  create object w_alv_grid
    exporting
      i_parent          = w_docking_container.

* Field that identify color line in internal table
  move 'COLOR_LINE' to is_layout-info_fname.

* Field that identify cell color in inetrnal table
  move 'COLOR_CELL' to is_layout-ctab_fname.

  call method w_alv_grid->set_table_for_first_display
    exporting
      is_layout                     = is_layout
    changing
      it_outtab                     = it_mara
      it_fieldcatalog               = it_fieldcat
    exceptions
      invalid_parameter_combination = 1
      program_error                 = 2
      too_many_lines                = 3
      others                        = 4.

endform.
*&--------------------------------------------------------------*
*&      Form  get_data
*&--------------------------------------------------------------*
form get_data.

  select * from mara up to 5 rows.
    clear : wa_mara-color_line, wa_mara-color_cell.

    move-corresponding mara to wa_mara.
    add 1                   to wa_mara-counter.
    move 'Blabla'           to wa_mara-free_text.

    if wa_mara-counter = '0002'
    and p_line = 'X'.
* Color line
      move 'C410' to wa_mara-color_line.
    elseif wa_mara-counter = '0004'
    and p_cell = 'X'.
* Color cell
      move 'FREE_TEXT' to wa_color-fname.
      move '6'         to wa_color-color-col.
      move '1'         to wa_color-color-int.
      move '1'         to wa_color-color-inv.
      append wa_color to it_color.
      wa_mara-color_cell[] = it_color[].
    endif.

    append wa_mara to it_mara.
  endselect.

endform.
*&--------------------------------------------------------------*
*&      Form  fill_catalog
*&--------------------------------------------------------------*
form fill_catalog.

*****************************************************************
* Colour code :                                                 *
* Colour is a 4-char field where :                              *
*              - 1st char = C (color property)                  *
*              - 2nd char = color code (from 0 to 7)            *
*                                  0 = background color         *
*                                  1 = blue                     *
*                                  2 = gray                     *
*                                  3 = yellow                   *
*                                  4 = blue/gray                *
*                                  5 = green                    *
*                                  6 = red                      *
*                                  7 = orange                   *
*              - 3rd char = intensified (0=off, 1=on)           *
*              - 4th char = inverse display (0=off, 1=on)       *
*                                                               *
* Colour overwriting priority :                                 *
*   1. Line                                                     *
*   2. Cell                                                     *
*   3. Column                                                   *
*****************************************************************
  data : w_position type i value '1'.

  clear wa_fieldcat.
  move w_position to wa_fieldcat-col_pos.
  move 'MATNR'    to wa_fieldcat-fieldname.
  move 'MARA'     to wa_fieldcat-ref_table.
  move 'MATNR'    to wa_fieldcat-ref_field.
  append wa_fieldcat to it_fieldcat.

  add 1 to w_position.

  clear wa_fieldcat.
  move w_position to wa_fieldcat-col_pos.
  move 'MATKL'    to wa_fieldcat-fieldname.
  move 'MARA'     to wa_fieldcat-ref_table.
  move 'MATKL'    to wa_fieldcat-ref_field.
* Color column
  if p_column = 'X'.
    move 'C610'     to wa_fieldcat-emphasize.
  endif.
  append wa_fieldcat to it_fieldcat.

  add 1 to w_position.

  clear wa_fieldcat.
  move w_position to wa_fieldcat-col_pos.
  move 'COUNTER'  to wa_fieldcat-fieldname.
  move 'N'        to wa_fieldcat-inttype.
  move '4'        to wa_fieldcat-intlen.
  move 'Counter'  to wa_fieldcat-coltext.
  append wa_fieldcat to it_fieldcat.

  add 1 to w_position.

  clear wa_fieldcat.
  move w_position  to wa_fieldcat-col_pos.
  move 'FREE_TEXT' to wa_fieldcat-fieldname.
  move 'C'         to wa_fieldcat-inttype.
  move '20'        to wa_fieldcat-intlen.
  move 'Text'      to wa_fieldcat-coltext.
  append wa_fieldcat to it_fieldcat.

endform.

Regards,

Rich HEilman

Former Member
0 Kudos

Hi,

If you find some answers helpful, please assign reward points.

Svetlin

Former Member
0 Kudos

Hi,

There is a sample code here:

http://www.sapfans.com/forums/viewtopic.php?t=52107

Best Regards,

Anjali