characterstic value

Former Member — Tue, 20 Feb 2007 09:47:29 GMT

Hi,

I would like to ask regarding characterstic value.

Actually I have internal characterstic(CABN-ATINN). Now I am getting the characterstic value (AUSP-ATWRT).

Now I wanted to get the characterstic value description.

Could anybody will suggest me the database table name for it?

Re: characterstic value

Former Member — Tue, 20 Feb 2007 09:49:33 GMT

check table

CABNT

Regards

Prabhu

Re: characterstic value

Former Member — Tue, 20 Feb 2007 09:49:48 GMT

Hello,

FORM F_GET_MAT_KLASS.


  DATA: BEGIN OF L_T_OBJECT OCCURS 0,
         OBJEK TYPE OBJNUM,
         MATNR TYPE MATNR,
        END OF L_T_OBJECT.
  DATA: L_OBJECTS TYPE TY_OBJECTS.
  CLEAR: L_T_OBJECT.
  REFRESH: L_T_OBJECT.
* Fill the object number
  LOOP AT G_T_MAT INTO G_R_MAT.
    AT NEW MATNR.
      L_T_OBJECT-OBJEK = G_R_MAT-MATNR.
      L_T_OBJECT-MATNR = G_R_MAT-MATNR.
      APPEND L_T_OBJECT.
    ENDAT.
  ENDLOOP.
  CLEAR:G_T_OBJECTS,G_T_CLASSDESC,G_T_CHARDESC,G_T_CABN,G_T_KSML,
        G_T_CAWNT.
  REFRESH: G_T_OBJECTS,G_T_CLASSDESC,G_T_CHARDESC,G_T_CABN,G_T_KSML,
           G_T_CAWNT.
* Get the material classification details
  SELECT A~CUOBJ A~OBJEK A~KLART B~ATINN B~ATZHL B~ATWRT B~ATFLV
         B~ATAWE B~ATFLB B~ATAW1 C~CLINT D~CLASS
    INTO CORRESPONDING FIELDS OF TABLE G_T_OBJECTS
    FROM INOB AS A INNER JOIN AUSP AS B
      ON A~CUOBJ = B~OBJEK AND
         A~KLART = B~KLART
         INNER JOIN KSSK AS C
         ON B~OBJEK = C~OBJEK AND
            B~KLART = C~KLART
         INNER JOIN KLAH AS D
         ON C~CLINT = D~CLINT
     FOR ALL ENTRIES IN L_T_OBJECT
   WHERE A~OBJEK EQ L_T_OBJECT-OBJEK AND
         A~OBTAB EQ 'MARA'  AND
         A~KLART IN S_KLART AND
         B~ADZHL EQ '0000'  AND
         C~LKENZ EQ ' '     AND
         D~CLASS IN S_CLASS.

  IF NOT G_T_OBJECTS[] IS INITIAL.
    SELECT CLINT IMERK KLART
      FROM KSML
      INTO CORRESPONDING FIELDS OF TABLE G_T_KSML
       FOR ALL ENTRIES IN G_T_OBJECTS
     WHERE CLINT EQ G_T_OBJECTS-CLINT.
  ENDIF.
  IF NOT G_T_KSML[] IS INITIAL.
    SORT G_T_KSML BY CLINT.
    SORT G_T_OBJECTS BY ATINN KLART.
    LOOP AT G_T_KSML.

      READ TABLE G_T_OBJECTS WITH KEY ATINN = G_T_KSML-IMERK.

      IF SY-SUBRC NE 0.
        CLEAR: L_OBJECTS.
        READ TABLE G_T_OBJECTS WITH KEY KLART = G_T_KSML-KLART.
        IF SY-SUBRC = 0.
          MOVE-CORRESPONDING G_T_OBJECTS TO L_OBJECTS.
          CLEAR G_T_OBJECTS.
          G_T_OBJECTS-ATINN = G_T_KSML-IMERK.
          G_T_OBJECTS-KLART = G_T_KSML-KLART.
          G_T_OBJECTS-CLINT = G_T_KSML-CLINT.
          G_T_OBJECTS-CUOBJ = L_OBJECTS-CUOBJ.
          G_T_OBJECTS-OBJEK = L_OBJECTS-OBJEK.
          G_T_OBJECTS-CLASS = L_OBJECTS-CLASS.
          APPEND G_T_OBJECTS.
          CLEAR G_T_OBJECTS.
        ENDIF.
      ENDIF.
    ENDLOOP.
  ENDIF.

  IF NOT G_T_OBJECTS[] IS INITIAL.

    SELECT CLINT KSCHL
      FROM SWOR
      INTO CORRESPONDING FIELDS OF TABLE G_T_CLASSDESC
       FOR ALL ENTRIES IN G_T_OBJECTS
     WHERE CLINT EQ G_T_OBJECTS-CLINT AND
           KLPOS EQ '01'              AND
           SPRAS EQ SY-LANGU.

    IF NOT G_T_CLASSDESC[] IS INITIAL.
      SORT G_T_CLASSDESC BY CLINT.
    ENDIF.

    SELECT ATINN ATBEZ
      FROM CABNT
      INTO CORRESPONDING FIELDS OF TABLE G_T_CHARDESC
       FOR ALL ENTRIES IN G_T_OBJECTS
     WHERE ATINN EQ G_T_OBJECTS-ATINN AND
           SPRAS EQ SY-LANGU.

    IF NOT G_T_CHARDESC[] IS INITIAL.
      SORT G_T_CHARDESC BY ATINN.
    ENDIF.

    SELECT ATINN MSEHI
    FROM CABN
    INTO CORRESPONDING FIELDS OF TABLE G_T_CABN
     FOR ALL ENTRIES IN G_T_OBJECTS
   WHERE ATINN EQ G_T_OBJECTS-ATINN.

    SELECT ATINN ATWTB
      FROM CAWNT
      INTO CORRESPONDING FIELDS OF TABLE G_T_CAWNT
       FOR ALL ENTRIES IN G_T_OBJECTS
     WHERE ATINN EQ G_T_OBJECTS-ATINN AND
           ADZHL EQ '0000'            AND
           SPRAS EQ SY-LANGU.

  ENDIF.

ENDFORM.                    " f_get_mat_klass

Vasanth

topic characterstic value in Application Development and Automation Discussions

characterstic value

Re: characterstic value

Re: characterstic value