topic Re: [Dump] Get the spool list in Application Development and Automation Discussions

[Dump] Get the spool list

guillaume-hrc — Tue, 25 Jul 2006 07:56:21 GMT

Hi,

Isn't there a way to retrieve the spool list generated by transaction ST22OLD or ST22 using FM or classes ?

It seems that both are using CALL DIALOG which prevents me from getting this list.

I tried FM 'RS_SNAP_DUMP_DISPLAY' and some SUBMIT ... EXPORTING LIST without success.

The only option left - as I see it - is to write my own code based on SAPMS380 using:

Include MS380TOP

Subroutine PRODUCE_LIST

Thanks in advance.

best regards,

Guillaume

Re: [Dump] Get the spool list

Laxmana_Appana_ — Tue, 25 Jul 2006 08:30:28 GMT

Hi,

Check this table : SNAP and database view : SNAP_BEG.

dump analysis , initial ALV contents are coming from this table only .

or check this program : RSSHOWRABAX

Regards

Appana

Re: [Dump] Get the spool list

guillaume-hrc — Tue, 25 Jul 2006 08:42:46 GMT

Hi Appana,

Thanks for this but in fact, the data are stored in a complex way in those tablse. The logic to display them is in SAPMS380 which is called by RSSHOWRABAX but - yet again - through a CALL DIALOG.

It means that I cannot get the spool list programmatically.

Best regards,

Guillaume

Re: [Dump] Get the spool list

guillaume-hrc — Thu, 14 Dec 2006 09:55:28 GMT

Hi,

Here is a report that allows output of the list.

*&---------------------------------------------------------------------*
*& Report  ZGGAR_SNAP_VIEWER                                           *
*&                                                                     *
*&---------------------------------------------------------------------*
*&                                                                     *
*&                                                                     *
*&---------------------------------------------------------------------*

INCLUDE rsshowrabax_top1.
INCLUDE rsshowrabax_class.

DATA: only_once         TYPE xfeld.
*DATA: second_language TYPE syst-langu.
DATA: ta_snap           TYPE TABLE OF snap.

FIELD-SYMBOLS: <ft>     TYPE ANY TABLE,
               <rs380>  TYPE ANY,
               <fs>     TYPE ANY.

SELECTION-SCREEN BEGIN OF BLOCK b WITH FRAME TITLE text-cs0.

PARAMETERS:
        p_datum  TYPE snap-datum         MEMORY ID st22_datum,
        p_uzeit  TYPE snap-uzeit         MEMORY ID st22_zeit,
        p_ahost  TYPE snap-ahost         MEMORY ID st22_host   DEFAULT sy-host,
        p_uname  TYPE snap-uname         MEMORY ID st22_name,
        p_mandt  TYPE snap-mandt         MEMORY ID st22_mandt  DEFAULT sy-mandt,
        p_xhold  TYPE snap-xhold         MEMORY ID st22_xhold,
        p_errid  TYPE snapt-errid        MEMORY ID st22_errid,
        p_prg    TYPE rdumpov-gprogram   MEMORY ID st22_prgname,
        p_except TYPE rdumpov-rexception MEMORY ID st22_except.

SELECTION-SCREEN END OF BLOCK b.

*------------------*
START-OF-SELECTION.
*------------------*

  SELECT * FROM snap INTO TABLE ta_snap
                     WHERE datum = p_datum
                       AND uzeit = p_uzeit
                       AND ahost = p_ahost
*                      AND modno = p_modno
                       AND mandt = p_mandt
                       AND uname = p_uname.

  SORT ta_snap.

  LOOP AT ta_snap INTO snap.
    PERFORM extract_strings_from_snap IN PROGRAM rsshowrabax.
  ENDLOOP.
  IF sy-subrc <> 0.
    RETURN.
  ENDIF.

  CALL 'C_SAPGPARAM' ID 'NAME'  FIELD 'zcsa/second_language'
                     ID 'VALUE' FIELD second_language.


* Set global variables from SNAP via table FT
  PERFORM set_variable IN PROGRAM rsshowrabax USING:
                    'FC'   cerrid,     "Current error id
                    'AI'   cinclu,     "Current include
                    'AL'   clinno,     "Current line number
                    'EN'   env,        "Environment
                    'US'   usr,        "User data
                    'XC'   exc_name.   "Exception name

  ASSIGN ('(RSSHOWRABAX)ft[]') TO <ft>.

  EXPORT ft              FROM <ft>
         cerrid          FROM cerrid
         exc_name        FROM exc_name
         cinclu          FROM cinclu
         clinno          FROM clinno
         env             FROM env
         usr             FROM usr
         second_language FROM second_language
  TO MEMORY ID 'St22_OLD_NEW'.

TOP-OF-PAGE.
  CHECK only_once IS INITIAL.

  only_once = 'X'.

  ASSIGN ('(SAPMS380)rs380') TO <rs380>.

  ASSIGN ('<rs380>-datum') TO <fs>. <fs> = p_datum.
  ASSIGN ('<rs380>-uzeit') TO <fs>. <fs> = p_uzeit.

  PERFORM page_top IN PROGRAM sapms380.

*------------------*
END-OF-SELECTION.
*------------------*

  PERFORM produce_list IN PROGRAM sapms380.

Best regards,

Guillaume

Re: [Dump] Get the spool list

OttoGold — Thu, 24 Apr 2014 11:34:38 GMT

Ubelievable! 7 years later and this seems to be the only way...