topic Re: help with selection screen in Application Development and Automation Discussions

help with selection screen

Former Member — Mon, 29 Jan 2007 18:09:52 GMT

Hi all,

i have a selection screen in which i have to select one of the 3 things using radio button.

based on each selection i.e radio button , i want to see a different selection screen.

let me know as how to proceed with this.

deepthi

Re: help with selection screen

RichHeilman — Mon, 29 Jan 2007 18:17:39 GMT

You can try something like this.



report zrich_0001.


selection-screen begin of block b1 with frame.
parameters: p_g1 radiobutton group gp1 default 'X' user-command chk,
            p_g2 radiobutton group gp1.
selection-screen end of block b1.

selection-screen begin of block b2 with frame.
parameters: p_gltrp type afko-gltrp modif id g1.
parameters: p_werks type aufk-werks modif id g1.
parameters: p_datum type afko-gltrp modif id g2.
parameters: p_uzeit type aufk-werks modif id g2.
selection-screen end of block b2.

at selection-screen output.

  loop at screen.
    if p_g1 = 'X' and screen-group1 = 'G2'.
      screen-active = 0.
      modify screen.
    endif.
    if p_g2 = 'X' and screen-group1 = 'G1'.
      screen-active = 0.
      modify screen.
    endif.
  endloop.

Regards,

Rich Heilman

Re: help with selection screen

Former Member — Mon, 29 Jan 2007 18:19:51 GMT

hi deepthi,

try doing this...

at selection-screen output.

Loop at screen.

IF p_rad1 = 'X'.(first radiobutton is selected)

IF screen-group1 = 'GR2'

screen-active = '0'.

screen-invisible = '1'.

ELSE.

screen-active = '1'.

screen-invisible = '0'.

ENDIF.

MODIFY SCREEN.

ELSE.

IF screen-group1 = 'GR1'. (second is selected)

screen-active = '0'.

screen-invisible = '1'.

ELSE.

screen-active = '1'.

screen-invisible = '0'.

ENDIF.

MODIFY SCREEN.

ENDIF.

ENDLOOP.

hope this helps,

do reward if it helps,

priya.

Re: help with selection screen

SantoshKallem — Mon, 29 Jan 2007 18:20:09 GMT

with the help of SCREEN table u can hide the block of selection-screen.

based on radio button u may see the area of screen.

regards.

santhosh

Message was edited by:

santhosh reddy

Re: help with selection screen

Former Member — Mon, 29 Jan 2007 18:33:07 GMT

hI ,

tHANKS FOR THE REPLY.

I UNDERSTOOD WHAT YOU ARE TALKING ABOUT.

THE SELECTION SCREEN AT THE BOTTOM CHANGES BASED ON THE RADIO BUTTON SELECTION.

INITIALLY I AM ABLE TO SEE THE THE SELECTION FOR THE RADIO BUTTON WHICH IS CHECKED BY DEFAULT.

IS THAT HOW IT WORKS

THANKS

Re: help with selection screen

RichHeilman — Mon, 29 Jan 2007 18:35:33 GMT

Yep.

Regards,

Rich Heilman

Re: help with selection screen

Former Member — Mon, 29 Jan 2007 18:42:00 GMT

You could set it so that the default radio button hides all of the fields (except the radio buttons) and when one of the other ones is selected, only the fields you want to display are shown.

Rob

Re: help with selection screen

Former Member — Mon, 29 Jan 2007 18:45:47 GMT

Hi ,

i awarded points to all

thanks