topic Re: Transferring multiple files to application server. in Application Development and Automation Discussions

Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 15:00:43 GMT

Hi,

I have 4 internal table & these I have to send to application server as 4 files... I do not want to do 4 time OPen dataset, transfer dataset & close dataset ... Is there any other way to do in one loop... if example code is provided that would be of great help...

Thank You,

SB.

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 15:04:37 GMT

Hi SB,

What you can do is have a perform which accepts internal table name and file name.

In the perform , have open dataset, loop at internal table and transfer the data to appl server file, and then call close dataset at the end.

so, One perform subroutine and multiple calls with different parameter values ......

Regards,

Raj

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 15:08:41 GMT

One perform with different parameter ... can you please explain more... for eg. the internal table are t_textfil1.txt, t_textfile2.txt, t_textfile3.txt, and t_textfile4.txt ... how do I use them in my perform statement??

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 15:09:56 GMT

something like

do 4 times.

open dataset sy-index for output.

transfer data.

enddo.

Regards,

Bikash.

Re: Transferring multiple files to application server.

andreas_mann3 — Thu, 15 Dec 2005 15:11:55 GMT

Hi,

try that and fill an itab with filename and itabname:

loop at t_file.

open dataset t_file-name ...

assign t_file-itab_name to <f>.

loop at <f> into wa.
 transfer wa to t_file-name .
endloop.

 close dataset t_file-name .
...


endloop.

Andreas

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 15:12:04 GMT

I would say that you need to do it 4 times. You can code it once in a perform and then call it 4 times.



data: itab type table of mara
data: xtab type mara.
data: p_file type localfile.

field-symbols: <fs_datatab> type table,
               <fs_wa> .

perform download_file using itab xtab p_file.


form download_file using data_tab wa file.

assign (data_tab) to <fs_datatab>.
assign (wa) to <fs_wa>.

open dataset file for output binary mode.
if sy-subrc = 0.
loop at <fs_datatab> into <fs_wa>.
transfer <fs_wa> to file.
endloop.
endif.

close dataset file.

endform.

Regards,

Rich Heilman

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 15:30:35 GMT

what I am trying to do now is once my t_txtfile1 internal table is getting populated I am moving the table name to t_filename which as 2 feilds... t_filename-name & t_filename-path....

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 15:40:48 GMT

Sounds like you will need to concatenate the path and file name together before using the OPEN DATASET.

data: filepathname(100) type c.

concatenate t_filename-path t_filename-name 
into filepathname.

Regards,

Rich Heilman

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 15:54:09 GMT

for 1st Internal table

ITAB_FINAL[] = ITAB1[] . "Your 1st internal table

PERFORM download_file using FILENAME1.

for 2nd internal table

clear : itab_final, itab_final[].

ITAB_FINAL[] = ITAB2[] . "Your 2nd internal table

PERFORM download_file using FILENAME2.

*--like this you can call the same FORM download_file any no of times.

FORM DOWNLOAD_FILE using p_fname.

*--here you use OPEN dataset etc..

open dataset p_fname for output in text mode encoding default.

loop at itab_final.

transfer itab_final-line to p_fname.

endloop.

close dataset p_fname.

ENDFORM.

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 16:01:53 GMT

Doing

ITAB_FINAL[] = ITAB1[]

ITAB_FINAL[] = ITAB2[]

will lead to give me 1 final table ... I don't want that ... these are 4 different tables & all of them have different set of data... if I combine them then the data becomes meaningless....

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 16:05:16 GMT

Exactly, that's why you need to use field symbols as I suggested in the previous post.

Regards,

Rich Heilman

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 16:11:37 GMT

Hi Rich,

In my T_filename table I am capturing the internal table name in the feild t_filename-name... and the path of the application server in the feild t_filename-path...

Iam doing this by:-

Select....

IF SY-SUBRC <> 0.

MESSAGE I004. " No data found

ELSE.

SORT T_BUKRS BY BUKRS.

MOVE 'T_BUKRS' TO T_FILENAME-NAME.

MOVE '/holdarchlogs/outbound/Comapny_Code_Text.txt' TO T_FILENAME-PATH.

ENDIF.

This I am doing for all success Select's ...

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 16:22:05 GMT

Oh, I see. I are still having a problem?

Make sure that you APPEND to your t_filename table.

Regards,

Rich Heilman

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 16:47:48 GMT

Hi Rich,

Yes I did that... but a new erroe is coming...

FORM DWNLOAD_DATA .

LOOP AT T_FILENAME.

Open the dataset file.

OPEN DATASET T_FILENAME-PATH FOR OUTPUT IN TEXT MODE ENCODING DEFAULT

. IF SY-SUBRC <> 0.

MESSAGE I006. " Dataset file could not be opened

ENDIF.

Transfer Comapny code to the application server.

IF T_FILENAME-NAME = T_BUKRS.

LOOP AT T_BUKRS

TRANSFER T_BUKRS TO T_FILENAME-PATH.

ENDLOOP.

ENDIF.

ENDLOOP.

Here error is "Transfer T_BUKRS is not expected."

ENDFORM. " DWNLOAD_DATA

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 19:19:51 GMT

Hi,

When I am transferring data to the application server... I want to that the columns in the application file should be seen distinctively ... is there any method to give lengths to the columns??

Thank You,

-SB.

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 19:24:11 GMT

You are missing the period after the LOOP statement.



LOOP AT T_BUKRS <b> .    "<<-----Need Period here</b>
TRANSFER T_BUKRS TO T_FILENAME-PATH.
ENDLOOP.

I thought that you didn't want to do 4 seperate loops, you are not using fields symbols in your code, why not?

Also, I think that when writing to the file, it will write the data with the lengths specified by the internal table structure.

Regards,

Rich HEilman

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 19:44:52 GMT

Please see this sample program. It is pretty much what I think you want to do. Using field symbols, we are passing th table, wa, and file name to one routine that downloads the data. This works really good in my system. Try it out.



report zrich_0002.


data: it001 type table of t001.
data: xt001 type t001.

data: it001w type table of t001w.
data: xt001w type t001w.

types: begin of t_files,
       table(20) type c,
       wa(20) type c,
       file(100) type c,
       end of t_files.

data: ifiles type table of t_files.
data: xfiles type t_files.

field-symbols: <fs_datatab> type table,
               <fs_wa> .

start-of-selection.

  xfiles-table = 'IT001'.
  xfiles-wa    = 'XT001'.
  xfiles-file  = '/usr/sap/TST/t001.txt'.
  append xfiles to ifiles.

  xfiles-table = 'IT001W'.
  xfiles-wa    = 'XT001W'.
  xfiles-file  = '/usr/sap/TST/t001W.txt'.
  append xfiles to ifiles.


  select * from t001 into table it001.
  select * from t001w into table it001w.


  loop at ifiles into xfiles.

    perform download_file using xfiles-table
                                xfiles-wa
                                xfiles-file.

  endloop.

*---------------------------------------------------------------------*
*       FORM download_file                                            *
*---------------------------------------------------------------------*
form download_file using data_tab wa file.

  assign (data_tab) to <fs_datatab>.
  assign (wa) to <fs_wa>.

  open dataset file for output in binary mode.
  if sy-subrc = 0.
    loop at <fs_datatab> into <fs_wa>.
      transfer <fs_wa> to file.
    endloop.
  endif.

  close dataset file.

endform.

Regards,

Rich Heilman

Re: Transferring multiple files to application server.

Former Member — Thu, 15 Dec 2005 21:27:56 GMT

Hi Rich,

My prg is giving a short dump when it is reading T001W. Error description is UC_OBJECTS_NOT_CHARLIKE...

The current statement is defined for character-type data objects only.

Can you once check this??

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 21:30:25 GMT

Hmmm....Interesting. What version of r/3 are you working with.

Regards,

Rich Heilman

Re: Transferring multiple files to application server.

RichHeilman — Thu, 15 Dec 2005 21:33:42 GMT

Try it with T000 instead. This may be a unicode thing. I'm not really sure. You are probably not using T001w in your requirement anyway, right?



report zrich_0002.


data: it001 type table of t001.
data: xt001 type t001.

data: it000 type table of t000.
data: xt000 type t000.

types: begin of t_files,
       table(20) type c,
       wa(20) type c,
       file(100) type c,
       end of t_files.

data: ifiles type table of t_files.
data: xfiles type t_files.

field-symbols: <fs_datatab> type table,
               <fs_wa> .

start-of-selection.

  xfiles-table = 'IT001'.
  xfiles-wa    = 'XT001'.
  xfiles-file  = '/usr/sap/TST/t001.txt'.
  append xfiles to ifiles.

  xfiles-table = 'IT000'.
  xfiles-wa    = 'XT000'.
  xfiles-file  = '/usr/sap/TST/t000.txt'.
  append xfiles to ifiles.


  select * from t001 into table it001.
  select * from t000 into table it000.


  loop at ifiles into xfiles.

    perform download_file using xfiles-table
                                xfiles-wa
                                xfiles-file.

  endloop.

*---------------------------------------------------------------------*
*       FORM download_file                                            *
*---------------------------------------------------------------------*
form download_file using data_tab wa file.

  assign (data_tab) to <fs_datatab>.
  assign (wa) to <fs_wa>.

  open dataset file for output in binary mode.
  if sy-subrc = 0.
    loop at <fs_datatab> into <fs_wa>.
      transfer <fs_wa> to file.
    endloop.
  endif.

  close dataset file.

endform.

Regards,

Rich Heilman