- SAP Managed Tags:
What this means is that you are setting the handler method for all instances of the class object, so there is more than one instance(object) of a class, the same handler will be fired for the different object references of the class.
Regards,
Rich Heilman
- SAP Managed Tags:
Well, in this case, there is only one object R1, so it really doesn't show the use of FOR ALL INSTANCES. Taking the example above and modifing it you can see how this can be implemented below.
report zrich_0001.
*---------------------------------------------------------------------*
* CLASS counter DEFINITION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class counter definition.
public section.
methods increment_counter.
events critical_value exporting value(excess) type i.
private section.
data: count type i,
threshold type i value 10.
endclass.
* All the methods of the calls are implemented
class counter implementation.
method increment_counter.
data diff type i.
add 1 to count.
if count > threshold.
diff = count - threshold.
raise event critical_value exporting excess = diff.
endif.
endmethod.
endclass.
*---------------------------------------------------------------------*
* CLASS handler DEFINITION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class handler definition.
public section.
methods handle_excess
for event critical_value of counter
importing excess.
endclass.
*---------------------------------------------------------------------*
* CLASS handler IMPLEMENTATION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class handler implementation.
method handle_excess.
write: / 'Excess is', excess.
endmethod.
endclass.
data: r1 type ref to counter,
r1_list type table of ref to counter,
h1 type ref to handler.
start-of-selection.
create object h1.
* Handler is set for the event
set handler h1->handle_excess for all instances .
do 5 times.
* Class is instantiated
create object: r1.
append r1 to r1_list.
enddo.
loop at r1_list into r1.
do 20 times.
call method r1->increment_counter.
enddo.
skip 1.
endloop.
REgards,
Rich Heilman
- SAP Managed Tags:
Now that I'm thinking about it, my last example doesn't give a clear picture, take this example where you have two instances of COUNTER, the event handler will be fired for both instances R1 and R2.
report zrich_0001.
*---------------------------------------------------------------------*
* CLASS counter DEFINITION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class counter definition.
public section.
methods increment_counter.
events critical_value exporting value(excess) type i.
private section.
data: count type i,
threshold type i value 10.
endclass.
* All the methods of the calls are implemented
class counter implementation.
method increment_counter.
data diff type i.
add 1 to count.
if count > threshold.
diff = count - threshold.
raise event critical_value exporting excess = diff.
endif.
endmethod.
endclass.
*---------------------------------------------------------------------*
* CLASS handler DEFINITION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class handler definition.
public section.
methods handle_excess
for event critical_value of counter
importing excess.
endclass.
*---------------------------------------------------------------------*
* CLASS handler IMPLEMENTATION
*---------------------------------------------------------------------*
* ........ *
*---------------------------------------------------------------------*
class handler implementation.
method handle_excess.
write: / 'Excess is', excess.
endmethod.
endclass.
data: r1 type ref to counter,
r2 type ref to counter,
h1 type ref to handler.
start-of-selection.
create object h1.
* Handler is set for the event
set handler h1->handle_excess for all instances .
* Class is instantiated
create object: r1, r2.
do 20 times.
call method r1->increment_counter.
enddo.
skip 1.
do 20 times.
call method r2->increment_counter.
enddo.
Regards,
RIch Heilman
