topic Re: Call external program in background mode in Application Development and Automation Discussions

Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:04:24 GMT

Hi,

I am creating a PO using bapi BAPI_PO_CREATE1 in exit USEREXIT_SAVE_DOCUMENT_PREPARE.

I dont want to write the code in my exit. Instead I want to write the code in a Z program and call it in my exit.

My Problem.

How do I call my z program in my exit so that I can pass internal tables from my exit to the z program. Also I want to schedule the call of my external program for background processing.

I am trying with SUBMIT ZPROG AND RETURN. But not able to pass an internal table.

I tried PERFORM BAPI_PO_CREATE IN PRGRAM ZPROG, but in this case not able to schedule it in background.

Please advise.

Regards,

Shobhit

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:14:13 GMT

Hi Shobhit,

Put a break point in your exit & see whether the Exit is firing.

Re: Call external program in background mode

RichHeilman — Mon, 05 Dec 2005 16:16:18 GMT

You need to pass the data using shared memory buffer. Here is an example.

This example gets data from MARA into an internal table, then exports the internal table to shared memory, then it schedules a background job for ZRICH_0005. In the ZRICH_0005, it imports the internal table and writes it out. This is the functionality that you are looking for.

Program A.



report zrich_0001 .

data:   l_valid,
        ls_params like pri_params,
        l_jobcount like tbtcjob-jobcount,
        l_jobname  like tbtcjob-jobname,
        l_key(60) type c.

data: imara type table of mara with header line.

start-of-selection.



  select * into corresponding fields of table imara
                from mara
                      up to 100 rows.

<b>  concatenate 'RICHTEST' sy-datum into l_key.
  export imara = imara
              to shared buffer indx(st) id l_key.</b>

* Get Print Parameters
  call function 'GET_PRINT_PARAMETERS'
       exporting
            no_dialog      = 'X'
       importing
            valid          = l_valid
            out_parameters = ls_params.

* Open Job
  l_jobname = 'ZRICH_0005'.
  call function 'JOB_OPEN'
       exporting
            jobname  = l_jobname
       importing
            jobcount = l_jobcount.

* Submit report to job
  submit zrich_0005
       via job     l_jobname
           number  l_jobcount
       to sap-spool without spool dynpro
           spool parameters ls_params
              and return.

* Schedule and close job.
  call function 'JOB_CLOSE'
       exporting
            jobcount  = l_jobcount
            jobname   = l_jobname
            strtimmed = 'X'.

Program B.



report zrich_0005 .


data:   l_key(60) type c.

data: imara type table of mara with header line.

start-of-selection.


<b>  concatenate 'RICHTEST' sy-datum into l_key.
  import imara = imara
              from shared buffer indx(st) id l_key.
  delete from shared buffer indx(st) id l_key.</b>

  loop at imara.

    write:/ imara-matnr, imara-matkl.

  endloop.

Regards,

Rich Heilman

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:18:31 GMT

You could try using the IMPORT/EXPORT FROM/TO MEMORY method

you could do this in your exit:

EXPORT it_table TO MEMORY ID 'MY_MEM_ID'.

In your Z scheduled program you could:

IMPORT it_table FROM MEMORY ID 'MY_MEM_ID'.

Note: Don't forget to declare the it_table in the Z program too.

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:18:53 GMT

Hi Phani,

The exit is very well firing as my code is working using the PERFORM.. method. But I want to schedule the perform in the background. For that I tried using SUBMIT.. but not able to pass internal table.

Regards,

Shobhit

Re: Call external program in background mode

RichHeilman — Mon, 05 Dec 2005 16:22:43 GMT

Ivo suggestion will not help as you are crossing work processes, you must use the shared buffer because it goes across all process, system wide.

Regards,

Rich Heilman

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:29:30 GMT

Hi Shobhit,

Try to Proceed according to Rich's Idea.

regards

vijay

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:36:25 GMT

Why do you want to do this in a different program? You'll be adding overhead by submitting a background job. If you do it in foreground with AND RETURN, you'll have to wait for the program to finish before the dialogue can continue.

Rob

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:46:38 GMT

Hi Rich and Rob!!

Thank you both!! Ill b following Rich's idea. I need to send the PO crearion to background because I want the Delivery to be created successfully after which only I want the background job to execute. (After checking the successful completion of the dialog)

Now I have another problem. I need to put a popup screen to take two input values to the user. These values would be required to create the PO in background.

How and where should I create this popup screen? in the exit or in the z program?

Thanks for any kind of help.

Regards,

Shobhit

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 16:53:16 GMT

If the Z program is in the background, you'll need the popup in the exit.

Rob

Re: Call external program in background mode

RichHeilman — Mon, 05 Dec 2005 16:54:19 GMT

I would put it in the exit since it is in the foreground. Try something like this.



report zrich_0001 .


data: fields type table of sval with header line.


fields-tabname   = 'EKKO'.
fields-fieldname = 'EBELN'.
append fields.

fields-tabname   = 'EKPO'.
fields-fieldname = 'EBELP'.
append fields.

call function 'POPUP_GET_VALUES'
  exporting
*   NO_VALUE_CHECK        = ' '
    popup_title           = 'Test'
*   START_COLUMN          = '5'
*   START_ROW             = '5'
* IMPORTING
*   RETURNCODE            =
  tables
    fields                = fields
* EXCEPTIONS
*   ERROR_IN_FIELDS       = 1
*   OTHERS                = 2
          .
if sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
endif.

Please make sure to award points for helpful answers. Thanks.

Regards,

Rich Heilman

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 17:00:58 GMT

I salute u Rich!!!

Thanks a lot.

Regards,

Shobhit

Re: Call external program in background mode

RichHeilman — Mon, 05 Dec 2005 17:04:52 GMT

So then it is all working now? using the shared buffer?

Regards,

Rich Heilman

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 18:48:25 GMT

Hi Rich,

Im setting runtime error:

My Code in Exit: (xvbfa is the table which i wanna pass)

concatenate 'SERVICEPO' sy-datum into l_key.

export xvbfa = xvbfa

to shared buffer indx(st) id l_key.

My Code in the called program ZMM_SERVICE_PO

Runtime Errors CONNE_IMPORT_WRONG_OBJECT_TYPE

Exceptn CX_SY_IMPORT_MISMATCH_ERROR

Date and Time 05.12.2005 21:41:54

ShrtText

Error when attempting to IMPORT object "XVBFA".

What happened?

Error in ABAP application program.

The current ABAP program "ZMM_SERVICE_PO" had to be terminated because one of

the

statements could not be executed.

This is probably due to an error in the ABAP program.

When importing the object "XVBFA", the object in the

dataset had a different type from the target object in the program

"ZMM_SERVICE_PO" (object types: field, field string/structure, table).

table).

Error analysis

An exception occurred. This exception will be dealt with in more detail

below. The exception, assigned to the class 'CX_SY_IMPORT_MISMATCH_ERROR', was

not caught, which

led to a runtime error. The reason for this exception is:

The object "XVBFA" has a different object type in the dataset from

that in the target program "ZMM_SERVICE_PO". (Object types: Field, flat

structure,

deep structure, flat table, deep table).

Missing Handling of System Exception

Program ZMM_SERVICE_PO

Trigger Location of Exception

Program ZMM_SERVICE_PO

Include ZMM_SERVICE_PO

Row 43

Module Name START-OF-SELECTION

Source Code Extract

Line SourceCde

REPORT ZMM_SERVICE_PO.

DATA: l_poheader LIKE bapimepoheader.

DATA: l_poheaderx LIKE bapimepoheaderx.

DATA: l_poitem LIKE bapimepoitem OCCURS 0 WITH HEADER LINE.

DATA: l_poitemx LIKE bapimepoitemx OCCURS 0 WITH HEADER LINE.

DATA: l_cond LIKE BAPIMEPOCOND OCCURS 0 WITH HEADER LINE.

DATA: l_condx LIKE BAPIMEPOCONDX OCCURS 0 WITH HEADER LINE.

DATA: l_poschedule LIKE bapimeposchedule OCCURS 0 WITH HEADER LINE.

DATA: l_poschedulex LIKE bapimeposchedulx OCCURS 0 WITH HEADER LINE.

DATA: l_purchaseorder LIKE bapimepoheader-po_number.

DATA: l_return TYPE BAPIRET2 OCCURS 0.

DATA: l_error_found TYPE c.

DATA: l_show_messages TYPE c.

DATA: l_eindt(10) TYPE c.

DATA: l_answer TYPE c.

DATA: l_VBAK TYPE STANDARD TABLE OF VBAK WITH HEADER LINE.

DATA: l_VBFA TYPE STANDARD TABLE OF VBFA WITH HEADER LINE.

DATA: xlips TYPE STANDARD TABLE OF LIPS WITH HEADER LINE.

*DATA: xvbfa TYPE STANDARD TABLE OF vbfa WITH HEADER LINE.

DATA xvbfa like vbfa.

DATA: l_key(60) type c.

concatenate 'SERVICEPO' sy-datum into l_key.

>>>>> import xvbfa = xvbfa

from shared buffer indx(st) id l_key.

delete from shared buffer indx(st) id l_key.

Could you help.

Regads,

Shobhit

Re: Call external program in background mode

RichHeilman — Mon, 05 Dec 2005 18:50:55 GMT

Looks like in the SUBMITTED program you are importing XVBFA, but XVBFA is not an internal table. You have it commented out. XVBFA needs to be an interal table, right?

Regards,

Rich Heilman

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 18:51:29 GMT

Your xvbfa in the user exit might be having a different structure compared to what you declared in your ZMM_SERVICE_PO. They have to have the same structure.

Srinivas

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 18:54:13 GMT

Here is the definition of XVBFA in SAPMV45A, include VBFADATA.

data: begin of xvbfa occurs 0.

include structure vbfavb.

data: end of xvbfa.

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 18:58:55 GMT

WHy can't you open another thread as every can see this..

Becaue this is already closed..

regards

vijay

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 19:01:27 GMT

Hi Rich,

It is an internal table only. Im just tryin diff ways to define n internal table. Thats why u see the commented line. Still I get the same error.

If you don't mind, may I have your email id?

Thanks & Regards,

Shobhit

Re: Call external program in background mode

Former Member — Mon, 05 Dec 2005 19:03:43 GMT

Shobhit, please look at my response. Change your xvbfa definition to that of the include, then it will be ok.

Srinivas