topic Re: BAPI_INSPECTIONPLAN_CREATE error in Application Development and Automation Discussions

BAPI_INSPECTIONPLAN_CREATE error

Former Member — Tue, 16 Oct 2018 08:10:01 GMT

I have got error while creation inspection plan

"A M3351 Material 100001 not maintained in plant 1000".

i am passing these values to fm.

t_materialtaskallocation-MATERIAL = IT_insplan-MATERIAL."'RWA910'. t_materialtaskallocation-PLANT = IT_insplan-PLANT."'1000'.

t_materialtaskallocation-valid_from = sy-datum.

APPEND t_materialtaskallocation.

t_task-valid_from = sy-datum.

t_task-TASK_LIST_GROUP = ' '. " IT_INSPLAN-TASK_LIST_GROUP

t_task-GROUP_COUNTER = '1'. "IT_insplan-GROUP_COUNTER.

t_task-TASK_LIST_USAGE = IT_insplan-TASK_LIST_USAGE."'5'.

t_task-PLANT = IT_insplan-PLANT."'1000'.

t_task-TASK_LIST_STATUS = IT_insplan-TASK_LIST_STATUS."'4'.

t_task-TASK_MEASURE_UNIT = IT_insplan-TASK_MEASURE_UNIT."'EA'.

t_task-LOT_SIZE_FROM = IT_insplan-LOT_SIZE_FROM."'0'.

t_task-LOT_SIZE_TO = IT_insplan-LOT_SIZE_TO. "'99999'.

t_task-DESCRIPTION = IT_insplan-DESCRIPTION."'TEST'.

APPEND t_task.

t_operation-valid_from = sy-datum.

t_operation-ACTIVITY = IT_insplan-ACTIVITY." '0010'

t_operation-OPERATION_ID = '0010'.

t_operation-CONTROL_KEY = IT_insplan-CONTROL_KEY."'QM01'.

t_operation-PLANT = IT_insplan-PLANT."'1000'.

t_operation-DESCRIPTION = IT_insplan-DESCRIPTION."'TEST'.

t_operation-OPERATION_MEASURE_UNIT = IT_insplan-OPERATION_MEASURE_UNIT."'EA'.

t_operation-DENOMINATOR = IT_insplan-DENOMINATOR."'1'.

t_operation-NOMINATOR = IT_insplan-NOMINATOR."'1'.

t_operation-BASE_QUANTITY = IT_insplan-BASE_QUANTITY."'1.0'.

APPEND t_operation.

t_inspcharacteristic-valid_from = sy-datum.

t_inspcharacteristic-ACTIVITY = IT_insplan-INS_ACTIVITY."'0010'.

t_inspcharacteristic-INSPCHAR = IT_insplan-INSPCHAR."'01'.

t_inspcharacteristic-PRESET_CTRL_INDS_KEY = IT_insplan-PRESET_CTRL_INDS_KEY."'1000'.

t_inspcharacteristic-MSTR_CHAR = IT_insplan-MSTR_CHAR."'8-105'. t_inspcharacteristic-PMSTR_CHAR = IT_insplan-PMSTR_CHAR. " '1000'. t_inspcharacteristic-CHA_MASTER_IMPORT_MODUS = IT_insplan-CHA_MASTER_IMPORT_MODUS."'N'.

t_inspcharacteristic-CHAR_DESCR = IT_insplan-CHAR_DESCR."'TESTY'. t_inspcharacteristic-SMPL_PROCEDURE = IT_insplan-SMPL_PROCEDURE."'FIX1-0'. t_inspcharacteristic-SMPL_UNIT = IT_insplan-SMPL_UNIT."'EA'.

t_inspcharacteristic-SMPL_QUANT = IT_insplan-SMPL_QUANT."'4.23'.

APPEND t_inspcharacteristic.

Re: BAPI_INSPECTIONPLAN_CREATE error

matt — Tue, 16 Oct 2018 08:11:05 GMT

When posting code, please use the code button in the editor. If pasting code, use right-click paste as text.

Re: BAPI_INSPECTIONPLAN_CREATE error

sudarshan_d29 — Tue, 13 Nov 2018 14:04:31 GMT

Hi siva prasad,

Refer functional people seems the error related to them "A M3351 Material 100001 not maintained in plant 1000".

If you are creating manually using t-code, you will get the same error that can be solved by them.

Sudarshan David

Re: BAPI_INSPECTIONPLAN_CREATE error

Former Member — Tue, 04 Dec 2018 13:25:51 GMT

Hi sudarshan rajamdavid,                                                    
Refer functional people he said to add below one in bapi after adding it is uploading fine.

T_OPERATION-INSP_POINT_COMPLT_FLOW_VARIANT = '2'.
check sample code in belo for uploading  multi operation and multi inspection for a material.
 if material contain group then it will increase counter for the same group 

else it will create groub and counter for the material 


*******************************************

* DECLARATIONS

*******************************************

TYPE-POOLS : SLIS.

DATA:

 T_TASK TYPE TABLE OF BAPI1191_TSK_C WITH HEADER LINE,

 T_MATERIALTASKALLOCATION TYPE TABLE OF BAPI1191_MTK_C WITH HEADER LINE,

 T_INSPCHARACTERISTIC TYPE TABLE OF BAPI1191_CHA_C WITH HEADER LINE,

 T_OPERATION TYPE TABLE OF BAPI1191_OPR_C WITH HEADER LINE,

 T_RETURN TYPE TABLE OF BAPIRET2 WITH HEADER LINE,

 t_REFERENCEOPERATION TYPE TABLE OF BAPI1191_REF_OPR_C WITH HEADER LINE,



 BEGIN OF IT_LOGHEAD OCCURS 0,

 MATERIAL LIKE BAPI1191_MTK_C-MATERIAL,

 PLANT LIKE BAPI1191_TSK_C-PLANT,

 MSGTYPE LIKE BAPIRET2-TYPE,

 MSG_TXT(100) TYPE C,

 MSG(100) TYPE C,

 EXPAND TYPE C,

 END OF IT_LOGHEAD .



* Structure to Load Data from the Text File

TYPES : BEGIN OF TY_INSPLAN,

 MATERIAL LIKE T_MATERIALTASKALLOCATION-MATERIAL,



 PLANT LIKE T_TASK-PLANT,

 DESCRIPTION LIKE T_TASK-DESCRIPTION,

 TASK_LIST_USAGE LIKE T_TASK-TASK_LIST_USAGE,

 TASK_LIST_STATUS LIKE T_TASK-TASK_LIST_STATUS,

 TASK_MEASURE_UNIT LIKE T_TASK-TASK_MEASURE_UNIT,

 IDENT_KEY LIKE T_TASK-IDENT_KEY ,

 SAMPLE_DRAWING_PROCEDURE like T_TASK-SAMPLE_DRAWING_PROCEDURE,



 ACTIVITY LIKE T_OPERATION-ACTIVITY,

 CONTROL_KEY LIKE T_OPERATION-CONTROL_KEY,

 OP_DESCRIPTION LIKE T_OPERATION-DESCRIPTION,

 OPERATION_MEASURE_UNIT LIKE T_OPERATION-OPERATION_MEASURE_UNIT,

 BASE_QUANTITY LIKE T_OPERATION-BASE_QUANTITY,





 INS_ACTIVITY LIKE T_INSPCHARACTERISTIC-ACTIVITY,

 INSPCHAR LIKE T_INSPCHARACTERISTIC-INSPCHAR,

 MSTR_CHAR LIKE T_INSPCHARACTERISTIC-MSTR_CHAR,

 CHAR_DESCR LIKE T_INSPCHARACTERISTIC-CHAR_DESCR,

 SMPL_PROCEDURE LIKE T_INSPCHARACTERISTIC-SMPL_PROCEDURE,

 SMPL_UNIT LIKE T_INSPCHARACTERISTIC-SMPL_UNIT,

 SMPL_QUANT LIKE T_INSPCHARACTERISTIC-SMPL_QUANT,

 TASK_LIST_GROUP LIKE T_INSPCHARACTERISTIC-TASK_LIST_GROUP,

 END OF TY_INSPLAN.





DATA : GV_BEGINCOL TYPE I VALUE '1',

 GV_BEGINROW TYPE I VALUE '2',

 GV_ENDCOL TYPE I VALUE '16384',

 GV_ENDROW TYPE I VALUE '1048576',

 IT_ALSMEX_TABLINE TYPE TABLE OF ALSMEX_TABLINE, " excel internal table

 WA_ALSMEX_TABLINE TYPE ALSMEX_TABLINE,

 GV_NO TYPE I,

 GV_EXTENSION TYPE STRING,

 GV_FILENAME TYPE STRING,

 GV_FILEPATH TYPE CHAR100,



 IT_INSPLAN TYPE TABLE OF TY_INSPLAN WITH HEADER LINE,



 V_GROUP TYPE BAPI1191_TSK_C-TASK_LIST_GROUP,

 V_GRPCOUNTER TYPE BAPI1191_TSK_C-GROUP_COUNTER,

 V_FILE TYPE LOCALFILE,

 V_ROW TYPE N,

 V_PLANT LIKE T_TASK-PLANT,

 V_LINES TYPE I,

 V_PER TYPE P,

 V_TXT(50) TYPE C.



"**** selection screen design

SELECTION-SCREEN BEGIN OF BLOCK BLOCK1 WITH FRAME TITLE TEXT-001.

PARAMETERS P_FILE TYPE RLGRAP-FILENAME OBLIGATORY.

SELECTION-SCREEN END OF BLOCK BLOCK1.



AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_FILE.

 CALL FUNCTION 'KD_GET_FILENAME_ON_F4'

 CHANGING

 FILE_NAME = P_FILE

 EXCEPTIONS

 MASK_TOO_LONG = 1.

 IF SY-SUBRC = 1.

 MESSAGE 'The length of input file path must not be greater than 100 (OR) Path selection failed' TYPE 'E'.

 ELSEIF SY-SUBRC = 2.

 MESSAGE ' Path selection failed' TYPE 'E'.

 ENDIF.



START-OF-SELECTION.

 PERFORM DATA_UPLOAD.

 PERFORM GROUP_CREATING. " FILLING ALL BAPI EXPORT INTERNAL TABLE.

* PERFORM FILL_BAPI_ITABS .

END-OF-SELECTION.

 PERFORM DISPLAY_RESULT.





* *----------------------------------------------------------------------*

***INCLUDE ZQM_QP01_RECORDING_DATA_UPLF01.

*----------------------------------------------------------------------*

*&---------------------------------------------------------------------*

*& Form DATA_UPLOAD

*&---------------------------------------------------------------------*

* text

*----------------------------------------------------------------------*

* --> p1 text

* <-- p2 text

*----------------------------------------------------------------------*

FORM DATA_UPLOAD .

*** calling function module to read from excel file to internal table

 CALL FUNCTION 'ALSM_EXCEL_TO_INTERNAL_TABLE'

 EXPORTING

 FILENAME = P_FILE

 I_BEGIN_COL = GV_BEGINCOL

 I_BEGIN_ROW = GV_BEGINROW

 I_END_COL = GV_ENDCOL

 I_END_ROW = GV_ENDROW

 TABLES

 INTERN = IT_ALSMEX_TABLINE

 EXCEPTIONS

 INCONSISTENT_PARAMETERS = 1

 UPLOAD_OLE = 2

 OTHERS = 3.



 IF SY-SUBRC = 1.

 MESSAGE 'Inconsistent_parameters' TYPE 'E'.

 ELSEIF SY-SUBRC = 2.

 MESSAGE ' upload_ole ' TYPE 'E'.

 ENDIF.



*** reading from internal table and moving data to multiple internal tables

 LOOP AT IT_ALSMEX_TABLINE INTO WA_ALSMEX_TABLINE.



 CASE WA_ALSMEX_TABLINE-COL.

 WHEN '0001'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-MATERIAL.

 CALL FUNCTION 'CONVERSION_EXIT_MATN1_INPUT'

 EXPORTING

 INPUT = IT_INSPLAN-MATERIAL

 IMPORTING

 OUTPUT = IT_INSPLAN-MATERIAL

 EXCEPTIONS

 LENGTH_ERROR = 1

 OTHERS = 2.

 WHEN '0002'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-PLANT.

 WHEN '0003'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-DESCRIPTION.

 WHEN '0004'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-TASK_LIST_USAGE.

 WHEN '0005'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-TASK_LIST_STATUS.

 WHEN '0006'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-TASK_MEASURE_UNIT.

 WHEN '0007'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-IDENT_KEY.

 WHEN '0008'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-SAMPLE_DRAWING_PROCEDURE.

 WHEN '0009'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-ACTIVITY.

 WHEN '0010'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-CONTROL_KEY.

 WHEN '0011'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-OP_DESCRIPTION.

 WHEN '0012'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-OPERATION_MEASURE_UNIT.

 WHEN '0013'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-BASE_QUANTITY.

 WHEN '0014'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-INS_ACTIVITY.

 WHEN '0015'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-INSPCHAR.

 WHEN '0016'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-MSTR_CHAR.

 WHEN '0017'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-CHAR_DESCR.

 WHEN '0018'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-SMPL_PROCEDURE.

 WHEN '0019'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-SMPL_UNIT.

 WHEN '0020'.

 MOVE WA_ALSMEX_TABLINE-VALUE TO IT_INSPLAN-SMPL_QUANT.

 WHEN '0021'.



 if WA_ALSMEX_TABLINE-VALUE = 'X'.

 select SINGLE PLNNR from MAPL into IT_INSPLAN-TASK_LIST_GROUP

 where MATNR = IT_INSPLAN-MATERIAL

 and WERKS = IT_INSPLAN-PLANT

 and PLNTY = 'Q'

 and DATUV = sy-datum.

 endif.

 AT END OF ROW.

 APPEND IT_INSPLAN.

 CLEAR IT_INSPLAN.

 ENDAT.

 ENDCASE.

 ENDLOOP.

 IT_INSPLAN-MATERIAL = '0'.

 APPEND IT_INSPLAN.



ENDFORM.


*&---------------------------------------------------------------------*

*& Form CALL_BAPI_AND_COMMIT

*&---------------------------------------------------------------------*

* Subroutine to Load the inspection plans

*----------------------------------------------------------------------*

FORM CALL_BAPI_AND_COMMIT .

 REFRESH T_RETURN.

 CALL FUNCTION 'BAPI_INSPECTIONPLAN_CREATE'

* EXPORTING

* TESTRUN = c

* PROFILE =

 IMPORTING

 GROUP = V_GROUP

 GROUPCOUNTER = V_GRPCOUNTER

 TABLES

 TASK = T_TASK

 MATERIALTASKALLOCATION = T_MATERIALTASKALLOCATION

 OPERATION = T_OPERATION

 REFERENCEOPERATION = t_REFERENCEOPERATION

 INSPCHARACTERISTIC = T_INSPCHARACTERISTIC

 RETURN = T_RETURN.



 READ TABLE T_RETURN INDEX 1.

 DESCRIBE TABLE T_RETURN.



 CALL FUNCTION 'CONVERSION_EXIT_MATN1_OUTPUT'

 EXPORTING

 INPUT = T_MATERIALTASKALLOCATION-MATERIAL

 IMPORTING

 OUTPUT = T_MATERIALTASKALLOCATION-MATERIAL.





* Check for success message and then Commit, otherwise dont commit

 IF T_RETURN-TYPE EQ 'S' AND SY-TFILL EQ 1.

 CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'

 EXPORTING

 WAIT = 'X'.



* Populate Success message in internal table for ALV Log display

 IT_LOGHEAD-PLANT = V_PLANT.

 IT_LOGHEAD-MATERIAL = T_MATERIALTASKALLOCATION-MATERIAL.

 IT_LOGHEAD-MSGTYPE = 'S'.

 IT_LOGHEAD-MSG_TXT = 'Inspection Plan Created Successfully'.

 CONCATENATE IT_LOGHEAD-MSG_TXT V_GRPCOUNTER V_GROUP INTO IT_LOGHEAD-MSG_TXT SEPARATED BY SPACE.

 IT_LOGHEAD-MSG = T_RETURN-MESSAGE.



 APPEND IT_LOGHEAD.

 ELSE.



 CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK' .



* Retrieve and populate Error Details for Log Display

 CLEAR T_RETURN.

 LOOP AT T_RETURN.

 IT_LOGHEAD-PLANT = V_PLANT.

 IT_LOGHEAD-MATERIAL = T_MATERIALTASKALLOCATION-MATERIAL.

 IT_LOGHEAD-MSGTYPE = T_RETURN-TYPE.

 IT_LOGHEAD-MSG_TXT = 'Inspection Plan Not Created'.

 CONCATENATE IT_LOGHEAD-MSG_TXT V_GRPCOUNTER V_GROUP INTO IT_LOGHEAD-MSG_TXT SEPARATED BY SPACE.

 IT_LOGHEAD-MSG = T_RETURN-MESSAGE.



 IF T_RETURN-PARAMETER IS NOT INITIAL.

 CONCATENATE IT_LOGHEAD-MSG '- Error in parameter'

 T_RETURN-PARAMETER INTO IT_LOGHEAD-MSG SEPARATED BY SPACE.

 IF T_RETURN-ROW IS NOT INITIAL.

 V_ROW = T_RETURN-ROW.

 CONCATENATE IT_LOGHEAD-MSG '- In Row' V_ROW

 INTO IT_LOGHEAD-MSG SEPARATED BY SPACE.

 ENDIF.

 ENDIF.



 APPEND IT_LOGHEAD.

 ENDLOOP.

 REFRESH T_RETURN.



 ENDIF.

ENDFORM. " CALL_BAPI_AND_COMMIT

*&---------------------------------------------------------------------*

*& Form CLEAR_INTERNAL_TABLES

*&---------------------------------------------------------------------*

* Subroutine to Clear Internal Tables

*----------------------------------------------------------------------*

FORM CLEAR_INTERNAL_TABLES .

 CLEAR T_MATERIALTASKALLOCATION[].

 CLEAR T_TASK[].

* CLEAR T_OPERATION[].

 CLEAR T_INSPCHARACTERISTIC[].

 CLEAR T_RETURN[].

ENDFORM. " CLEAR_INTERNAL_TABLES

*&---------------------------------------------------------------------*

*& Form DISPLAY_RESULT

*&---------------------------------------------------------------------*

* text

*----------------------------------------------------------------------*

* --> p1 text

* <-- p2 text

*----------------------------------------------------------------------*

FORM DISPLAY_RESULT .



 DATA: IT_FIELDCAT TYPE SLIS_T_FIELDCAT_ALV,

 WA_FIELDCAT TYPE LINE OF SLIS_T_FIELDCAT_ALV,

 WA_LAYOUT TYPE SLIS_LAYOUT_ALV,

 IT_KEYINFO TYPE TABLE OF SLIS_KEYINFO_ALV WITH HEADER LINE.



 WA_FIELDCAT-COL_POS = 1.

 WA_FIELDCAT-FIELDNAME = 'MATERIAL'.

 WA_FIELDCAT-SELTEXT_M = 'Material'.

 APPEND WA_FIELDCAT TO IT_FIELDCAT.

 CLEAR WA_FIELDCAT.



 WA_FIELDCAT-COL_POS = 2.

 WA_FIELDCAT-FIELDNAME = 'PLANT'.

 WA_FIELDCAT-SELTEXT_M = 'Plant'.

 APPEND WA_FIELDCAT TO IT_FIELDCAT.

 CLEAR WA_FIELDCAT.



 WA_FIELDCAT-COL_POS = 3.

 WA_FIELDCAT-FIELDNAME = 'MSGTYPE'.

 WA_FIELDCAT-SELTEXT_M = 'Msg.type'.

 APPEND WA_FIELDCAT TO IT_FIELDCAT.

 CLEAR WA_FIELDCAT.



 WA_FIELDCAT-COL_POS = 4.

 WA_FIELDCAT-FIELDNAME = 'MSG_TXT'.

 WA_FIELDCAT-SELTEXT_M = 'Msg.text'.

 APPEND WA_FIELDCAT TO IT_FIELDCAT.

 CLEAR WA_FIELDCAT.

 WA_FIELDCAT-COL_POS = 5.

 WA_FIELDCAT-FIELDNAME = 'MSG'.

 WA_FIELDCAT-SELTEXT_M = 'Error reason'.

 APPEND WA_FIELDCAT TO IT_FIELDCAT.

 CLEAR WA_FIELDCAT.





*- desining layout

 WA_LAYOUT-COLWIDTH_OPTIMIZE = 'X'.

 WA_LAYOUT-ZEBRA = 'X'.



 CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'

 EXPORTING

 IS_LAYOUT = WA_LAYOUT

 IT_FIELDCAT = IT_FIELDCAT

 TABLES

 T_OUTTAB = IT_LOGHEAD.



ENDFORM.

*&---------------------------------------------------------------------*

*& Form UNIT_CONVERT

*&---------------------------------------------------------------------*

* text

*----------------------------------------------------------------------*

* -->P_IT_INSPLAN_OPERATION_MEASURE_U text

*----------------------------------------------------------------------*

FORM UNIT_CONVERT USING P_MEASURE_UNIT.

 CALL FUNCTION 'CONVERSION_EXIT_CUNIT_INPUT'

 EXPORTING

 INPUT = P_MEASURE_UNIT

 LANGUAGE = SY-LANGU

 IMPORTING

 OUTPUT = P_MEASURE_UNIT.

ENDFORM.





form group_creating.

 loop at IT_INSPLAN.



 IF IT_INSPLAN-MATERIAL IS NOT INITIAL.

 IF T_TASK IS NOT INITIAL .

 PERFORM CALL_BAPI_AND_COMMIT.

 PERFORM CLEAR_INTERNAL_TABLES.

 ENDIF.

 IF IT_INSPLAN-PLANT IS NOT INITIAL.

 V_PLANT = IT_INSPLAN-PLANT.

 ENDIF.



 CLEAR T_MATERIALTASKALLOCATION[].

 CLEAR T_TASK[].

 CLEAR T_OPERATION[].

 CLEAR T_INSPCHARACTERISTIC[].

 if IT_INSPLAN-TASK_LIST_GROUP is INITIAL.

 select SINGLE PLNNR from MAPL into IT_INSPLAN-TASK_LIST_GROUP

 where MATNR = IT_INSPLAN-MATERIAL

 and WERKS = IT_INSPLAN-PLANT

 and PLNTY = 'Q'.

* and DATUV = sy-datum.

 endif.

 T_MATERIALTASKALLOCATION-MATERIAL = IT_INSPLAN-MATERIAL."'RWA910'.

 T_MATERIALTASKALLOCATION-PLANT = V_PLANT. "'1000'.

 T_MATERIALTASKALLOCATION-TASK_LIST_GROUP = IT_INSPLAN-TASK_LIST_GROUP.

 T_MATERIALTASKALLOCATION-VALID_FROM = SY-DATUM.

 APPEND T_MATERIALTASKALLOCATION.

*************************************

 T_TASK-VALID_FROM = SY-DATUM.

 T_TASK-TASK_LIST_GROUP = IT_INSPLAN-TASK_LIST_GROUP.

 T_TASK-DESCRIPTION = IT_INSPLAN-DESCRIPTION. "'TEST'.

 T_TASK-TASK_LIST_USAGE = IT_INSPLAN-TASK_LIST_USAGE. "'5'.

 T_TASK-TASK_LIST_STATUS = IT_INSPLAN-TASK_LIST_STATUS. "'4'.

 PERFORM UNIT_CONVERT USING IT_INSPLAN-TASK_MEASURE_UNIT.

 T_TASK-TASK_MEASURE_UNIT = IT_INSPLAN-TASK_MEASURE_UNIT. "'EA'.

 T_TASK-IDENT_KEY = IT_INSPLAN-IDENT_KEY. "100

 T_TASK-SAMPLE_DRAWING_PROCEDURE = IT_INSPLAN-SAMPLE_DRAWING_PROCEDURE.

 T_TASK-PLANT = V_PLANT.

 APPEND T_TASK.

 ENDIF.

*****************************

 IF IT_INSPLAN-ACTIVITY IS NOT INITIAL.

 CLEAR T_OPERATION-TASK_LIST_GROUP.

 T_OPERATION-VALID_FROM = SY-DATUM..

 T_OPERATION-TASK_LIST_GROUP = IT_INSPLAN-TASK_LIST_GROUP.

 T_OPERATION-ACTIVITY = IT_INSPLAN-ACTIVITY. " 0010.

 T_OPERATION-CONTROL_KEY = IT_INSPLAN-CONTROL_KEY. "'QM01'.

 T_OPERATION-DESCRIPTION = IT_INSPLAN-OP_DESCRIPTION. "'TEST'.

 PERFORM UNIT_CONVERT USING IT_INSPLAN-OPERATION_MEASURE_UNIT.

 T_OPERATION-OPERATION_MEASURE_UNIT = IT_INSPLAN-OPERATION_MEASURE_UNIT. "'EA'.

 T_OPERATION-DENOMINATOR = '1'. "IT_INSPLAN-DENOMINATOR.

 T_OPERATION-NOMINATOR = '1'.

 T_OPERATION-BASE_QUANTITY = IT_INSPLAN-BASE_QUANTITY. "'1.0'.

 T_OPERATION-PLANT = V_PLANT. "'1000'.

 T_OPERATION-INSP_POINT_COMPLT_FLOW_VARIANT = '2'.

 APPEND T_OPERATION.

 ENDIF.

*******************

 T_INSPCHARACTERISTIC-TASK_LIST_GROUP = IT_INSPLAN-TASK_LIST_GROUP.

 T_INSPCHARACTERISTIC-ACTIVITY = IT_INSPLAN-ins_ACTIVITY.

 T_INSPCHARACTERISTIC-INSPCHAR = IT_INSPLAN-INSPCHAR.

 T_INSPCHARACTERISTIC-PMSTR_CHAR = V_PLANT.

 T_INSPCHARACTERISTIC-CHA_MASTER_IMPORT_MODUS = 'C'.

 T_INSPCHARACTERISTIC-VALID_FROM = SY-DATUM.



 T_INSPCHARACTERISTIC-CHAR_DESCR = IT_INSPLAN-CHAR_DESCR.

 T_INSPCHARACTERISTIC-MSTR_CHAR = IT_INSPLAN-MSTR_CHAR. "'TEST1' . "'8-105'.

 T_INSPCHARACTERISTIC-SMPL_PROCEDURE = IT_INSPLAN-SMPL_PROCEDURE. "fix-1

 PERFORM UNIT_CONVERT USING IT_INSPLAN-SMPL_UNIT.

 T_INSPCHARACTERISTIC-SMPL_UNIT = IT_INSPLAN-SMPL_UNIT. "ea

 T_INSPCHARACTERISTIC-SMPL_QUANT = IT_INSPLAN-SMPL_QUANT. "'4.12'.

 APPEND T_INSPCHARACTERISTIC.

 ENDLOOP.

ENDFORM.

Re: BAPI_INSPECTIONPLAN_CREATE error

Raviteja117 — Thu, 16 Nov 2023 05:32:49 GMT

can you please, provide the upload file. so that it can be easy for every one test it, execute it, and finally understnd it.

Re: BAPI_INSPECTIONPLAN_CREATE error

xiswanto — Thu, 16 Nov 2023 08:54:42 GMT

this post is 5 years old with a marked best answer, I don't think the author of this question still expecting others to help with his issue.