topic Re: MODULE POOL in Application Development and Automation Discussions

MODULE POOL

Former Member — Wed, 20 Dec 2006 15:18:27 GMT

HI EXPERTS,.

I AM MAKING SOME MODIFICATIONS TO THE SE38 TRANSACTION THROUGH MODULE POOL.I AM HAVING THE FIRST SCREEN AS THE MP SCREEN N FROM THERE I AM CALLING SE38 DEPENDING ON THE ACTION OF THE USER.HERE I WANT TO SKIP THE FIRST SCREEN N ENTER THE EDITOR DIRECTLY.BUT I AM UNABLE TO ACHIEVE THAT EVEN AFTER USING SKIP FIRST SCREEN.

CAN U GIVE ME A SOLUTION TO THIS.

REGARDS,

SUPRIYA MANIK.

Re: MODULE POOL

RichHeilman — Wed, 20 Dec 2006 15:28:53 GMT

Here is a nice little trick.



data: program_name type string.

program_name = 'ZPROGRAM'.

* You can make it display mode by adding the extension
editor-call for report program_name.   "DISPLAY-MODE

Regards,

Rich Heilman

Re: MODULE POOL

Former Member — Wed, 20 Dec 2006 15:32:17 GMT

why ru using SE38...from ur program ru tryng to execute a report or what else ur doing...

Re: MODULE POOL

Former Member — Wed, 20 Dec 2006 15:40:15 GMT

HI RICH,

TO SET THE PROGRAM STANDARDS I AM CALL DOING THE BDC IN MP AND THE CALLING THE TRANSACTION.WHEN I CALL THE TRANSACTION AFTER PRESSING THE CREATE BUTTON IT SHOULD OPEN THE EDITOR IN THE EDITABLE MODE FOR THE CODE TO BE WRITTEN.THIS IS THE FUNCTIONALITY.

NOW WHEN I SAY CREATE IT IS GOING TO THE FIRST SCREEN N THERE WHEN I CLICK ON CHANGE IT IS GOING TO THE EDITOR.

I WANT TO DIRECTLY GO TO THE EDITOR IN CHANGE MODE WHEN I CLICK ON THE CREATE BUTTON.

HELP ME WITH THIS!!!

Re: MODULE POOL

RichHeilman — Wed, 20 Dec 2006 15:46:03 GMT

Ok then do your BDC coding up to the point when the user is to take over, when calling the transaction set the MODE = 'E'. When there is no more BDC instructions, the program will simply stop and allow the user to take over.

Regards,

Rich Heilman

Re: MODULE POOL

Former Member — Wed, 20 Dec 2006 15:53:33 GMT

STILL IT IS GOING TO THE FIRST SCREEN RICH!!!

Re: MODULE POOL

RichHeilman — Wed, 20 Dec 2006 15:55:32 GMT

Sure, have you recorded the SE38 transaction using SHDB?

Regards,

Rich Heilman

Re: MODULE POOL

Former Member — Wed, 20 Dec 2006 16:02:11 GMT

NOW I AM USING BDC ONLY FOR THE TABLES UPDATE.

I AM CALLING THE TRANSACTION SE38 N THEN TRYING TO SKIP THE FIRST SCREEN.BUT I AM UNABLE TO DO THIS.

SET PARAMETER ID 'RID' FIELD TB_DATA-PROGRAMM

CALL TRANSACTION 'SE38' USING TB_BDCDATA MODE 'N'.

Re: MODULE POOL

RichHeilman — Wed, 20 Dec 2006 16:05:17 GMT

You can not just SKIP the first screen in SE38. You must now do a partial BDC, where you record SE38(entering the name, clicking "Create", giving title, and so on) Then calling SE38 using BDCDATA with MODE 'E'. If you do it right, SE38 will stop at the editor screen.

Regards,

Rich Heilman

Re: MODULE POOL

RichHeilman — Wed, 20 Dec 2006 16:13:32 GMT

For example, run this program, it creates the program(Here ZRICH_0004) fills in the description and goes to the point where you must choose a development class, if you want to simply force local object, then just uncomment that code, it will go directly to the editor screen.



report zrich_0001.

DATA:   BDCDATA type table of BDCDATA  WITH HEADER LINE.
DATA:   MESSTAB type table of BDCMSGCOLL WITH HEADER LINE.



perform bdc_dynpro      using 'SAPLWBABAP' '0100'.
perform bdc_field       using 'BDC_CURSOR'
                              'RS38M-PROGRAMM'.
perform bdc_field       using 'BDC_OKCODE'
                              '=NEW'.
perform bdc_field       using 'RS38M-PROGRAMM'
                        'ZRICH_0004'.    "< program name
perform bdc_field       using 'RS38M-FUNC_EDIT'
                              'X'.

perform bdc_dynpro      using 'SAPLSEDTATTR' '0200'.
perform bdc_field       using 'BDC_CURSOR'
                              'TRDIR-SUBC'.
perform bdc_field       using 'BDC_OKCODE'
                              '=DROPDOWN_ENTER_SC'.
perform bdc_field       using 'RS38M-REPTI'
                        'Test'.          "< description
perform bdc_field       using 'TRDIR-SUBC'
                              '1'.
perform bdc_field       using 'TRDIR-FIXPT'
                         'X'.

perform bdc_dynpro      using 'SAPLSEDTATTR' '0200'.
perform bdc_field       using 'BDC_CURSOR'
                              'RS38M-REPTI'.
perform bdc_field       using 'BDC_OKCODE'
                              '=CONT'.


*perform bdc_dynpro      using 'SAPLSTRD' '0100'.
*perform bdc_field       using 'BDC_CURSOR'
*                              'KO007-L_DEVCLASS'.
*perform bdc_field       using 'BDC_OKCODE'
*                         '=TEMP'.


  call transaction 'SE38' using BDCDATA
                               mode 'E'.

*----------------------------------------------------------------------*
*        Start new screen                                              *
*----------------------------------------------------------------------*
FORM BDC_DYNPRO USING PROGRAM DYNPRO.
  CLEAR BDCDATA.
  BDCDATA-PROGRAM  = PROGRAM.
  BDCDATA-DYNPRO   = DYNPRO.
  BDCDATA-DYNBEGIN = 'X'.
  APPEND BDCDATA.
ENDFORM.

*----------------------------------------------------------------------*
*        Insert field                                                  *
*----------------------------------------------------------------------*
FORM BDC_FIELD USING FNAM FVAL.
    CLEAR BDCDATA.
    BDCDATA-FNAM = FNAM.
    BDCDATA-FVAL = FVAL.
    APPEND BDCDATA.
ENDFORM.

Regards,

Rich Heilman

Re: MODULE POOL

Former Member — Wed, 20 Dec 2006 16:32:29 GMT

THANKS A LOT RICH.IT REALLY SOLVED MY PROBLEM.I CANT THANK U ENOUGH.