topic Re: dynamic assignment - runtime error. in Application Development and Automation Discussions

dynamic assignment - runtime error.

jyothsna1234 — Sun, 05 Jun 2022 21:39:53 GMT

Hi,

The following is a snippet of programming albeit from a very old SAP tutorial. This gives runtime error. Is dynamic assignment of table name not allowed ? Is this obsolete now. Just curious. Thanks

TABLES: SPFLI, SFLIGHT.

DATA: BEGIN OF WA,

LINE(100),

END OF WA.

PARAMETERS: TABNAME(10) DEFAULT 'SPFLI'.

SELECT * FROM (TABNAME) INTO WA.

WRITE: / WA-LINE.

ENDSELECT.

IF SY-SUBRC NE 0.

WRITE: / TEXT-001.

ENDIF.

Re: dynamic assignment - runtime error.

Sandra_Rossi — Mon, 06 Jun 2022 07:48:54 GMT

SELECT ... FROM (tabname) is not obsolete as you can find in the ABAP documentation.

Maybe the code was working in Non-Unicode SAP systems, but anyway the code in this tutorial (?) should have WA correspond to the structure of the table. You can find lots of working examples in the forum and in the ABAP documentation.

Re: dynamic assignment - runtime error.

Rajasekhar_Dina — Tue, 14 Jun 2022 12:39:06 GMT

Hello,

You can refer the demo program DEMO_SELECT_INTO_NEW_VARIANTS which demonstrates how the NEW addition is used in different variants of the INTO clause.

Re: dynamic assignment - runtime error.

Rajasekhar_Dina — Tue, 14 Jun 2022 12:46:35 GMT

You can try this way:

DATA: dref TYPE REF TO data,

tabname TYPE tabname.

FIELD-SYMBOLS: <row> TYPE any,

<component> TYPE any.

PARAMETERS: P_TABNAME(10) DEFAULT 'SPFLI'.

START-OF-SELECTION.

tabname = p_tabname.

* dynamically create appropriate Data Structure

CREATE DATA dref TYPE (tabname).

ASSIGN dref->* TO <row>.

* fetch the data

SELECT *

FROM (tabname) UP TO 2 ROWS

INTO <row>.

* display the result

NEW-LINE.

DO.

ASSIGN COMPONENT sy-index OF STRUCTURE <row> TO <component>.

IF sy-subrc <> 0.

EXIT. " no more components

ENDIF.

WRITE: <component>.

ENDDO.

ENDSELECT.

Re: dynamic assignment - runtime error.

RaymondGiuseppi — Tue, 14 Jun 2022 13:32:42 GMT

Check online or F1 help

A classic defined work area must meet some prerequisites.
In non obsolete version, you can dynamically define the target work area/internal table, check either @DATA(dobj) or NEW @DATA(dref)

Re: dynamic assignment - runtime error.

matt — Tue, 14 Jun 2022 14:23:15 GMT

What would be most helpful is if you would give some details on what the error message is.

Or is it a secret?