Dynamic ALV

Former Member — Tue, 10 Oct 2006 12:59:11 GMT

Hi friends,

I have requirement to display output listin ALV.

Once user entered in selection screen input Work order type (1,2...6). if user select order type 1 and 2 . the display like this Plant, Plant description, No of ord1,

%no of ord1, No of Ord2, % no of ord2, Total no of Orders.

if the user seleceted order type 1, 2, and 4. The output display like this

Plant, Plant description, No of ord1,

%no of ord1, No of Ord2, % no of ord2, no of ord4, % No of ord4 , Total no of Orders.

Its urgent requirement.

Re: Dynamic ALV

RichHeilman — Tue, 10 Oct 2006 13:02:43 GMT

Here is an example program which you can use to build your program.



report zrich_0001.

type-pools: slis.

field-symbols: <dyn_table> type standard table,
               <dyn_wa>.

data: alv_fldcat type slis_t_fieldcat_alv,
      it_fldcat type lvc_t_fcat.

selection-screen begin of block b1 with frame title text-001.
parameters: p_flds(5) type c.
selection-screen end of block b1.

start-of-selection.

* build the dynamic internal table
  perform build_dyn_itab.

* write 5 records to the alv grid
  do 5 times.
    perform build_report.
  enddo.

* call the alv grid.
  perform call_alv.


************************************************************************
*  Build_dyn_itab
************************************************************************
form build_dyn_itab.

  data: new_table type ref to data,
        new_line  type ref to data,
        wa_it_fldcat type lvc_s_fcat.

* Create fields .
  do p_flds times.
    clear wa_it_fldcat.
    wa_it_fldcat-fieldname = sy-index.
    wa_it_fldcat-datatype = 'CHAR'.
    wa_it_fldcat-intlen = 5.
    append wa_it_fldcat to it_fldcat .
  enddo.

* Create dynamic internal table and assign to FS
  call method cl_alv_table_create=>create_dynamic_table
               exporting
                  it_fieldcatalog = it_fldcat
               importing
                  ep_table        = new_table.

  assign new_table->* to <dyn_table>.

* Create dynamic work area and assign to FS
  create data new_line like line of <dyn_table>.
  assign new_line->* to <dyn_wa>.

endform.

*********************************************************************
*      Form  build_report
*********************************************************************
form build_report.

  data: fieldname(20) type c.
  data: fieldvalue(5) type c.
  data: index(3) type c.
  field-symbols: <fs1>.

  do p_flds times.

    index = sy-index.

* Set up fieldvalue
    concatenate 'FLD' index into
             fieldvalue.
    condense   fieldvalue no-gaps.

    assign component  index  of structure <dyn_wa> to <fs1>.
    <fs1> =  fieldvalue.

  enddo.

* Append to the dynamic internal table
  append <dyn_wa> to <dyn_table>.


endform.

************************************************************************
*  CALL_ALV
************************************************************************
form call_alv.

  data: wa_cat like line of alv_fldcat.

  do p_flds times.
    clear wa_cat.
    wa_cat-fieldname = sy-index.
    wa_cat-seltext_s = sy-index.
    wa_cat-outputlen = '5'.
    append wa_cat to alv_fldcat.
  enddo.


* Call ABAP List Viewer (ALV)
  call function 'REUSE_ALV_GRID_DISPLAY'
       exporting
            it_fieldcat = alv_fldcat
       tables
            t_outtab    = <dyn_table>.

endform.

Regards,

Rich Heilman

Re: Dynamic ALV

Former Member — Tue, 10 Oct 2006 13:03:45 GMT

Hello,

If depend on the fieldcat.

If workorder = '2'.

Built the fieldcat depending on ur réquirement

endif.

Similarly for alll the inputs.

If useful reward.

Vasanth

topic Re: Dynamic ALV in Application Development and Automation Discussions

Dynamic ALV

Re: Dynamic ALV

Re: Dynamic ALV