Current method name (method meta data)

former_member185943 — Tue, 05 Jun 2007 13:46:28 GMT

Hello!

Is it possible to get meta data about current method being executed? For example:

CLASS lcl_some_class IMPLEMENTATION.
  METHOD some_method.
    DATA: l_method_name TYPE char50.
*   (do something to get method name)
    WRITE 'Current method is: ', l_method_name.
  ENDMETHOD.
ENDCLASS.

And the result would be something like:

LCL_SOME_CLASS->SOME_METHOD

Thanks!

Regards,

Igor

Re: Current method name (method meta data)

RichHeilman — Tue, 05 Jun 2007 13:55:21 GMT

Hi Igor, this may not be fool proof, but it does work in my case.




report zrich_0003 .

*---------------------------------------------------------------------*
*       CLASS lcl_some_class DEFINITION
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
class lcl_some_class definition.

  public section.
    class-methods: some_method.

endclass.


*---------------------------------------------------------------------*
*       CLASS lcl_some_class IMPLEMENTATION
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
class lcl_some_class implementation.
  method some_method.
    data: l_method_name type char50.
    data: icallstack type sys_callst.
    data: xcallstack like line of icallstack.

    call function 'SYSTEM_CALLSTACK'
         importing
              et_callstack = icallstack.


    read table icallstack into xcallstack index 1.
    if sy-subrc  = 0 and xcallstack-eventtype = 'METH'.
      l_method_name = xcallstack-eventname.
    endif.

*   (do something to get method name)
    write:/ 'Current method is: ', l_method_name.
  endmethod.
endclass.


start-of-selection.

  call method lcl_some_class=>some_method.

Regards,

Rich Heilman

Re: Current method name (method meta data)

former_member185943 — Tue, 05 Jun 2007 14:17:24 GMT

Thanks, Rich!

Good enough for me. I can get the class name using RTTI, so I guess I have it all.

Regards,

Igor

topic Re: Current method name (method meta data) in Application Development and Automation Discussions

Current method name (method meta data)

Re: Current method name (method meta data)

Re: Current method name (method meta data)