topic Re: Extracting MATNR: in Application Development and Automation Discussions

Extracting MATNR:

Former Member — Mon, 20 Nov 2006 00:13:14 GMT

Hi,

Can some one help me with the sample code or a prototype or logic in:

Identifying the List of materials (MATNR) which are unique to Plant number(WERKS) 0004 only & Non shared with other Plants.

Thank you.

Re: Extracting MATNR:

RichHeilman — Mon, 20 Nov 2006 00:19:10 GMT

You can use table MARC. First do a SELECT and get all of the materials for plant 4. Then loop at this internal table and do a select against MARC with that material, then check how many records where retrieved, if more than one, then you know that that material is extended to other plants, not just plant 4.

data: imarc type table of marc with header line.
data: imarcx type table of marc with header line.
data: marc_lines type i.

select * into table imarc from marc
                 where werks = '0004'.

loop at imarc.

refresh imarcx.
select * into table imarcx from marc
                where matnr = imarc-matnr.
describe table imarcx lines marc_lines.
if marc_lines > 1.
  write:/ 'Material is extended to other plants, not just 0004'.
elseif marc_lines = 1.
  write:/ 'Material is extended to plant 0004 only'.
endif.

endloop.

Regards,

Rich Heilman

Re: Extracting MATNR:

suresh_datti — Mon, 20 Nov 2006 01:57:59 GMT

Rich:

When using select * into table inside a loop, is the REFRESH still needed?

~Suresh

Re: Extracting MATNR:

Former Member — Mon, 20 Nov 2006 02:34:44 GMT

Hi Sekhar

Please check another way of extracting the same.

TABLES: MARC.
TYPES: BEGIN OF T_MARC,
         MATNR TYPE MATNR,
         COUNT TYPE I,
       END OF T_MARC.
DATA: IT_MARC TYPE TABLE OF T_MARC.
PARAMETERS: P_WERKS TYPE WERKS_D OBLIGATORY.

SELECT MATNR COUNT( * ) INTO TABLE IT_MARC FROM MARC AS A
       WHERE EXISTS ( SELECT * FROM MARC WHERE MATNR = A~MATNR
                                         AND   WERKS = P_WERKS )
       GROUP BY MATNR
       HAVING COUNT( * ) EQ 1.

Kind Regards

Eswar

Re: Extracting MATNR:

Former Member — Mon, 20 Nov 2006 03:05:10 GMT

hI,

TRY THIS CODE.

tables: mara.

data: itab like marC occurs 0 with header line.

DATA: ITAB_TMP LIKE MARC OCCURS 0 WITH HEADER LINE.

selection-screen: begin of block blk1 with frame title text-001.

select-options: s_MATNR for mara-matnr.

selection-screen end of block blk1.

start-of-selection.

select * from marC into table itab

where matnr in s_MATNR.

SORT ITAB.

ITAB_TMP[] = ITAB[].

SORT ITAB_TMP.

loop at itab.

LOOP AT ITAB_TMP WHERE MATNR = ITAB-MATNR AND

WERKS <> ITAB-WERKS.

DELETE ITAB WHERE MATNR = ITAB-MATNR.

EXIT.

ENDLOOP.

endloop.

LOOP AT ITAB.

WRITE : / ITAB-MATNR,20 ITAB-WERKS.

ENDLOOP.

Note: Above code is sample only. needs to be tuned as per the requirement.

regards,

sundaramj.

Re: Extracting MATNR:

Former Member — Mon, 20 Nov 2006 03:07:40 GMT

Thank you Rich!!

That was awesome. I really didn,t get the thought of 'DESCRIBE'...

Anyways thank you once again for the detailed code.

Re: Extracting MATNR:

Former Member — Mon, 20 Nov 2006 03:11:25 GMT

Thanks to others too.

But I felt much comfortable with his code i ment by RICH...

Anyways I'm rewardin you guys too .

Re: Extracting MATNR:

RichHeilman — Mon, 20 Nov 2006 14:00:09 GMT

Suresh, no the REFRESH is not needed. It is just one of my habits to clear stuff.

Regards,

Rich Heilman