Re: Control Break Statements

Former Member — Fri, 07 Mar 2008 17:14:22 GMT

Hi ,

At New

1. When a new record comes at new triggers. Atnew only used inside loop and endloop.

2. At new is controlbreak statment on at new the left side field change, the event

trigers and the values become 0 and *

On Change

1. On change of works same like at-new but the diff is it can be used out side of a loop,like select and

endselect,case endcase.

2.. on change of is not a control break statement and we can use onchange of out side the loop

and

The Major difference between the two is that AT NEW can be

used ONLY for INTERNAL TABLES, while ON CHANGE OF can be used for any loop processing i.e do..enddo, while..endwhile and loop..endloop also.

When we use At new for a field, it will trigger whenever there is any change in al lthe fields from the left to that of the particular field. But when we use On change of it triggers only when there is any change in the particular field.

At new can only be used inside loop. On change of can used outside the loop.

No logical Expressions can be added with at new. Logical expressions like AND OR can be used with on change of.

When AT NEW occurs, the alpha-numeric fields have * in their value,where as in case of On Change, the alphanumeric fields have their Corresponding value, of that particular record, where the Event gets fired.

On Change of executes for the first value of field too, this is not the case with At New.

On change of cannot be used in ABAP objects At new can be used in this.

Regards,

Re: Control Break Statements

Former Member — Sat, 08 Mar 2008 05:52:16 GMT

One more diff is:

In case of AT NEW,

At a time we specify one filed name. But we can call n no.of times with different field names.

Loop itab.

at new f

end at.

at new g

endat.

endloop.

In case of on change of,

we specify more than one field at a time.

on change of f g.

endon.

At Statements:

The AT statement introduces a statement block that you end with the ENDAT statement.

AT level.

statement block

ENDAT.

You can react to the following control level changes:

level

Meaning

FIRST

First line of the internal table

LAST

Last line of the internal table

NEW f

Beginning of a group of lines with the same contents in the field f and in the fields left of f

END Of f

End of a group of lines with the same contents in the field f and in the fields left of f

You can use control level statements to react to control breaks in internal tables instead of programming them yourself with logical expressions. Within the loop, you must order the AT-ENDATstatement blocks according to the hierarchy of the control levels. If the internal table itab has the columns f1, f2,.... and if it is sorted by these columns, you must program the loop as follows:

LOOP AT itab.

AT FIRST.... ENDAT.

AT NEW f1....... ENDAT.

AT NEW f2....... ENDAT.

.......

single record processing

.......

AT END OF f2.... ENDAT.

AT END OF f1.... ENDAT.

AT LAST..... ENDAT.

ENDLOOP.

The innermost hierarchy level single line processing processes the table lines that do not correspond to a control level change. You do not have to use all control level statements. But you must place the ones that you use in the above sequence. You should not use control level statements in loops where the line selection is restricted by WHERE or FROM and TO. Neither should the table be modified during the loop.

If a control level field f1, f2,.... is not known until runtime, you can specify it dynamically as (n1), (n2), … where n1, n2,.... contains the field of f1, f2,.... . If n1, n2,.... is empty at runtime, the criterion for changing the control level is ignored. You can further restrict the group level fields f1, f2,.... to partial fields by specifying offset and length.

If you are working with a work area wa, it does not contain the current line in the AT-ENDATstatement block. All character fields to the right of the current group key are filled with asterisks (*). All other fields to the right of the current group key contain their initial value.

Within an AT-ENDAT block, you can calculate the contents of the numeric fields of the corresponding control level using the SUMstatement.

You can only use this statement within a LOOP. If you use SUM in an AT-ENDAT block, the system calculates totals for the numeric fields of all lines in the current line group and writes them to the corresponding fields in the work area (see example in ). If you use the SUM statement outside an AT-ENDAT block (single entry processing), the system calculates totals for the numeric fields of all lines of the internal table in each loop pass and writes them to the corresponding fields of the work area. It therefore only makes sense to use the SUM statement in AT-ENDAT blocks.

If the table contains a nested table, you cannot use the SUMstatement. Neither can you use it if you are using a field symbol instead of a work area in the LOOP statement.

REPORT demo_int_tables_at_1.

DATA: BEGIN OF line,

col1(1) TYPE c,

col2 TYPE i,

col3 TYPE i,

END OF line.

DATA itab LIKE HASHED TABLE OF line

WITH UNIQUE KEY col1 col2.

line-col1 = 'A'.

DO 3 TIMES.

line-col2 = sy-index.

line-col3 = sy-index ** 2.

INSERT line INTO TABLE itab.

ENDDO.

line-col1 = 'B'.

DO 3 TIMES.

line-col2 = 2 * sy-index.

line-col3 = ( 2 * sy-index ) ** 2.

INSERT line INTO TABLE itab.

ENDDO.

SORT itab.

LOOP AT itab INTO line.

WRITE: / line-col1, line-col2, line-col3.

AT END OF col1.

SUM.

ULINE.

WRITE: / line-col1, line-col2, line-col3.

SKIP.

ENDAT.

AT LAST.

SUM.

ULINE.

WRITE: / line-col1, line-col2, line-col3.

ENDAT.

ENDLOOP.

The list output is:

A 1 1

A 2 4

A 3 9

________________________________

A 6 14

B 2 4

B 4 16

B 6 36

________________________________

B 12 56

________________________________

18 70

The program creates a hashed table itab, fills it with six lines, and sorts it. In the LOOP - ENDLOOP block, the work area LINE is output for each loop pass. The first field of the table key, col1, is used for control level processing. The total for all numeric fields is always calculated when the contents of col1 change and when the system is in the last loop pass.

REPORT demo_int_tables_at_2.

DATA: BEGIN OF line,

carrid TYPE sbook-carrid,

connid TYPE sbook-connid,

fldate TYPE sbook-fldate,

custtype TYPE sbook-custtype,

class TYPE sbook-class,

bookid TYPE sbook-bookid,

END OF line.

DATA itab LIKE SORTED TABLE OF line WITH UNIQUE KEY table_line.

SELECT carrid connid fldate custtype class bookid

FROM sbook INTO CORRESPONDING FIELDS OF TABLE itab.

LOOP AT itab INTO line.

AT FIRST.

WRITE / 'List of Bookings'.

ULINE.

ENDAT.

AT NEW carrid.

WRITE: / 'Carrid:', line-carrid.

ENDAT.

AT NEW connid.

WRITE: / 'Connid:', line-connid.

ENDAT.

AT NEW fldate.

WRITE: / 'Fldate:', line-fldate.

ENDAT.

AT NEW custtype.

WRITE: / 'Custtype:', line-custtype.

ENDAT.

WRITE: / line-bookid, line-class.

AT END OF class.

ULINE.

ENDAT.

ENDLOOP.

In this example, the sorted internal table itab is filled with data from the database table SBOOK using the Open SQL statement SELECT. The sequence of the columns in the internal table defines the control level hierarchy. Since the table key is the entire line, the sort sequence and the control level hierarchy are the same. The sequence of the AT-ENDAT blocks within the LOOP - ENDLOOP statements is important.

The output looks something like this:

List of Bookings

Carrid: AA

Connid: 0017

Fldate: 1998/11/22

Custtype: B

00063509 C

00063517 C

...

______________________________________________

00063532 F

00063535 F

...

______________________________________________

Custtype: P

00063653 C

00063654 C

...

______________________________________________

00063668 F

00063670 F

...

______________________________________________

Fldate: 1998/29/11

Custtype: B

00064120 C

00064121 C

...

and so on.

On chnage of event:

ON CHANGE OF dobj [OR dobj1 [OR dobj2] ... ].

statement_block

ENDON.

Effect:

The statements ON CHANGE OF and ENDON, which are forbidden in classes, define a control structure that can contain a statement block statement_block. After ON CHANGE OF, any number of data objects dobj1, dobj2... of any data type can be added, linked by OR.

The first time a statement ON CHANGE OF is executed, the statement block is executed if at least one of the specified data objects is not initial. The statement block is executed for each additional execution of the same statement ON CHANGE OF, if the content of one of the specified data objects has been changed since the last time the statement ON CHANGE OF was executed.

For each time the statement ON CHANGE OF is executed, the content of all the specified data objects is saved as an auxiliary variable internally in the global system. The auxiliary variable is linked to this statement and cannot be accessed in the program. The auxiliary variables and their contents are retained longer than the lifetime of procedures. An auxiliary variable of this type can only be initialized if its statement ON CHANGE OF is executed while the associated data object is initial.

Note:

This control structure, which is forbidden in classes, is particularly prone to errors and should be replaced by branches with explicitly declared auxiliary variables.

Example:

In a SELECT loop, a statement block should only be executed if the content of the column CARRID has changed.

DATA spfli_wa TYPE spfli.

SELECT *

FROM spfli

INTO spfli_wa

ORDER BY carrid.

...

ON CHANGE OF spfli_wa-carrid.

...

ENDON.

...

ENDSELECT.

The following section of a program shows how the ON control structure can be replaced by an IF control structure with an explicit auxiliary variable carrid_buffer.

DATA carrid_buffer TYPE spfli-carrid.

CLEAR carrid_buffer.

SELECT *

FROM spfli

INTO spfli_wa

ORDER BY carrid.

...

IF spfli_wa-carrid <> carrid_buffer.

carrid_buffer = spfli_wa-carrid.

...

ENDIF.

...

ENDSELECT.

If it is helpful rewards points.

Regards

Pratap.M

topic Re: Control Break Statements in Application Development and Automation Discussions

Control Break Statements

Re: Control Break Statements

Re: Control Break Statements