topic Re: Using REDUCE to Sum a Table in Application Development and Automation Discussions

Using REDUCE to Sum a Table

ron_mitton — Tue, 15 Mar 2022 16:51:01 GMT

How can I convert this to a REDUCE expression ?

I can't convert the WHERE to WHILE

Thanks

DATA header_price TYPE bapicond-cond_value.
LOOP AT order_conditions_in ASSIGNING FIELD-SYMBOL(<cond>) WHERE cond_type = 'PR00'.
  header_price = header_price + <cond>-cond_type.
ENDLOOP.

"Unsuccessful attempt
"Message - The statement before "WHILE ..." was not closed (period missing).
DATA(header_price2) = REDUCE bapicond-cond_value( INIT p = 0 
                                                  FOR prices IN order_conditions_in 
                                                  while prices=>cond_type = 'PR00' 
                                                  NEXT p = p + prices-cond_value ).

Re: Using REDUCE to Sum a Table

Sandra_Rossi — Tue, 15 Mar 2022 17:28:22 GMT

You have to use WHERE, not WHILE. Why do you want to use WHILE?

Re: Using REDUCE to Sum a Table

ron_mitton — Tue, 15 Mar 2022 18:07:41 GMT

The documentation only mentions UNTIL and WHILE

REDUCE|NEW|VALUE type( ... FOR ... UNTIL|WHILE ...|... IN ... ... ) .

Re: Using REDUCE to Sum a Table

abo — Tue, 15 Mar 2022 18:28:44 GMT

Here is a complete working example

Re: Using REDUCE to Sum a Table

ron_mitton — Tue, 15 Mar 2022 18:55:17 GMT

Thank you.

This works:

DATA(header_price) = REDUCE bapicond-cond_value( INIT p = 0 
                      FOR prices IN order_conditions_in 
                      WHERE ( cond_type = 'PR00' ) 
                      NEXT p = p + prices-cond_value ).

Re: Using REDUCE to Sum a Table

retired_member — Wed, 16 Mar 2022 09:16:00 GMT

Please be aware, that FOR has two variants:

FOR ... UNTIL|WHILE ... 
      | ... IN ...

FOR ... UNTIL|WHILE has the semantics of statements DO|WHILE.

FOR ... IN has the semantics of LOOP.

You must not mix up the syntax.

Re: Using REDUCE to Sum a Table

MichaelSauter — Thu, 17 Mar 2022 14:43:39 GMT

Hey everyone,

I wrote a small program which does this aggregation in four ways (loop, reduce with for...in...where, while, reduce with for...while). Which one you like most is up to you, I'd go with option 2.

Kind regards,

Michael

types:
  begin of s_input,
    cond_type  type string,
    cond_value type i,
  end of s_input,
  t_input type standard table of s_input with empty key.


data(lt_input) = value t_input(
  ( cond_type = 'PR00' cond_value = 10 )
  ( cond_type = 'PR01' cond_value = 10 )
  ( cond_type = 'PR00' cond_value = 10 )
  ( cond_type = 'PR01' cond_value = 10 ) ).


" loop 
data lv_header_price1 type i.
loop at lt_input assigning field-symbol(<cond>)
  where cond_type = 'PR00'.

  lv_header_price1 = lv_header_price1 + <cond>-cond_value.
endloop.
write: / lv_header_price1.

" reduce with FOR ... IN ...WHERE
data(lv_header_price2) = reduce i( init p = 0
                                   for prices in lt_input
                                   where ( cond_type = 'PR00' )
                                   next p = p + prices-cond_value ).
write: / lv_header_price2.

" while
data lv_header_price3 type i.
data(lv_index) = 1.
while lv_index < lines( lt_input ) + 1.
  if lt_input[ lv_index ]-cond_type = 'PR00'.
    lv_header_price3 = lv_header_price3 + lt_input[ lv_index ]-cond_value.
  endif.
  lv_index = lv_index + 1.
endwhile.
write: / lv_header_price3.

" reduce with FOR ... WHILE
data(lv_header_price4) = reduce i( init p = 0
                                   for i = 1 while i < lines( lt_input ) + 1
                                   next p = cond #( when lt_input[ i ]-cond_type = 'PR00' then p + lt_input[ i ]-cond_value
                                                    else p ) ).
write: / lv_header_price4.