select-option field on module pool screen

Former Member — Mon, 30 Oct 2006 12:23:57 GMT

hi all,

Can anyone pls let me know, how to design and use a field like a select-option field on a Module-pool screen i.e. how can i get that multiple selections tab after the high field of the select-options.

thanks in advance,

vinny

Re: select-option field on module pool screen

RichHeilman — Mon, 30 Oct 2006 13:05:24 GMT

All you need to do is define your selection screen and then embed it in a subscreen area of your dynpro(screen). Here is a sample program.



report zrich_0006 .

tables: mara.

* Custom Selection Screen 1010
<b>selection-screen begin of screen 1010 as subscreen.</b>
selection-screen begin of block b1 with frame title text-001.
parameters: p_rad1 radiobutton group grp1 default 'X',
            p_rad2 radiobutton group grp1,
            p_rad3 radiobutton group grp1.
select-options: s_matnr for  mara-matnr,
                s_matkl for  mara-matkl,
                s_mtart for  mara-mtart.
selection-screen end of block b1.
selection-screen end of screen 1010.


start-of-selection.

  call screen 100.
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
module status_0100 output.
*  SET PF-STATUS 'xxxxxxxx'.
*  SET TITLEBAR 'xxx'.

endmodule.
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
module user_command_0100 input.

endmodule.


<b>* Screen screen 100 with a subscreen area called "subscreen_1010"
* Screen Flow Logic follows

*process before output.
*
*  module status_0100.
*
*  call subscreen subscreen_1010 including sy-repid '1010'.
*
*process after input.
*
*  call subscreen subscreen_1010 .
*
*  module user_command_0100.</b>

Regards,

Rich Heilman

Re: select-option field on module pool screen

Former Member — Mon, 30 Oct 2006 13:12:41 GMT

Refer this link:

Regards,

ravi

Re: select-option field on module pool screen

Former Member — Sat, 04 Nov 2006 05:54:10 GMT

Hi Vinny,

We have an option called as Ranges.. Which is same as that of the Select options.. So when u r doing it in Module pool program use this Ranges.. It will work out

With REgards,

Murthy

topic Re: select-option field on module pool screen in Application Development and Automation Discussions

select-option field on module pool screen

Re: select-option field on module pool screen

Re: select-option field on module pool screen

Re: select-option field on module pool screen