back ground process using abap program

Former Member — Tue, 21 Aug 2007 11:16:12 GMT

Hi,

How to create background process using job_open,Job_submit,job_close function modules

Re: back ground process using abap program

former_member189059 — Tue, 21 Aug 2007 11:17:45 GMT



DATA: lv_job_name         LIKE tbtco-jobname,
lv_job_nr           LIKE tbtco-jobcount,
lv_job_released     TYPE c,
lv_job_start_sofort TYPE c,
lv_print_parameters TYPE pri_params.
lv_job_name = 'Z_BGPROGRAM'.

  CALL FUNCTION 'JOB_OPEN'
    EXPORTING
      jobname          = lv_job_name
    IMPORTING
      jobcount         = lv_job_nr
    EXCEPTIONS
      cant_create_job  = 1
      invalid_job_data = 2
      jobname_missing  = 3
      OTHERS           = 4.
  IF syst-subrc = 0.
" submit job with all the selection screen params...
    SUBMIT (lv_job_name)
        WITH applfile = applfile " these are the parameters of the background program
        WITH p_lines = p_lines
        USER syst-uname " you must use this
       VIA JOB lv_job_name NUMBER lv_job_nr AND RETURN.
    IF sy-subrc = 0.
      CALL FUNCTION 'JOB_CLOSE'
        EXPORTING
          jobcount             = lv_job_nr
          jobname              = lv_job_name
          strtimmed            = 'X'
        IMPORTING
          job_was_released     = lv_job_released
        EXCEPTIONS
          cant_start_immediate = 1
          invalid_startdate    = 2
          jobname_missing      = 3
          job_close_failed     = 4
          job_nosteps          = 5
          job_notex            = 6
          lock_failed          = 7
          OTHERS               = 8.
      IF syst-subrc <> 0.
        MESSAGE i162(00) WITH
        'An error occured while closing the background job.'.
        STOP.
      ENDIF.
    ENDIF.
  ENDIF.
  SKIP 1.
  WRITE: / 'Background process', lv_job_name , 'called successfully' NO-GAP.
  WRITE: / 'You can check the job in transaction SM37'.

topic Re: back ground process using abap program in Application Development and Automation Discussions

back ground process using abap program

Re: back ground process using abap program