simple for u

Former Member — Tue, 17 Jul 2007 13:12:28 GMT

hello

friends

i had a zrub_client table and it had almost 20 attributes

i want the structure of that table in notepad or wordpad file or excel with datatypes and all

Please can u help me out

Hope u got my problem

i had copied the field names from se16 but from their datatypes are not comings

With Best Regards

Ruby

Re: simple for u

Former Member — Tue, 17 Jul 2007 13:15:13 GMT

Hi,

Goto that table in SE11 and press display, then press CNTR + Y then start the copying from first field to last field then press CNTR + C then come to your note pad then pate it there

Regards

Sudheer

Re: simple for u

Former Member — Tue, 17 Jul 2007 13:19:17 GMT

Thanx Friend

It Works

With Best Regards

Ruby

Re: simple for u

RaymondGiuseppi — Tue, 17 Jul 2007 13:21:18 GMT

I had frequently the same problem so I build a simple ALV report (5mn)

REPORT ZSE11ALV..

TABLES dfies.

DATA: header TYPE x030l,
      rc LIKE sy-subrc,
      fieldtab TYPE TABLE OF dfies,
      is_variant TYPE disvariant.

PARAMETERS: tabname LIKE dfies-tabname
              MEMORY ID dtb OBLIGATORY
              MATCHCODE OBJECT dd_tabl,
            p-varia LIKE disvariant-variant.

INITIALIZATION.
  PERFORM default_for_variant USING  sy-repid p-varia.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p-varia.
  PERFORM vari_f4 USING p-varia.

AT SELECTION-SCREEN ON tabname.
  CALL FUNCTION 'GET_FIELDTAB'
       EXPORTING
            tabname             = tabname
       IMPORTING
            header              = header
            rc                  = rc
       TABLES
            fieldtab            = fieldtab
       EXCEPTIONS
            internal_error      = 1
            no_texts_found      = 2
            table_has_no_fields = 3
            table_not_activ     = 4
            OTHERS              = 5.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

END-OF-SELECTION.

  is_variant-report = sy-repid.
  is_variant-variant = p-varia.

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
       EXPORTING
            i_bypassing_buffer = 'X'
            i_structure_name   = 'DFIES'
            i_default          = 'X'
            i_save             = 'A'
            is_variant         = is_variant
       TABLES
            t_outtab           = fieldtab
       EXCEPTIONS
            OTHERS             = 1.

*&---------------------------------------------------------------------*
*&      Form  vari_f4
*&---------------------------------------------------------------------*
FORM vari_f4 USING    p_p_varia.

  DATA: e_exit(1) TYPE c.

  is_variant-report = sy-repid.
  is_variant-variant = p_p_varia.

  CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
    EXPORTING
      is_variant                = is_variant
*     I_TABNAME_HEADER          =
*     I_TABNAME_ITEM            =
*     IT_DEFAULT_FIELDCAT       =
      i_save                    = 'A'
*     I_DISPLAY_VIA_GRID        = ' '
    IMPORTING
      e_exit                    = e_exit
      es_variant                = is_variant
    EXCEPTIONS
      not_found                 = 1
      program_error             = 2
      OTHERS                    = 3.

  IF sy-subrc = 1. " pas trouvé
    MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ELSE.
    IF e_exit = space.
      p_p_varia = is_variant-variant.
    ENDIF.
  ENDIF.
ENDFORM.                                                    " vari_f4

*&---------------------------------------------------------------------*
*&      Form  default_for_variant
*&---------------------------------------------------------------------*
FORM default_for_variant USING    value(p_report)
                                  p_variant.

  CLEAR is_variant.
  is_variant-report = p_report.
  CALL FUNCTION 'REUSE_ALV_VARIANT_DEFAULT_GET'
       EXPORTING
            i_save     = 'A'
       CHANGING
            cs_variant = is_variant
       EXCEPTIONS
            not_found  = 2.

  IF sy-subrc = 0.
    p_variant = is_variant-variant.
  ENDIF.

ENDFORM.                    " default_for_variant

Just build a default variant adapted to your needs.

Regards

topic Re: simple for u in Application Development and Automation Discussions

simple for u

Re: simple for u

Re: simple for u

Re: simple for u