topic Re: alv oops in Application Development and Automation Discussions

alv oops

Former Member — Thu, 27 Sep 2007 04:26:01 GMT

Hi friends,

i want to develop a report with oops can any one give me the basic programming concepts and method if possible.

Thanks in advance,

Sasi.

Re: alv oops

Former Member — Thu, 27 Sep 2007 04:29:49 GMT

hi sasi,

The following example shows the object-oriented aspect of function groups in the simple case of a counter.

Suppose we have a function group called COUNTER:

FUNCTION-POOL COUNTER.

DATA COUNT TYPE I.

FUNCTION SET_COUNTER.

Local Interface IMPORTING VALUE(SET_VALUE)

COUNT = SET_VALUE.

ENDFUNCTION.

FUNCTION INCREMENT_COUNTER.

ADD 1 TO COUNT.

ENDFUNCTION.

FUNCTION GET_COUNTER.

Local Interface: EXPORTING VALUE(GET_VALUE)

GET_VALUE = COUNT.

ENDFUNCTION.

The function group has a global integer field COUNT, and three function modules, SET_COUNTER, INCREMENT_COUNTER, and GET_COUNTER, that work with the field. Two of the function modules have input and output parameters. These form the data interface of the function group.

Any ABAP program can then work with this function group. For example:

DATA NUMBER TYPE I VALUE 5.

CALL FUNCTION 'SET_COUNTER' EXPORTING SET_VALUE = NUMBER.

DO 3 TIMES.

CALL FUNCTION 'INCREMENT_COUNTER'.

ENDDO.

CALL FUNCTION 'GET_COUNTER' IMPORTING GET_VALUE = NUMBER.

After this section of the program has been processed, the program variable NUMBER will have the value 8.

The program itself cannot access the COUNT field in the function group. Operations on this field are fully encapsulated in the function module. The program can only communicate with the function group by calling its function modules.

CLASS C_COUNTER DEFINITION.

PUBLIC SECTION.

METHODS: SET_COUNTER IMPORTING VALUE(SET_VALUE) TYPE I,

INCREMENT_COUNTER,

GET_COUNTER EXPORTING VALUE(GET_VALUE) TYPE I.

PRIVATE SECTION.

DATA COUNT TYPE I.

ENDCLASS.

CLASS C_COUNTER IMPLEMENTATION.

METHOD SET_COUNTER.

COUNT = SET_VALUE.

ENDMETHOD.

METHOD INCREMENT_COUNTER.

ADD 1 TO COUNT.

ENDMETHOD.

METHOD GET_COUNTER.

GET_VALUE = COUNT.

ENDMETHOD.

ENDCLASS.

The class C_COUNTER contains three public methods - SET_COUNTER, INCREMENT_COUNTER, and GET_COUNTER. Each of these works with the private integer field COUNT. Two of the methods have input and output parameters. These form the data interface of the class. The field COUNT is not outwardly visible.

The example in the section Working with Objects shows how you can create instances of the class C_COUNTER.

Inheritance: Introductory Example

The following simple example shows the principle of inheritance within ABAP Objects. It is based on the Simple Introduction to Classes. A new class counter_ten inherits from the existing class counter.

REPORT demo_inheritance.

CLASS counter DEFINITION.

PUBLIC SECTION.

METHODS: set IMPORTING value(set_value) TYPE i,

increment,

get EXPORTING value(get_value) TYPE i.

PROTECTED SECTION .

DATA count TYPE i.

ENDCLASS.

CLASS counter IMPLEMENTATION.

METHOD set.

count = set_value.

ENDMETHOD.

METHOD increment.

ADD 1 TO count.

ENDMETHOD.

METHOD get.

get_value = count.

ENDMETHOD.

ENDCLASS.

CLASS counter_ten DEFINITION INHERITING FROM counter.

PUBLIC SECTION.

METHODS increment REDEFINITION .

DATA count_ten.

ENDCLASS.

CLASS counter_ten IMPLEMENTATION.

METHOD increment.

DATA modulo TYPE I.

CALL METHOD super->increment .

write / count.

modulo = count mod 10.

IF modulo = 0.

count_ten = count_ten + 1.

write count_ten.

ENDIF.

ENDMETHOD.

ENDCLASS.

DATA: count TYPE REF TO counter,

number TYPE i VALUE 5.

START-OF-SELECTION.

CREATE OBJECT count TYPE counter_ten .

CALL METHOD count->set EXPORTING set_value = number.

DO 20 TIMES.

CALL METHOD count->increment.

ENDDO.

The class COUNTER_TEN is derived from COUNTER. It redefines the method INCREMENT. To do this, you must change the visibility of the COUNT attribute from PRIVATE to PROTECTED. The redefined method calls the obscured method of the superclass using the pseudoreference SUPER->. The redefined method is a specialization of the inherited method.

The example instantiates the subclass. The reference variable pointing to it has the type of the superclass. When the INCREMENT method is called using the superclass reference, the system executes the redefined method from the subclass.

Interfaces - Introductory Example

The following simple example shows how you can use an interface to implement two counters that are different, but can be addressed in the same way. See also the example in the Classes section.

INTERFACE I_COUNTER.

METHODS: SET_COUNTER IMPORTING VALUE(SET_VALUE) TYPE I,

INCREMENT_COUNTER,

GET_COUNTER EXPORTING VALUE(GET_VALUE) TYPE I.

ENDINTERFACE.

CLASS C_COUNTER1 DEFINITION.

PUBLIC SECTION.

INTERFACES I_COUNTER.

PRIVATE SECTION.

DATA COUNT TYPE I.

ENDCLASS.

CLASS C_COUNTER1 IMPLEMENTATION.

METHOD I_COUNTER~SET_COUNTER.

COUNT = SET_VALUE.

ENDMETHOD.

METHOD I_COUNTER~INCREMENT_COUNTER.

ADD 1 TO COUNT.

ENDMETHOD.

METHOD I_COUNTER~GET_COUNTER.

GET_VALUE = COUNT.

ENDMETHOD.

ENDCLASS.

CLASS C_COUNTER2 DEFINITION.

PUBLIC SECTION.

INTERFACES I_COUNTER.

PRIVATE SECTION.

DATA COUNT TYPE I.

ENDCLASS.

CLASS C_COUNTER2 IMPLEMENTATION.

METHOD I_COUNTER~SET_COUNTER.

COUNT = ( SET_VALUE / 10) * 10.

ENDMETHOD.

METHOD I_COUNTER~INCREMENT_COUNTER.

IF COUNT GE 100.

MESSAGE I042(00).

COUNT = 0.

ELSE.

ADD 10 TO COUNT.

ENDIF.

ENDMETHOD.

METHOD I_COUNTER~GET_COUNTER.

GET_VALUE = COUNT.

ENDMETHOD.

ENDCLASS.

The interface I_COUNTER contains three methods SET_COUNTER, INCREMENT_COUNTER, and GET_COUNTER. The classes C_COUNTER1 and C_COUNTER2 implement the interface in the public section. Both classes must implement the three interface methods in their implementation part. C_COUNTER1 is a class for counters that can have any starting value and are then increased by one. C_COUNTER2 is a class for counters that can only be increased in steps of 10. Both classes have an identical outward face. It is fully defined by the interface in both cases.

The following sections explain how a user can use an interface reference to address the objects of both classes:

Events: Introductory Example

The following simple example shows the principle of events within ABAP Objects. It is based on the Simple Introduction to Classes. An event critical_value is declared and triggered in class counter.

REPORT demo_class_counter_event.

CLASS counter DEFINITION.

PUBLIC SECTION.

METHODS increment_counter.

EVENTS critical_value EXPORTING value(excess) TYPE i.

PRIVATE SECTION.

DATA: count TYPE i,

threshold TYPE i VALUE 10.

ENDCLASS.

CLASS counter IMPLEMENTATION.

METHOD increment_counter.

DATA diff TYPE i.

ADD 1 TO count.

IF count > threshold.

diff = count - threshold.

RAISE EVENT critical_value EXPORTING excess = diff.

ENDIF.

ENDMETHOD.

ENDCLASS.

CLASS handler DEFINITION.

PUBLIC SECTION.

METHODS handle_excess

FOR EVENT critical_value OF counter

IMPORTING excess.

ENDCLASS.

CLASS handler IMPLEMENTATION.

METHOD handle_excess.

WRITE: / 'Excess is', excess.

ENDMETHOD.

ENDCLASS.

DATA: r1 TYPE REF TO counter,

h1 TYPE REF TO handler.

START-OF-SELECTION.

CREATE OBJECT: r1, h1.

SET HANDLER h1->handle_excess FOR ALL INSTANCES.

DO 20 TIMES.

CALL METHOD r1->increment_counter.

ENDDO.

The class COUNTER implements a counter. It triggers the event CRITICAL_VALUE when a threshold value is exceeded, and displays the difference. HANDLER can handle the exception in COUNTER. At runtime, the handler is registered for all reference variables that point to the object.

Events in ABAP Objects - Example

The following example shows how to declare, call, and handle events in ABAP Objects.

Overview

This object works with the interactive list displayed below. Each user interaction triggers an event in ABAP Objects. The list and its data is created in the class C_LIST. There is a class STATUS for processing user actions. It triggers an event BUTTON_CLICKED in the AT USER-COMMAND event. The event is handled in the class C_LIST. It contains an object of the class C_SHIP or C_TRUCK for each line of the list. Both of these classes implement the interface I_VEHICLE. Whenever the speed of one of these objects changes, the event SPEED_CHANGE is triggered. The class C_LIST reacts to this and updates the list.

Constraints

The ABAP statements used for list processing are not yet fully available in ABAP Objects. However, to produce a simple test output, you can use the following statements:

WRITE [AT] /<offset>(<length>) <f>

ULINE

SKIP

NEW-LINE

Note: The behavior of formatting and interactive list functions in their current state are not guaranteed. Incompatible changes could occur in a future release.

Declarations

This example is implemented using local interfaces and classes. Below are the declarations of the interfaces and classes:

*****************************************************************

Interface and Class declarations

*****************************************************************

INTERFACE I_VEHICLE.

DATA MAX_SPEED TYPE I.

EVENTS SPEED_CHANGE EXPORTING VALUE(NEW_SPEED) TYPE I.

METHODS: DRIVE,

STOP.

ENDINTERFACE.

*----

CLASS C_SHIP DEFINITION.

PUBLIC SECTION.

METHODS CONSTRUCTOR.

INTERFACES I_VEHICLE.

PRIVATE SECTION.

ALIASES MAX FOR I_VEHICLE~MAX_SPEED.

DATA SHIP_SPEED TYPE I.

ENDCLASS.

*----

CLASS C_TRUCK DEFINITION.

PUBLIC SECTION.

METHODS CONSTRUCTOR.

INTERFACES I_VEHICLE.

PRIVATE SECTION.

ALIASES MAX FOR I_VEHICLE~MAX_SPEED.

DATA TRUCK_SPEED TYPE I.

ENDCLASS.

*----

CLASS STATUS DEFINITION.

PUBLIC SECTION.

CLASS-EVENTS BUTTON_CLICKED EXPORTING VALUE(FCODE) LIKE SY-UCOMM.

CLASS-METHODS: CLASS_CONSTRUCTOR,

USER_ACTION.

ENDCLASS.

*----

CLASS C_LIST DEFINITION.

PUBLIC SECTION.

METHODS: FCODE_HANDLER FOR EVENT BUTTON_CLICKED OF STATUS

IMPORTING FCODE,

LIST_CHANGE FOR EVENT SPEED_CHANGE OF I_VEHICLE

IMPORTING NEW_SPEED,

LIST_OUTPUT.

PRIVATE SECTION.

DATA: ID TYPE I,

REF_SHIP TYPE REF TO C_SHIP,

REF_TRUCK TYPE REF TO C_TRUCK,

BEGIN OF LINE,

ID TYPE I,

FLAG,

IREF TYPE REF TO I_VEHICLE,

SPEED TYPE I,

END OF LINE,

LIST LIKE SORTED TABLE OF LINE WITH UNIQUE KEY ID.

ENDCLASS.

*****************************************************************

The following events are declared in the example:

The instance event SPEED_CHANGE in the interface I_VEHICLE

The static event BUTTON_CLICKED in the class STATUS.

The class C_LIST contains event handler methods for both events.

Note that the class STATUS does not have any attributes, and therefore only works with static methods and events.

Implementations

Below are the implementations of the methods of the above classes:

*****************************************************************

Implementations

*****************************************************************

CLASS C_SHIP IMPLEMENTATION.

METHOD CONSTRUCTOR.

MAX = 30.

ENDMETHOD.

METHOD I_VEHICLE~DRIVE.

CHECK SHIP_SPEED < MAX.

SHIP_SPEED = SHIP_SPEED + 10.

RAISE EVENT I_VEHICLE~SPEED_CHANGE

EXPORTING NEW_SPEED = SHIP_SPEED.

ENDMETHOD.

METHOD I_VEHICLE~STOP.

CHECK SHIP_SPEED > 0.

SHIP_SPEED = 0.

RAISE EVENT I_VEHICLE~SPEED_CHANGE

EXPORTING NEW_SPEED = SHIP_SPEED.

ENDMETHOD.

ENDCLASS.

*----

CLASS C_TRUCK IMPLEMENTATION.

METHOD CONSTRUCTOR.

MAX = 150.

ENDMETHOD.

METHOD I_VEHICLE~DRIVE.

CHECK TRUCK_SPEED < MAX.

TRUCK_SPEED = TRUCK_SPEED + 50.

RAISE EVENT I_VEHICLE~SPEED_CHANGE

EXPORTING NEW_SPEED = TRUCK_SPEED.

ENDMETHOD.

METHOD I_VEHICLE~STOP.

CHECK TRUCK_SPEED > 0.

TRUCK_SPEED = 0.

RAISE EVENT I_VEHICLE~SPEED_CHANGE

EXPORTING NEW_SPEED = TRUCK_SPEED.

ENDMETHOD.

ENDCLASS.

*----

CLASS STATUS IMPLEMENTATION.

METHOD CLASS_CONSTRUCTOR.

SET PF-STATUS 'VEHICLE'.

WRITE 'Click a button!'.

ENDMETHOD.

METHOD USER_ACTION.

RAISE EVENT BUTTON_CLICKED EXPORTING FCODE = SY-UCOMM.

ENDMETHOD.

ENDCLASS.

*----

CLASS C_LIST IMPLEMENTATION.

METHOD FCODE_HANDLER .

CLEAR LINE.

CASE FCODE.

WHEN 'CREA_SHIP'.

ID = ID + 1.

CREATE OBJECT REF_SHIP.

LINE-ID = ID.

LINE-FLAG = 'C'.

LINE-IREF = REF_SHIP.

APPEND LINE TO LIST.

WHEN 'CREA_TRUCK'.

ID = ID + 1.

CREATE OBJECT REF_TRUCK.

LINE-ID = ID.

LINE-FLAG = 'T'.

LINE-IREF = REF_TRUCK.

APPEND LINE TO LIST.

WHEN 'DRIVE'.

CHECK SY-LILLI > 0.

READ TABLE LIST INDEX SY-LILLI INTO LINE.

CALL METHOD LINE-IREF->DRIVE.

WHEN 'STOP'.

LOOP AT LIST INTO LINE.

CALL METHOD LINE-IREF->STOP.

ENDLOOP.

WHEN 'CANCEL'.

LEAVE PROGRAM.

ENDCASE.

CALL METHOD LIST_OUTPUT.

ENDMETHOD.

METHOD LIST_CHANGE .

LINE-SPEED = NEW_SPEED.

MODIFY TABLE LIST FROM LINE.

ENDMETHOD.

METHOD LIST_OUTPUT.

SY-LSIND = 0.

SET TITLEBAR 'TIT'.

LOOP AT LIST INTO LINE.

IF LINE-FLAG = 'C'.

WRITE / ICON_WS_SHIP AS ICON.

ELSEIF LINE-FLAG = 'T'.

WRITE / ICON_WS_TRUCK AS ICON.

ENDIF.

WRITE: 'Speed = ', LINE-SPEED.

ENDLOOP.

ENDMETHOD.

ENDCLASS.

*****************************************************************

The static method USER_ACTION of the class STATUS triggers the static event BUTTON_CLICKED. The instance methods I_VEHICLE_{DRIVE and I_VEHICLE}STOP trigger the instance event I_VEHICLE~SPEED_CHANGE in the classes C_SHIP and C_TRUCK.

Using the Classes in a Program

The following program uses the above classes:

REPORT OO_EVENTS_DEMO NO STANDARD PAGE HEADING.

*****************************************************************

Global data of program

*****************************************************************

DATA LIST TYPE REF TO C_LIST.

*****************************************************************

Program events

*****************************************************************

START-OF-SELECTION.

CREATE OBJECT LIST.

SET HANDLER: LIST->FCODE_HANDLER,

LIST->LIST_CHANGE FOR ALL INSTANCES.

*----

AT USER-COMMAND.

CALL METHOD STATUS=>USER_ACTION.

*****************************************************************

The program creates an object of the class C_LIST and registers the event handler method FCODE_HANDLER of the object for the class event BUTTON_CLICKED, and the event handler method LIST_CHANGE for the event SPEED_CHANGE of all instances that implement the interface I_VEHICLE.

Gimme ur mail id. i will send more....

<b> Pls reward if helpful.</b>

Re: alv oops

Former Member — Thu, 27 Sep 2007 04:31:18 GMT

HI,

see this this code.

DATA:t_mara TYPE TABLE OF mara.

DATA:FCAT TYPE LVC_T_FCAT.

DATA:G_CONTAINER TYPE SCRFNAME VALUE 'TABC',"TABC is *container in screen 101

GRID TYPE REF TO CL_GUI_ALV_GRID,

G_CUSTOM_CONTAINER TYPE REF TO CL_GUI_CUSTOM_CONTAINER.

set screen 101.

MODULE STATUS_0101 output.

IF G_CUSTOM_CONTAINER IS INITIAL.

CREATE OBJECT G_CUSTOM_CONTAINER "CREATING OBJECT FOR CUSTOM CONTAINER

EXPORTING CONTAINER_NAME = G_CONTAINER.

CREATE OBJECT GRID "CREATING GRID IN WRKBNCH SCREEN

EXPORTING I_PARENT = G_CUSTOM_CONTAINER.

CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'

EXPORTING

I_STRUCTURE_NAME = 'MARA'

CHANGING

CT_FIELDCAT = FCAT[].

SELECT * from mara into table t_mara.

CALL METHOD GRID->SET_TABLE_FOR_FIRST_DISPLAY

CHANGING

IT_FIELDCATALOG = FCAT[]

IT_OUTTAB = t_MARA.

ENDIF.

ENDMODULE.

flow logic of screen 101:

PROCESS BEFORE OUTPUT.

MODULE STATUS_0101.

PROCESS AFTER INPUT.

rgds,

bharat.

Re: alv oops

Former Member — Thu, 27 Sep 2007 04:52:56 GMT

good

Here is the example codes

http://www.erpgenie.com/abap/controls/alvgrid.htm

https://www.sdn.sap.com/irj/sdn/wiki?path=/pages/viewpage.action&pageid=37566

thanks

mrutyun^

Re: alv oops

Former Member — Thu, 27 Sep 2007 05:14:43 GMT

Refer some std progs for help on it...

BCALVGRID* and press F4.

u ll get various progs as per need with comments for explanation