topic Re: Please send the ALV code in Application Development and Automation Discussions

Please send the ALV code

Former Member — Sat, 11 Nov 2006 07:53:28 GMT

Please send the ALV code.

requirement:

If the user having the role 1 I want to download all the fields

If the user having the role 2 I want to download the 2 or 3 fields.

Kindly send the code.

thanks in ad......

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 08:06:45 GMT

Here is the Pseudo Code

1. You need to have a custom button for download functionality

2. Upon clicking the button do a authority check

AUTHORITY-CHECK.

If sy-subrc = 0.

Download the entire internal table.

else.

Have another table with only those fields and copy the data from main internal table and then download.

endif.

Regards,

Ravi

Note - Please mark all the helpful answers

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 08:10:01 GMT

where i have to write the Auth check.

after the event_download is it correct.

its very helpfull answwer.

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 08:15:49 GMT

U can try to use the authorizazions or check if the user belong or not belong to a certain role:

DATA: ROLE.

* Extract the fields for ALV
  CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
       EXPORTING
            I_PROGRAM_NAME     = GT_REPID
            I_INTERNAL_TABNAME = 'T_OUTPUT'
            I_INCLNAME         = GT_REPID
*            I_STRUCTURE_NAME   = 'LFA1'
       CHANGING
            CT_FIELDCAT        = GT_FIELDCAT[].


* Check the authorizations:
  AUTHORITY-CHECK OBJECT <AUTH OBJECT>
           ID <ID> FIELD <FIELD>.
           
  IF SY-SUBRC = 0. 
    ROLE = '1'.
  ELSE.
    ROLE = '2'.
  ENDIF.


  LOOP AT GT_FIELDCAT INTO LS_FIELDCAT.  
    CASE LS_FIELDCAT-FIELDNAME.
      WHEN <FIELD1> OR <FIELD2> ....
         IF ROLE = '2'.
           DELETE GT_FIELDCAT.
         ENDIF.
      WHEN OTHERS.
      .............. 
    ENDCASE.
  ENDLOOP.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 08:26:06 GMT

MAX,

IN WHICH TABLE CAN I GET THE ROLES DETAILS AND USER DETAILS.

HOW I CAN LINK THESE DETAILS.

I AM DOING THE HRREPORT THE OUTPUT WILL DISPLAY IN ALV GRID.

PL GUIDE ME.

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 08:32:33 GMT

In table AGR_USERS you find all user roles.

My code should be good for you if "Download" means you don't have to show some fields.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 08:46:16 GMT

MAX,

CAN U SEND THE FULL CODINF PL

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 09:03:42 GMT

Here I use the fm for ALV, but the concept doesn't change for OO ALV.

I don't know how you use the ALV

TYPE-POOLS SLIS.

DATA: GT_FIELDCAT   TYPE SLIS_T_FIELDCAT_ALV,
      LS_FIELDCAT   TYPE SLIS_FIELDCAT_ALV,
      GT_REPID      LIKE SY-REPID.


DATA: T_ROLES LIKE STANDARD TABLE OF AGR_USERS WITH HEADER LINE.

DATA: BEGIN OF T_OUTPUT OCCURS 0,
        FIELD1,
        FIELD2,
        FIELD3,
        FIELD4,
        FIELDN,
      END   OF T_OUTPUT.

DATA: ROLE.


* Check user rules

SELECT * FROM AGR_USERS INTO TABLE T_ROLES WHERE UNAME = SY-UNAME
                                             AND FROM_DAT <= SY-DATUM
                                             AND TO_DAT => SY-DATUM.

READ TABLE T_ROLES WITH KEY AGR_NAME = '????????'.
IF SY-SUBRC = 0.
* User can see all fields.
  ROLE = '1'.
ELSE.
  ROLE = '2'.
ENDIF.




GT_REPID = SY-REPID.

* Extract the fields for ALV
CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
     EXPORTING
          I_PROGRAM_NAME     = GT_REPID
          I_INTERNAL_TABNAME = 'T_OUTPUT'
          I_INCLNAME         = GT_REPID
     CHANGING
          CT_FIELDCAT        = GT_FIELDCAT[].


* Check the authorizations:

IF ROLE = '2'.
* Delete all fields the user can't see

  DELETE GT_FIELDCAT WHERE FIELDNAME = 'FIELD1'
                        OR FIELDNAME = 'FIELD2'.

ENDIF.

* Show the output

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
     EXPORTING
          I_CALLBACK_PROGRAM = GT_REPID
          IT_FIELDCAT        = GT_FIELDCAT
     TABLES
          T_OUTTAB           = T_OUTPUT.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 09:10:11 GMT

MAX,

THANKS FOR UR HELP.

I AM GOING TO WRITE THE CODE.

CAN U GIVE UR YAHOO CHAT IT

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 09:11:31 GMT

I HAVE WRITTEN THE BELOW CODE.

FIRST I TRY TO DISPLAY THE ALL RECORDS.

REPORT ZSSN

LINE-SIZE 140

LINE-COUNT 40

NO STANDARD PAGE HEADING.

----

Program Name : ZSSN Date Created : 11/13/2006 *
Author's Name : Satish (CN000244) *
Program Title : SSN Banking Info *

----

Tables

TABLES: PERNR,

T502T. " Marital Status Designators

TYPE-POOLS: SLIS.

Info Types

INFOTYPES: 0001,

0002.

Internal Tables

*DATA: T_P0002 LIKE STANDARD TABLE OF P0002 WITH HEADER LINE.

DATA: T_T502T LIKE STANDARD TABLE OF T502T WITH HEADER LINE.

DATA: STAT(10) TYPE C,

CHECK TYPE I.

DATA: BEGIN OF T_P0002 OCCURS 0,

BEGDA LIKE P0002-BEGDA,

ENDDA LIKE P0002-ENDDA,

NACHN LIKE P0002-NACHN,

VORNA LIKE P0002-VORNA,

FAMST LIKE T502T-FAMST,

FTEXT LIKE T502T-FTEXT,

END OF T_P0002.

DATA: gt_fieldcat TYPE slis_t_fieldcat_alv, "ALV Catalog Table

gs_fieldcat TYPE slis_fieldcat_alv. "ALV Catalog Structure

Start of selection

START-OF-SELECTION.

GET PERNR.

To get the marital status

SELECT * FROM T502T

INTO TABLE T_T502T

WHERE SPRSL = 'EN'.

IF SY-SUBRC EQ 0 .

SORT T_T502T BY FAMST .

ENDIF .

RP-READ-INFOTYPE P0002-PERNR 0002 P0002 PN-BEGDA PN-ENDDA.

RP-PROVIDE-FROM-LAST P0002 SPACE PN-BEGDA '31129999' .

IF PNP-SW-FOUND EQ '1' .

READ TABLE T_T502T WITH KEY FAMST = P0002-FAMST

BINARY SEARCH .

T_P0002-BEGDA = P0002-BEGDA.

T_P0002-ENDDA = P0002-ENDDA.

T_P0002-NACHN = P0002-NACHN.

T_P0002-VORNA = P0002-VORNA.

T_P0002-FAMST = P0002-FAMST.

T_P0002-FTEXT = T_T502T-FTEXT.

APPEND T_P0002.

endif.

gs_fieldcat-col_pos = '1'.

gs_fieldcat-fieldname = 'BEGDA'.

gs_fieldcat-outputlen = 10.

gs_fieldcat-seltext_l = 'BEGIN DATE'.

APPEND gs_fieldcat TO gt_fieldcat.

gs_fieldcat-col_pos = '2'.

gs_fieldcat-fieldname = 'ENDDA'.

gs_fieldcat-outputlen = 10.

gs_fieldcat-seltext_l = 'END DATE'.

APPEND gs_fieldcat TO gt_fieldcat.

CLEAR gs_fieldcat.

gs_fieldcat-col_pos = '3'.

gs_fieldcat-fieldname = 'NACHN'.

gs_fieldcat-outputlen = 15.

gs_fieldcat-seltext_l = 'LAST NAME'.

APPEND gs_fieldcat TO gt_fieldcat.

CLEAR gs_fieldcat.

gs_fieldcat-col_pos = '4'.

gs_fieldcat-fieldname = 'VORNA'.

gs_fieldcat-outputlen = 15.

gs_fieldcat-seltext_l = 'FIRST NAME'.

APPEND gs_fieldcat TO gt_fieldcat.

CLEAR gs_fieldcat.

gs_fieldcat-col_pos = '5'.

gs_fieldcat-fieldname = 'FAMST'.

gs_fieldcat-outputlen = 5.

gs_fieldcat-seltext_l = 'MARITAL KEY'.

APPEND gs_fieldcat TO gt_fieldcat.

gs_fieldcat-col_pos = '6'.

gs_fieldcat-fieldname = 'FTEXT'.

gs_fieldcat-outputlen = 5.

gs_fieldcat-seltext_l = 'MARITAL STATUS'.

APPEND gs_fieldcat TO gt_fieldcat.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'

EXPORTING

i_background_id = 'ALV_BACKGROUND'

i_grid_title = 'SSN BANK INFO'

i_structure_name = 'veda'

it_fieldcat = gt_fieldcat[]

TABLES

t_outtab = T_P0002.

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 09:17:58 GMT

In your situation:

CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'

EXPORTING

I_PROGRAM_NAME = GT_REPID

I_INTERNAL_TABNAME = 'T_P0002'

I_INCLNAME = GT_REPID

CHANGING

CT_FIELDCAT = GT_FIELDCAT[].

And the delete all fields the users can't see.

max_abap4@yahoo.it

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 09:34:52 GMT

kindly execute my program.

initially it displayed 1 record. when i click the back button it will add 1 more records ..like that it will increase the records.

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 09:44:55 GMT

Insert the call of grid in END-OF-SELECTION event:

START-OF-SELECTION.

GET PERNR.

To get the marital status

SELECT * FROM T502T

INTO TABLE T_T502T

WHERE SPRSL = 'EN'.

IF SY-SUBRC EQ 0 .

SORT T_T502T BY FAMST .

ENDIF .

RP-READ-INFOTYPE P0002-PERNR 0002 P0002 PN-BEGDA PN-ENDDA.

RP-PROVIDE-FROM-LAST P0002 SPACE PN-BEGDA '31129999' .

IF PNP-SW-FOUND EQ '1' .

READ TABLE T_T502T WITH KEY FAMST = P0002-FAMST

BINARY SEARCH .

T_P0002-BEGDA = P0002-BEGDA.

T_P0002-ENDDA = P0002-ENDDA.

T_P0002-NACHN = P0002-NACHN.

T_P0002-VORNA = P0002-VORNA.

T_P0002-FAMST = P0002-FAMST.

T_P0002-FTEXT = T_T502T-FTEXT.

APPEND T_P0002.

endif.

END-OF-SELECTION

gs_fieldcat-col_pos = '1'.

gs_fieldcat-fieldname = 'BEGDA'.

gs_fieldcat-outputlen = 10.

gs_fieldcat-seltext_l = 'BEGIN DATE'.

APPEND gs_fieldcat TO gt_fieldcat.

gs_fieldcat-col_pos = '2'.

gs_fieldcat-fieldname = 'ENDDA'.

gs_fieldcat-outputlen = 10.

gs_fieldcat-seltext_l = 'END DATE'.

APPEND gs_fieldcat TO gt_fieldcat.

CLEAR gs_fieldcat.

gs_fieldcat-col_pos = '3'.

gs_fieldcat-fieldname = 'NACHN'.

gs_fieldcat-outputlen = 15.

gs_fieldcat-seltext_l = 'LAST NAME'.

APPEND gs_fieldcat TO gt_fieldcat.

CLEAR gs_fieldcat.

gs_fieldcat-col_pos = '4'.

gs_fieldcat-fieldname = 'VORNA'.

gs_fieldcat-outputlen = 15.

gs_fieldcat-seltext_l = 'FIRST NAME'.

APPEND gs_fieldcat TO gt_fieldcat.

CLEAR gs_fieldcat.

gs_fieldcat-col_pos = '5'.

gs_fieldcat-fieldname = 'FAMST'.

gs_fieldcat-outputlen = 5.

gs_fieldcat-seltext_l = 'MARITAL KEY'.

APPEND gs_fieldcat TO gt_fieldcat.

gs_fieldcat-col_pos = '6'.

gs_fieldcat-fieldname = 'FTEXT'.

gs_fieldcat-outputlen = 5.

gs_fieldcat-seltext_l = 'MARITAL STATUS'.

APPEND gs_fieldcat TO gt_fieldcat.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'

EXPORTING

i_background_id = 'ALV_BACKGROUND'

i_grid_title = 'SSN BANK INFO'

i_structure_name = 'veda'

it_fieldcat = gt_fieldcat[]

TABLES

t_outtab = T_P0002.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 10:23:08 GMT

MAX,

MY REQUIREMENT IS :

I WANT TO DISPLAY 7 FIELDS IN THE OUTPUT FOR BOTH ROLES.

WHEN THE ROLE 1 USER EXECUTE THE REPORT, IT IS NOT ALLOWED TO DOWNLOAD FOR 1 FILED.

WHEN THE ROLE 2 USER EXECUTE THE REPORT IT DOWNLOAD THE ALL FIELDS I.E 7 FIELDS.

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 10:55:35 GMT

Try this example:

TYPE-POOLS SLIS.

PARAMETERS: P_ROLE TYPE N.

DATA: GT_FIELDCAT   TYPE SLIS_T_FIELDCAT_ALV,
      ET_FIELDCAT   TYPE SLIS_T_FIELDCAT_ALV,
      LS_FIELDCAT   TYPE SLIS_FIELDCAT_ALV,
      GT_REPID      LIKE SY-REPID,
      GT_EVENT_EXIT TYPE SLIS_T_EVENT_EXIT,
      LT_EVENT_EXIT TYPE SLIS_EVENT_EXIT.


DATA: T_ROLES LIKE STANDARD TABLE OF AGR_USERS WITH HEADER LINE.

DATA: BEGIN OF T_OUTPUT OCCURS 0,
        FIELD1,
        FIELD2,
        FIELD3,
        FIELD4,
      END   OF T_OUTPUT.

DATA: ROLE.


* Check user rules

*SELECT * FROM AGR_USERS INTO TABLE T_ROLES WHERE UNAME = SY-UNAME
*                                             AND FROM_DAT <= SY-DATUM
*                                             AND TO_DAT => SY-DATUM.
*
*READ TABLE T_ROLES WITH KEY

DO 4 TIMES.
  MOVE SY-INDEX TO T_OUTPUT-FIELD1.
  T_OUTPUT-FIELD2 = T_OUTPUT-FIELD3 = T_OUTPUT-FIELD4 = T_OUTPUT-FIELD1.
  APPEND T_OUTPUT.
ENDDO.


GT_REPID = SY-REPID.

* Extract the fields for ALV
CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
     EXPORTING
          I_PROGRAM_NAME     = GT_REPID
          I_INTERNAL_TABNAME = 'T_OUTPUT'
          I_INCLNAME         = GT_REPID
     CHANGING
          CT_FIELDCAT        = GT_FIELDCAT[].




LT_EVENT_EXIT-UCOMM  = '&XXL'.
LT_EVENT_EXIT-BEFORE = 'X'.
LT_EVENT_EXIT-AFTER  = 'X'.
APPEND LT_EVENT_EXIT TO GT_EVENT_EXIT.



* Check the authorizations:


ROLE = P_ROLE.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
     EXPORTING
          I_CALLBACK_PROGRAM      = GT_REPID
          I_CALLBACK_USER_COMMAND = 'USER_COMMAND'
          IT_FIELDCAT             = GT_FIELDCAT
          IT_EVENT_EXIT           = GT_EVENT_EXIT
     TABLES
          T_OUTTAB                = T_OUTPUT.

*---------------------------------------------------------------------*
*       FORM user_command                                             *
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
*  -->  R_UCOMM                                                       *
*  -->  RS_SELFIELD                                                   *
*---------------------------------------------------------------------*
FORM USER_COMMAND USING R_UCOMM LIKE SY-UCOMM
                        RS_SELFIELD TYPE SLIS_SELFIELD.

  CHECK R_UCOMM = '&XXL'. "Create (excel) file

  CHECK ROLE = '1'.

  IF RS_SELFIELD-BEFORE_ACTION = 'X'.
    CALL FUNCTION 'REUSE_ALV_GRID_LAYOUT_INFO_GET'
         IMPORTING
              ET_FIELDCAT = ET_FIELDCAT.

* Save old chararcterstics
    GT_FIELDCAT[] = ET_FIELDCAT[].

    LOOP AT ET_FIELDCAT INTO LS_FIELDCAT WHERE FIELDNAME = 'FIELD2'
                                            OR FIELDNAME = 'FIELD3'
                                            OR FIELDNAME = 'FIELD4'.
      LS_FIELDCAT-NO_OUT = 'X'.
      MODIFY ET_FIELDCAT FROM LS_FIELDCAT.
    ENDLOOP.

* Set new layout
    CALL FUNCTION 'REUSE_ALV_GRID_LAYOUT_INFO_SET'
         EXPORTING
              IT_FIELDCAT = ET_FIELDCAT.

  ENDIF.




  IF RS_SELFIELD-AFTER_ACTION = 'X'.
* Set old layout
    CALL FUNCTION 'REUSE_ALV_GRID_LAYOUT_INFO_SET'
         EXPORTING
              IT_FIELDCAT = GT_FIELDCAT.
  ENDIF.
ENDFORM.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 11:12:47 GMT

both r giving the same results:

i want like this;

1 2 3

if role = 2.

if i download alv report foor role 2. the result should be

1 2

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 11:25:49 GMT

How are you downloading the report?

I tried it and if the role is 1 only first colunm is dowloaded.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 11:31:47 GMT

In the selection screen i give 1 and execute the report.

it will display the 4 rows and 4 columns.

and then i try to download, using the local file and select it as spreadsheet

and save it as max.xls in local disk.

when i open the max.xls it will display all 4 columns and 4 rows.

thanks in ad

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 11:45:43 GMT

You haven't read well what I wrote.

In my previuos example I developed only the case to export the data to excel (Spreadsheet option), in this case the OK_CODE is &XXL'.

Now I've inserted all options to export the data:

OK_CODE -> &XXL --> Spreadsheet

OK_CODE -> &AQW --> Word Processing

OK_CODE -> %PC --> Local file

OK_CODE -> &CRTEMPL --> Crystal report

TYPE-POOLS SLIS.

PARAMETERS: P_ROLE TYPE N.

DATA: GT_FIELDCAT   TYPE SLIS_T_FIELDCAT_ALV,
      ET_FIELDCAT   TYPE SLIS_T_FIELDCAT_ALV,
      LS_FIELDCAT   TYPE SLIS_FIELDCAT_ALV,
      GT_REPID      LIKE SY-REPID,
      GT_EVENT_EXIT TYPE SLIS_T_EVENT_EXIT,
      LT_EVENT_EXIT TYPE SLIS_EVENT_EXIT.


DATA: T_ROLES LIKE STANDARD TABLE OF AGR_USERS WITH HEADER LINE.

DATA: BEGIN OF T_OUTPUT OCCURS 0,
        FIELD1,
        FIELD2,
        FIELD3,
        FIELD4,
      END   OF T_OUTPUT.

DATA: ROLE.


* Check user rules

*SELECT * FROM AGR_USERS INTO TABLE T_ROLES WHERE UNAME = SY-UNAME
*                                             AND FROM_DAT <= SY-DATUM
*                                             AND TO_DAT => SY-DATUM.
*
*READ TABLE T_ROLES WITH KEY

DO 4 TIMES.
  MOVE SY-INDEX TO T_OUTPUT-FIELD1.
  T_OUTPUT-FIELD2 = T_OUTPUT-FIELD3 = T_OUTPUT-FIELD4 = T_OUTPUT-FIELD1.
  APPEND T_OUTPUT.
ENDDO.


GT_REPID = SY-REPID.

* Extract the fields for ALV
CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
     EXPORTING
          I_PROGRAM_NAME     = GT_REPID
          I_INTERNAL_TABNAME = 'T_OUTPUT'
          I_INCLNAME         = GT_REPID
     CHANGING
          CT_FIELDCAT        = GT_FIELDCAT[].



LT_EVENT_EXIT-BEFORE = 'X'.
LT_EVENT_EXIT-AFTER  = 'X'.
LT_EVENT_EXIT-UCOMM  = '&XXL'.  "<-- Excel
APPEND LT_EVENT_EXIT TO GT_EVENT_EXIT.
LT_EVENT_EXIT-UCOMM  = '&AQW'.  "<-- Word Processing
APPEND LT_EVENT_EXIT TO GT_EVENT_EXIT.
LT_EVENT_EXIT-UCOMM  = '%PC'.  "<-- Local file
APPEND LT_EVENT_EXIT TO GT_EVENT_EXIT.
LT_EVENT_EXIT-UCOMM  = '&CRTEMPL'. "<--- Crystal Report
APPEND LT_EVENT_EXIT TO GT_EVENT_EXIT.


* Check the authorizations:


ROLE = P_ROLE.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
     EXPORTING
          I_CALLBACK_PROGRAM      = GT_REPID
          I_CALLBACK_USER_COMMAND = 'USER_COMMAND'
          IT_FIELDCAT             = GT_FIELDCAT
          IT_EVENT_EXIT           = GT_EVENT_EXIT
     TABLES
          T_OUTTAB                = T_OUTPUT.

*---------------------------------------------------------------------*
*       FORM user_command                                             *
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
*  -->  R_UCOMM                                                       *
*  -->  RS_SELFIELD                                                   *
*---------------------------------------------------------------------*
FORM USER_COMMAND USING R_UCOMM LIKE SY-UCOMM
                        RS_SELFIELD TYPE SLIS_SELFIELD.

  CHECK ROLE = '2'.

  IF RS_SELFIELD-BEFORE_ACTION = 'X'.
    CALL FUNCTION 'REUSE_ALV_GRID_LAYOUT_INFO_GET'
         IMPORTING
              ET_FIELDCAT = ET_FIELDCAT.

* Save old chararcterstics
    GT_FIELDCAT[] = ET_FIELDCAT[].

    LOOP AT ET_FIELDCAT INTO LS_FIELDCAT WHERE FIELDNAME = 'FIELD2'
                                            OR FIELDNAME = 'FIELD3'
                                            OR FIELDNAME = 'FIELD4'.
      LS_FIELDCAT-NO_OUT = 'X'.
      MODIFY ET_FIELDCAT FROM LS_FIELDCAT.
    ENDLOOP.

* Set new layout
    CALL FUNCTION 'REUSE_ALV_GRID_LAYOUT_INFO_SET'
         EXPORTING
              IT_FIELDCAT = ET_FIELDCAT.

  ENDIF.




  IF RS_SELFIELD-AFTER_ACTION = 'X'.
* Set old layout
    CALL FUNCTION 'REUSE_ALV_GRID_LAYOUT_INFO_SET'
         EXPORTING
              IT_FIELDCAT = GT_FIELDCAT.
  ENDIF.
ENDFORM.

Max

Re: Please send the ALV code

Former Member — Sat, 11 Nov 2006 11:55:04 GMT

thanks for ur unbelivable help.

thank uuuuuu soooooooooooooo much MAX.