Field Value request for parameter

Former Member — Mon, 24 Jul 2006 22:47:10 GMT

I have two input parameter fields.

I would like to display values (f4) of the second field based on the first field.

Currently the both of these fields values are store in two seperate tables and there is no relationship exists.

Any suggestions on how to do this.

Thanks

Steve

Re: Field Value request for parameter

abdul_hakim — Mon, 24 Jul 2006 23:56:45 GMT

you could try creating collective search help in your case.

Cheers,

Abdul Hakim

Re: Field Value request for parameter

RichHeilman — Tue, 25 Jul 2006 00:08:51 GMT

Please consider the following sample program.



report zrich_0002 .

parameters: p_vbeln type vbak-vbeln,
            p_posnr type vbap-posnr.

at selection-screen on value-request for p_posnr.


  data: begin of help_item occurs 0,
          posnr type vbap-posnr,
          matnr type vbap-matnr,
          arktx type vbap-arktx,
        end of help_item.

  data: dynfields type table of dynpread with header line.


  dynfields-fieldname = 'P_VBELN'.
  append dynfields.

  call function 'DYNP_VALUES_READ'
       exporting
            dyname               = sy-cprog
            dynumb               = sy-dynnr
            translate_to_upper   = 'X'
       tables
            dynpfields           = dynfields
       exceptions
            invalid_abapworkarea = 1
            invalid_dynprofield  = 2
            invalid_dynproname   = 3
            invalid_dynpronummer = 4
            invalid_request      = 5
            no_fielddescription  = 6
            invalid_parameter    = 7
            undefind_error       = 8
            double_conversion    = 9
            stepl_not_found      = 10
            others               = 11.


  read table dynfields with key fieldname = 'P_VBELN'.

  p_vbeln = dynfields-fieldvalue.


  call function 'CONVERSION_EXIT_ALPHA_INPUT'
       exporting
            input  = p_vbeln
       importing
            output = p_vbeln.

  select posnr matnr arktx into table help_item
                 from vbap
                      where vbeln = p_vbeln.



  call function 'F4IF_INT_TABLE_VALUE_REQUEST'
       exporting
            retfield    = 'POSNR'
            dynprofield = 'P_POSNR'
            dynpprog    = sy-cprog
            dynpnr      = sy-dynnr
            value_org   = 'S'
       tables
            value_tab   = help_item.

Regards,

Rich Heilman

Re: Field Value request for parameter

Former Member — Tue, 25 Jul 2006 22:16:50 GMT

Thanks Rich,

I will try this and let you know.

Steve

topic Re: Field Value request for parameter in Application Development and Automation Discussions

Field Value request for parameter

Re: Field Value request for parameter

Re: Field Value request for parameter

Re: Field Value request for parameter