topic Re: Problem with local class, static private attribute and public method in Application Development and Automation Discussions

Problem with local class, static private attribute and public method

Former Member — Thu, 31 May 2007 12:08:25 GMT

Hello SDN,

Consider the following situation:

1) I have defined a LOCAL class airplane.

2) This class has a private static attribute "type table of ref to" airplane (array of airplanes)

3) A public method should return the private static table attribute

Problems:

a) The table cannot be given as an EXPORTING parameter in the method because TYPE TABLE OF... is not supported and I get syntax errors. I also cannot define a dictionary table type because it is a local class.

b) The table cannot be given as a TABLES parameter in the method because TABLES is not supported in the OO context.

c) The table cannot be given as an EXPORTING parameter in the method defined as LIKE myStaticAttribute because my method is PUBLIC and my attribute is PRIVATE. ABAP syntax requires that all PUBLIC statements are defined before PRIVATE ones, therefore it cannot find the attribute to reference to with LIKE.

I see only 2 solutions:

a) Never ever use local classes and always use global classes so that I might define a dictionary table type of my class which I can then use in my class.

b) Make the attribute public, but this goes against OO principles, and isn't really an option.

Am I missing anything here, or is this simply overlooked so far?

Re: Problem with local class, static private attribute and public method

oliver — Thu, 31 May 2007 12:30:38 GMT

Hi Nils,

all the stuff you mentioned should work once you define a table type in SE11. Define a new data structure of type "table type" and use this one.

Let me know, if you still have problems.

Regards,

Re: Problem with local class, static private attribute and public method

Former Member — Thu, 31 May 2007 12:33:32 GMT

I'm afraid this is impossible, since it is a local class and not a global one. The dictionary does not recognize the class type outside of the ABAP report where I defined the class in, therefore, the problem cannot be solved this way.

Re: Problem with local class, static private attribute and public method

oliver — Thu, 31 May 2007 12:39:29 GMT

If I understand you correctly, the dictionary doesn't have to know your local class. Dictionary types are global and by that also known in your local class.

Table types at help.sap.com

http://help.sap.com/saphelp_nw70/helpdata/en/90/8d7304b1af11d194f600a0c929b3c3/frameset.htm

Once defined in SE11, you define a internal table like this:


DATA lt_itab TYPE z_my_tabletype.

Give it a try.

Re: Problem with local class, static private attribute and public method

Former Member — Thu, 31 May 2007 12:48:45 GMT

I already tried this before posting the thread.

If I try to create a dictionary table type, of a line type of the class I defined in my abap report, it will not activate on grounds of not finding the local class.

This is the exact error message when attempting to activate the dictionary type:

Referenced class or interface LCL_AIRPLANE not active/implemented.

I'm most sure that the report is activated, and it makes sense. The dictionary normally cannot find local types either when taken outside of the report context.

Re: Problem with local class, static private attribute and public method

oliver — Thu, 31 May 2007 13:00:36 GMT

Ok, now I got it. I didn't realized that the table should contain references to your local class. Sure ddic doesn't know your local class, so you can't use it there. Sorry for that.

How about using a type pool? Just a guess...

Re: Problem with local class, static private attribute and public method

Former Member — Thu, 31 May 2007 13:43:20 GMT

I fail to see how a type pool can solve this problem.

Bear in mind that I'm simply trying to create a local class with a static table attribute of the class itself. Such a simple OO scenario shouldn't be too hard too implement, should it?

Re: Problem with local class, static private attribute and public method

oliver — Thu, 31 May 2007 13:51:58 GMT

Sure;) But local classes are for me just a poor replacement of global SE24 classes. They work nice in a local context, but you shouldn't expect to much from it. I think they were done mostly because of having local event handler for global classes.

The nice thing is of course that you have the source in full in the editor, but as Horst Keller mentioned in a recent <a href="/people/horst.keller/blog/2007/05/05/source-code-editing-of-global-classes, this will also available for global classes in 7.10. Strike;)

Re: Problem with local class, static private attribute and public method

Former Member — Thu, 31 May 2007 14:16:06 GMT

I agree that global classes are far superior when compared to their local variants. It's just that I bumped into this inconsistency when toying around with local classes, and I have to come to the conclusion that they are woefully flawed. I was just hoping someone could prove otherwise.

Until someone can, I'll consider this as a very serious inconsistency in the ABAP language.

Re: Problem with local class, static private attribute and public method

oliver — Thu, 31 May 2007 14:19:26 GMT

You are absolutely free to do so;) If you want to see some fun stuff, look into the language specs before ABAP OO, like TABLES. That also quite interesting;)

Re: Problem with local class, static private attribute and public method

Former Member — Fri, 01 Jun 2007 07:21:11 GMT

Hello,

Just a suggestion,

I suppose you're using the local class in an report/function group. Did you try to define your table type in the "TOP" include.

First declare the class with "CLASS c1 DEFINITION DEFERRED."

Then your table type.

Finally your class definition.

Regards,

Walter

EDIT: As Uwe said, you can create in your dictionary a table type with reference to OBJECT. Don't forget to cast your object when accessing it.

Message was edited by:

Walter Tighzert

Re: Problem with local class, static private attribute and public method

uwe_schieferstein — Fri, 01 Jun 2007 07:34:45 GMT

Hello Niels

Since your class is local and, thus, only know to the "surrounding" application is does not really make sense to make it public to any other application.

However, if you require to store instances of your local classes in internal tables simply use the most generic reference type possible, i.e. OBJECT.

The following sample report shows how to do that. Furthermore, I believe it also shows that there are no serious inconsistency in the ABAP language.

*&---------------------------------------------------------------------*
*& Report  ZUS_SDN_LOCAL_CLASS
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  zus_sdn_local_class.


" NOTE: SWF_UTL_OBJECT_TAB is a table type having reference type OBJECT


*---------------------------------------------------------------------*
*       CLASS lcl_airplane DEFINITION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_airplane DEFINITION.

  PUBLIC SECTION.
    DATA:    md_counter(3)             TYPE n.

    METHODS: constructor,

             get_instances
               RETURNING
                 value(rt_instances)   TYPE swf_utl_object_tab.

  PRIVATE SECTION.
    CLASS-DATA: mt_instances    TYPE swf_utl_object_tab.




ENDCLASS.                    "lcl_airplane DEFINITION




*---------------------------------------------------------------------*
*       CLASS lcl_airplane IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_airplane IMPLEMENTATION.

  METHOD constructor.
    APPEND me TO mt_instances.

    DESCRIBE TABLE mt_instances.
    md_counter = syst-tfill.
  ENDMETHOD.                    "constructor


  METHOD get_instances.
    rt_instances = mt_instances.
  ENDMETHOD.                    "get_instance

ENDCLASS.                    "lcl_airplane IMPLEMENTATION



DATA:
  gt_instances      TYPE swf_utl_object_tab,
  go_object         TYPE REF TO object,
  go_airplane       TYPE REF TO lcl_airplane.



START-OF-SELECTION.

  " Create a few airplane instance
  DO 5 TIMES.
    CREATE OBJECT go_airplane.
  ENDDO.


  gt_instances = go_airplane->get_instances( ).
  CLEAR: go_airplane.

  LOOP AT gt_instances INTO go_object.
    go_airplane ?= go_object.

    WRITE: / 'Airplane =', go_airplane->md_counter.
  ENDLOOP.



END-OF-SELECTION.

Regards

Uwe

Re: Problem with local class, static private attribute and public method

Former Member — Fri, 01 Jun 2007 07:42:17 GMT

Grmlb,

This would do the trick I suppose. But I still resent the fact that I would have to create my table using a general object instead of the type I immediately want. In any other OO language, this simple scenario would be not be an issue, hence my surprise.

Problem solved.

Thank you.

Re: Problem with local class, static private attribute and public method

Former Member — Fri, 01 Jun 2007 07:53:53 GMT

Hi Niels,

Try using the following.

CLASS cl_a DEFINITION DEFERRED.

class cl_a definition.

private section.

class-data: gv_var type table of ref to cl_a.

endclass.

Award points if found useful.

Regards

Indrajit

Re: Problem with local class, static private attribute and public method

uwe_schieferstein — Fri, 01 Jun 2007 08:47:41 GMT

Hello Niels

Although I used a table type defined in the DDIC this is, of course, not mandatory.

Have a look at this version of the sample report.

You mask as why I use the option ...WITH DEFAULT KEY for the type definition? Well, simply inactive this option and see what the syntax check tells you.

*&---------------------------------------------------------------------*
*& Report  ZUS_SDN_LOCAL_CLASS_1
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  zus_sdn_local_class_1.


" NOTE: SWF_UTL_OBJECT_TAB is a table type having reference type OBJECT


TYPES: ty_t_object  TYPE TABLE OF REF TO object
                    WITH DEFAULT KEY.  " this option is mandatory!!!

*---------------------------------------------------------------------*
*       CLASS lcl_airplane DEFINITION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_airplane DEFINITION.

  PUBLIC SECTION.
    DATA:    md_counter(3)             TYPE n.

    METHODS: constructor,

             get_instances
               RETURNING
                 value(rt_instances)   TYPE ty_t_object.

  PRIVATE SECTION.
    CLASS-DATA: mt_instances    TYPE ty_t_object.




ENDCLASS.                    "lcl_airplane DEFINITION




*---------------------------------------------------------------------*
*       CLASS lcl_airplane IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_airplane IMPLEMENTATION.

  METHOD constructor.
    APPEND me TO mt_instances.

    DESCRIBE TABLE mt_instances.
    md_counter = syst-tfill.
  ENDMETHOD.                    "constructor


  METHOD get_instances.
    rt_instances = mt_instances.
  ENDMETHOD.                    "get_instance

ENDCLASS.                    "lcl_airplane IMPLEMENTATION



DATA:
  gt_instances      TYPE ty_t_object,
  go_object         TYPE REF TO object,
  go_airplane       TYPE REF TO lcl_airplane.



START-OF-SELECTION.

  " Create a few airplane instance
  DO 5 TIMES.
    CREATE OBJECT go_airplane.
  ENDDO.


  gt_instances = go_airplane->get_instances( ).
  CLEAR: go_airplane.

  LOOP AT gt_instances INTO go_object.
    go_airplane ?= go_object.

    WRITE: / 'Airplane =', go_airplane->md_counter.
  ENDLOOP.



END-OF-SELECTION.

Regards

Uwe