topic Re: Selection Screen in Application Development and Automation Discussions

Selection Screen

Former Member — Thu, 09 Aug 2007 17:37:25 GMT

Can i display more than one selection screen.

First -> Selection Screen:

Parameters & Select-options

Second -> Selection Screen

Parameters & Select-options

Third -> Output List

After the user select some parameters and select options - after execution it should display again a new selection screen and later Output list.

If Yes, then please mention how can i achieve it.

Re: Selection Screen

RichHeilman — Thu, 09 Aug 2007 17:49:29 GMT

Interesting requirement, with an equally interesting solution, yes?



report zrich_0001.

tables: sscrfields.

data: current_step type n.

selection-screen begin of block b1 with frame title text-001.
parameters: p_datum1 type sy-datum modif id gp1.
select-options s_datum1 for sy-datum modif id gp1.
selection-screen end of block b1.

selection-screen begin of block b2 with frame title text-002.
parameters: p_datum2 type sy-datum modif id gp2.
select-options s_datum2 for sy-datum modif id gp2.
selection-screen end of block b2.

at selection-screen output.

  loop at screen.
    if screen-group1 = 'GP2'
      and current_step = '0'.
      screen-active = '0'.
    endif.
    if screen-group1 = 'GP1'
       and current_step = '1'.
      screen-active = '0'.
    endif.
    modify screen.
  endloop.

at selection-screen.
  current_step = current_step + 1.

  check sy-ucomm = 'ONLI'
     or sy-ucomm = space.

  if current_step < 2.
    sscrfields-ucomm = space.
  elseif current_step = 2.
    sscrfields-ucomm = 'ONLI'.
    clear current_step.
  endif.


start-of-selection.

  write:/ 'This is your output list'.

Regards,

RIch Heilman

Re: Selection Screen

Former Member — Thu, 09 Aug 2007 18:04:54 GMT

Hi,

Yes it is possible to do so.Just make sure that there are different blocks for your selection screen parameters.

selection-screen: begin of block B1 or B2 and so on.

Thanks,

Sandeep.

Re: Selection Screen

Former Member — Fri, 10 Aug 2007 06:35:33 GMT

Thanks! Rich.

I would try this and let u know about it.

Can u let me know - what does the word sy-ucomm = 'ONLI' means.

Or what internally happens in "AT SELECTION SCREEN" event - where you are incrementing the step count and checking the sy-ucomm.

Earlier, I was trying to create a screen in SE51 and call the screen from program - but was not able to display "select-options and parameters".

Rich, I am having few questions on data transfer and posted it on SDN.

Can you please respond to the below thread -

Thanks

Kamal

Re: Selection Screen

Former Member — Fri, 10 Aug 2007 06:40:59 GMT

yes

you can creat 2 selection screens

1st design a selection screen its scren number by default 1000

creat a selection screen with other number

when u pres execute call that screen at that time

write logic for that screen

reward if usefull