topic Re: Trigger PAI in Application Development and Automation Discussions

Trigger PAI

aakash_neelaperumal2 — Mon, 27 Aug 2007 17:22:07 GMT

Normally in module pool programming PAI is triggered when we press a button or do some action in the screen. But my requirement is to trigger PAI automatically after PBO is complete(after the data is shown in the screen). Is there any function module to trigger PAI in the code.

Re: Trigger PAI

marcelo_ramos1 — Mon, 27 Aug 2007 17:53:25 GMT

Hi,

I think you can try use the Method "set_new_ok_code":



  CALL METHOD cl_gui_cfw=>set_new_ok_code
    EXPORTING
      new_code = '<Your New OKCODE>'.

Regards.

Marcelo Ramos

Re: Trigger PAI

alejandro_bindi — Mon, 27 Aug 2007 17:55:40 GMT

You can use this class method:


    CALL METHOD cl_gui_cfw=>set_new_ok_code
      EXPORTING
        new_code = 'XXXX'.

Problem is, after PAI, PBO automatically triggers, so you'll probably enter an endless loop (i'm not able to try out now). You should only trigger PAI automatically based on some condition that will change sometime, recheck your requirement.

Regards

Please reward points if helpful.

Message was edited by:

Alejandro Bindi

Re: Trigger PAI

aakash_neelaperumal2 — Mon, 27 Aug 2007 18:05:15 GMT

No this is not happening for module pool programming. PAI is not triggered...

Re: Trigger PAI

alejandro_bindi — Mon, 27 Aug 2007 18:12:27 GMT

What I mean is:

Normal module behaviour is:

PBO > [user action] > PAI > PBO > [user action] > PAI > PBO > [user action] > PAI ....

You intend to replace [user action] with an automatic triggering (using the method we suggested). So, taking [user action] out of the way:

PAI > PBO > PAI > PBO > PAI > PBO > PAI > PBO....

You will loose interaction which is the dialog program main purpose. To avoid that, you should call the method based on some condition which is not always true.

Hope you get it.

Regards

Re: Trigger PAI

aakash_neelaperumal2 — Mon, 27 Aug 2007 18:15:26 GMT

The automatic trigger of PAI will happen only after some regular time interval. So there wont be a problem in stopping the flow.

Re: Trigger PAI

alejandro_bindi — Mon, 27 Aug 2007 18:16:51 GMT

That's it, no problem then.

Regards

Re: Trigger PAI

RichHeilman — Mon, 27 Aug 2007 18:24:14 GMT

Do you want to automatically fire the PAI at some time interval, see this example.



REPORT  zrich_0001.

*----------------------------------------------------------------------*
*       CLASS lcl_event_handler DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_event_handler DEFINITION.

  PUBLIC SECTION.

    CLASS-METHODS: on_finished FOR EVENT finished OF cl_gui_timer.

ENDCLASS.                    "lcl_event_handler DEFINITION

DATA: gui_timer TYPE REF TO cl_gui_timer.
DATA: timeout TYPE i VALUE '3'.

PARAMETERS: p_datum TYPE sy-datum,
            p_uzeit TYPE sy-uzeit.

AT SELECTION-SCREEN OUTPUT.

  CREATE OBJECT gui_timer.

  SET HANDLER lcl_event_handler=>on_finished FOR gui_timer.

  gui_timer->interval = timeout.
  CALL METHOD gui_timer->run.

AT SELECTION-SCREEN.

  CASE sy-ucomm.
    WHEN 'REFR'.
* Do What ever
        p_datum = sy-datum.
        p_uzeit = sy-uzeit.

  ENDCASE.



*---------------------------------------------------------------------*
*       CLASS lcl_event_handler IMPLEMENTATION
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
CLASS lcl_event_handler IMPLEMENTATION.

  METHOD on_finished.

* Start Timer again
    gui_timer->interval = timeout.
    CALL METHOD gui_timer->run.

* cause PAI
    CALL METHOD cl_gui_cfw=>set_new_ok_code
      EXPORTING
        new_code = 'REFR'.

  ENDMETHOD.                    "on_finished

ENDCLASS.                    "lcl_event_handler IMPLEMENTATION

The implementatino is pretty much the same for a dynpro as well.

Regards,

Rich Heilman

Re: Trigger PAI

marcelo_ramos1 — Mon, 27 Aug 2007 18:25:39 GMT

Hi,

You can use the program <b>DEMO_CUSTOM_CONTROL</b> as example.

<b>Don't forget to close this Thread and reward points when your question be answered.</b>

Regards.

Marcelo Ramos