topic Re: Dynamic Structure Creation in Application Development and Automation Discussions

Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 13:11:16 GMT

Hi All.

I want to create a structure during runtime. There are 3 fields A,B,C.

During Creation of Structure it MIGHT Have any combination of components A,B,C.

How do i create that structure.

For eg: Struct 1,

A Type ....

B Type ...

End of Struct 1.

Struct 2

B Type...

C Type..

End Struct 2.

Struct 3

B Type...

End Struct 2.

So the Dynamically structure can have any components ?

PLEASE HELP URGENTLY.

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 13:21:40 GMT

This seems to be easy:

Have you ever heard of RTTI (Run Time Type Interface)?

To create a descriptor of a structure dynamically at run time, call the static method CREATE of class CL_ABAP_STRUCTDESCR and provide a list of the components to parameter P_COMPONENTS. The result is a descriptor of that structure.

Afterwards you may execute CREATE DATA ... TYPE HANDLE structure descriptor to create a data object having this structure.

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 13:23:44 GMT

Hi,

use field-groups in stead of creating the structure.

REPORT demo_extract.

NODES: spfli, sflight.

FIELD-GROUPS: header, flight_info, flight_date.

START-OF-SELECTION.

INSERT: spfli-carrid spfli-connid

INTO header,

spfli-cityfrom spfli-cityto

INTO flight_info.

INSERT:sflight-fldate INTO header.

(after inserting the fields u want u can extract this will stop further insertion of the fields)

GET spfli. (instead u can use selection statements here)

EXTRACT flight_info.

(move the values in the fields to some internal table)

GET sflight.

EXTRACT flight_date.

(move the values in the fields to some internal table)

end-of-selection.

(u can print the data here)

rgds,

bharat.

Re: Dynamic Structure Creation

RichHeilman — Wed, 06 Feb 2008 13:29:18 GMT

I think if you want the structure to be dynamic, you need to build it on the fly, in this case I think you need to create a dynamic internal table first, and then create structure or work area based off that. Check this blog for the solution. Check the part where <dyn_wa> is created, this is a field symbol for a dynamically built structure.

/people/rich.heilman2/blog/2005/07/27/dynamic-internal-tables-and-structures--abap

Regards,

Rich Heilman

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 13:31:48 GMT

good

check this code of creating dynamic structure and work accordingly,hope this would give you the solution of your problem.

REPORT zmaschl_create_data_dynamic .

TYPE-POOLS: slis.

DATA: it_fcat TYPE slis_t_fieldcat_alv,

is_fcat LIKE LINE OF it_fcat.

DATA: it_fieldcat TYPE lvc_t_fcat,

is_fieldcat LIKE LINE OF it_fieldcat.

DATA: new_table TYPE REF TO data.

DATA: new_line TYPE REF TO data.

FIELD-SYMBOLS: <l_table> TYPE ANY TABLE,

<l_line> TYPE ANY,

<l_field> TYPE ANY.

Build fieldcat

CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'

EXPORTING

i_structure_name = 'SYST'

CHANGING

ct_fieldcat = it_fcat[].

LOOP AT it_fcat INTO is_fcat WHERE NOT reptext_ddic IS initial.

MOVE-CORRESPONDING is_fcat TO is_fieldcat.

is_fieldcat-fieldname = is_fcat-fieldname.

is_fieldcat-ref_field = is_fcat-fieldname.

is_fieldcat-ref_table = is_fcat-ref_tabname.

APPEND is_fieldcat TO it_fieldcat.

ENDLOOP.

Create a new Table

CALL METHOD cl_alv_table_create=>create_dynamic_table

EXPORTING

it_fieldcatalog = it_fieldcat

IMPORTING

ep_table = new_table.

Create a new Line with the same structure of the table.

ASSIGN new_table->* TO <l_table>.

CREATE DATA new_line LIKE LINE OF <l_table>.

ASSIGN new_line->* TO <l_line>.

Test it...

DO 30 TIMES.

ASSIGN COMPONENT 'SUBRC' OF STRUCTURE <l_line> TO <l_field>.

<l_field> = sy-index.

INSERT <l_line> INTO TABLE <l_table>.

ENDDO.

LOOP AT <l_table> ASSIGNING <l_line>.

ASSIGN COMPONENT 'SUBRC' OF STRUCTURE <l_line> TO <l_field>.

WRITE <l_field>.

ENDLOOP.

thanks

mrutyun^

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 13:38:08 GMT

Rich:

You don´t have to create an internal table first. You can create a structure descriptor using RTTI (CL_ABAP_STRUCTDESCR) and create an data object afterwards referencing this structure descriptor.

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 13:47:50 GMT

Here an example:


TYPE-POOLS:
  abap.

DATA:
  gr_structdescr    TYPE REF TO cl_abap_structdescr,
  gt_components     TYPE abap_component_tab,
  gw_component      TYPE LINE OF abap_component_tab,
  gr_wa             TYPE REF TO data.


START-OF-SELECTION.

* determine components of structure -> GT_COMPONENTS
  MOVE 'COMP1' TO gw_component-name.
  gw_component-type ?= cl_abap_elemdescr=>get_string( ).
  INSERT gw_component INTO TABLE gt_components.

  MOVE 'COMP2' TO gw_component-name.
  gw_component-type ?= cl_abap_elemdescr=>get_i( ).
  INSERT gw_component INTO TABLE gt_components.


* get structure descriptor -> GR_STRUCTDESCR
  gr_structdescr ?= cl_abap_structdescr=>create( gt_components ).


* create work area of structure GR_STRUCTDESCR -> GR_WA
  CREATE DATA gr_wa TYPE HANDLE gr_structdescr.

<REMOVED BY MODERATOR>

Edited by: Alvaro Tejada Galindo on Feb 11, 2008 5:18 PM

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 14:23:00 GMT

Rich

how can you create internal table first. The fields that structure will have as an component will come from selection screens where users will select by checking the checkbox that i want these fields in the internal table.

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 14:25:04 GMT

Mike.

How do you describe fields/components as KEY using RTTI

Beacuase some components will act as a key in internal table.

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 14:36:17 GMT

Here the enhanced coding, that also creates an internal table:


TYPE-POOLS:
  abap.

DATA:
  gr_structdescr    TYPE REF TO cl_abap_structdescr,
  gr_tabledescr     TYPE REF TO cl_abap_tabledescr,
  gt_components     TYPE abap_component_tab,
  gw_component      TYPE LINE OF abap_component_tab,
  gt_keys           TYPE abap_keydescr_tab,
  gw_key            TYPE LINE OF abap_keydescr_tab,
  gr_wa             TYPE REF TO data,
  gr_itab           TYPE REF TO data.


FIELD-SYMBOLS:
  <gw_wa>           TYPE ANY,
  <gt_itab>         TYPE ANY TABLE.


START-OF-SELECTION.

* determine components of structure -> GT_COMPONENTS
  MOVE 'COMP1' TO gw_component-name.
  gw_component-type ?= cl_abap_elemdescr=>get_string( ).
  INSERT gw_component INTO TABLE gt_components.

  MOVE 'COMP2' TO gw_component-name.
  gw_component-type ?= cl_abap_elemdescr=>get_i( ).
  INSERT gw_component INTO TABLE gt_components.


* get structure descriptor -> GR_STRUCTDESCR
  gr_structdescr ?= cl_abap_structdescr=>create( gt_components ).


* create work area of structure GR_STRUCTDESCR -> GR_WA
  CREATE DATA gr_wa TYPE HANDLE gr_structdescr.

  ASSIGN gr_wa->* TO <gw_wa>.


* determine key components -> GT_KEYS
  MOVE 'COMP1' TO gw_key-name.
  INSERT gw_key INTO TABLE gt_keys.


* create descriptor for internal table -> GR_TABLEDESCR
  gr_tabledescr ?= cl_abap_tabledescr=>create( p_line_type  = gr_structdescr
                                               p_table_kind = cl_abap_tabledescr=>tablekind_hashed
                                               p_unique     = abap_true
                                               p_key        = gt_keys
                                               p_key_kind   = cl_abap_tabledescr=>keydefkind_user ).


* create internal table -> GR_ITAB
  CREATE DATA gr_itab TYPE HANDLE gr_tabledescr.

  ASSIGN gr_itab->* TO <gt_itab>.

  sy-subrc = sy-subrc.

<REMOVED BY MODERATOR>

Edited by: Alvaro Tejada Galindo on Feb 11, 2008 5:19 PM

Re: Dynamic Structure Creation

RichHeilman — Wed, 06 Feb 2008 14:44:29 GMT

Very nice Mike. I like it. I did not know that you could create a structure by adding the components like that. Very nice. Thanks.

Regards,

Rich Heilman

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 14:53:49 GMT

Mike.

Thats a good one. Will assign points.

May i have your email address in case i need to contact you please Mike ?

Re: Dynamic Structure Creation

Former Member — Wed, 06 Feb 2008 15:38:05 GMT

@AMC:

Thanks. Have a look at my Profile here in SDN by clicking my name on the left side of this message, there you should find my eMail address, don´t you?!

--MIKE

Re: Dynamic Structure Creation

Former Member — Fri, 08 Feb 2008 16:54:13 GMT

Matt,

I have a function module that has dynamic generation of internal table code. The generation has succesfully.

How do i call the function module given the and get back a dynamic internal table given the above code in the function module

Please help

Re: Dynamic Structure Creation

Former Member — Mon, 11 Feb 2008 07:47:44 GMT

Could you please paste the code of your FM? That would make things easier

Re: Dynamic Structure Creation

Former Member — Mon, 11 Feb 2008 20:10:38 GMT

Guys,

I understood that part. Thats fine.

Another challenge that i am facing now is that i want to use RTTC/RTTI to dynamically create a internal table looking at th e structure of another internal table.

For eg: Table A is created dynamically by the system and then i want to create another Table B dynamically looking at the structure of Table A.

Please help. THis is very important to my work.

Re: Dynamic Structure Creation

Former Member — Mon, 11 Feb 2008 21:23:12 GMT

Hi AMC,

you can use the RTTI type descriptor (table type) more than just one time. So it should be no problem to create another internal table of the same type...

--MIKE

Re: Dynamic Structure Creation

Former Member — Tue, 12 Feb 2008 09:00:00 GMT

Do you have an example code please. The important thing to this is that the keys are different. Table A has 2 keys and Tale B has 3 keys

Please provide an code example

Re: Dynamic Structure Creation

Former Member — Tue, 12 Feb 2008 09:37:46 GMT


TYPE-POOLS:
  abap.
 
DATA:
  gr_structdescr    TYPE REF TO cl_abap_structdescr,
  gr_tabledescr1    TYPE REF TO cl_abap_tabledescr,
  gr_tabledescr2    TYPE REF TO cl_abap_tabledescr,
  gt_components     TYPE abap_component_tab,
  gw_component      TYPE LINE OF abap_component_tab,
  gt_keys           TYPE abap_keydescr_tab,
  gw_key            TYPE LINE OF abap_keydescr_tab,
  gr_wa             TYPE REF TO data,
  gr_itab1          TYPE REF TO data,
  gr_itab2			TYPE REF TO data.
 
 
FIELD-SYMBOLS:
  <gw_wa>           TYPE ANY,
  <gt_itab1>        TYPE ANY TABLE,
  <gt_itab2>		TYPE ANY TABLE.
 
 
START-OF-SELECTION.
 
* determine components of structure -> GT_COMPONENTS
  MOVE 'COMP1' TO gw_component-name.
  gw_component-type ?= cl_abap_elemdescr=>get_string( ).
  INSERT gw_component INTO TABLE gt_components.
 
  MOVE 'COMP2' TO gw_component-name.
  gw_component-type ?= cl_abap_elemdescr=>get_i( ).
  INSERT gw_component INTO TABLE gt_components.
 
 
* get structure descriptor -> GR_STRUCTDESCR
  gr_structdescr ?= cl_abap_structdescr=>create( gt_components ).
 
 
* create work area of structure GR_STRUCTDESCR -> GR_WA
  CREATE DATA gr_wa TYPE HANDLE gr_structdescr.
 
  ASSIGN gr_wa->* TO <gw_wa>.
 
 
* determine key components -> GT_KEYS
  MOVE 'COMP1' TO gw_key-name.
  INSERT gw_key INTO TABLE gt_keys.
 
 
* create descriptor for internal table -> GR_TABLEDESCR1
  gr_tabledescr1 ?= cl_abap_tabledescr=>create( p_line_type  = gr_structdescr
                                               p_table_kind = cl_abap_tabledescr=>tablekind_hashed
                                               p_unique     = abap_true
                                               p_key        = gt_keys
                                               p_key_kind   = cl_abap_tabledescr=>keydefkind_user ).
 
 
* create internal table -> GR_ITAB1
  CREATE DATA gr_itab1 TYPE HANDLE gr_tabledescr1.
 
  ASSIGN gr_itab1->* TO <gt_itab1>.
  
  
* determine key components -> GT_KEYS
  MOVE 'COMP2' TO gw_key-name.
  INSERT gw_key INTO TABLE gt_keys.
 
 
* create descriptor for internal table -> GR_TABLEDESCR2
  gr_tabledescr2 ?= cl_abap_tabledescr=>create( p_line_type  = gr_structdescr
                                               p_table_kind = cl_abap_tabledescr=>tablekind_hashed
                                               p_unique     = abap_true
                                               p_key        = gt_keys
                                               p_key_kind   = cl_abap_tabledescr=>keydefkind_user ).
 
 
* create internal table -> GR_ITAB2
  CREATE DATA gr_itab2 TYPE HANDLE gr_tabledescr2.
 
  ASSIGN gr_itab2->* TO <gt_itab2>.
  
  
  
* <GT_ITAB1> has a key with 1 component
* <GT_ITAB2> has a key with 2 components

Re: Dynamic Structure Creation

Former Member — Tue, 12 Feb 2008 09:50:42 GMT

Many Thanks.

My problem is that i am not creating the structure from the scratch but i have the internal table of type hashed and i want to use that table to modify the keys of the same hashed table or the new hashed table.

Please help with code sample i am appreciating your every second here.