topic Weird behaviour with VALUE and SWITCH in Application Development and Automation Discussions

Weird behaviour with VALUE and SWITCH

EnnoWulff — Mon, 08 Mar 2021 19:46:03 GMT

Today I encountered a strange behaviour after I added a SWITCH statement in a VALUE assignment.

Let's assume there is a simple table with two columns ID and TXT:

  TYPES: BEGIN OF _test,
           id   TYPE char02,
           txt  TYPE string,
         END OF _test,
         _test_t TYPE STANDARD TABLE OF _test WITH DEFAULT KEY.

Then there is a simple VALUE statement to fill the table:

  DATA(test) =  VALUE _test_t(
      ( id = 'AA'   txt = 'AAA' )
      ( id = 'bb'   txt = 'bbb' )
      (             txt = 'CCC' )     ).

Not a big deal and works as expected:

ID | TXT
---+-----
AA | AAA
bb | bbb
   | CCC

Then I added the SWITCH statement because line #2 should have a different value depending on a variable:

  DATA(test) =  VALUE _test_t(
      ( id = 'AA' txt = 'AAA' )
      ( SWITCH #( sy-uname(1)
         WHEN 'E' THEN VALUE #( id = 'BB'  txt = 'BBB' )
                  ELSE VALUE #( id = 'bb'  txt = 'bbb' ) ) )
      ( txt = 'CCC' ) ).

As my username starts with E the result looks - also expected - like this:

ID | TXT
---+-----
AA | AAA
BB | BBB
   | CCC

But then for any reason I didn't want to have the field ID filled in the first line and changed my code accordingly:

  DATA(test) =  VALUE _test_t(
      ( txt = 'AAA' )              "Value for ID deleted!
      ( SWITCH #( sy-uname(1)
         WHEN 'E' THEN VALUE #( id = 'BB'  txt = 'BBB' )
                  ELSE VALUE #( id = 'bb'  txt = 'bbb' ) ) )
      ( txt = 'CCC' ) ).

The expected result would be, that line #2 is the only line where field ID is filled:

ID | TXT
---+-----
   | AAA
BB | BBB
   | CCC

But the result is the following:

ID | TXT
---+-----
   | AAA
BB | BBB
BB | CCC

Line #3 is filled with ID = "BB" although I do not tell the system to do so...

I tested on two different SAP-Systems:

SAP_ABA 750/ SAP_BASIS 750
SAP_ABA 75E/ SAP_BASIS 754

Can anyone proof this behavior or tell me what I am doing wrong?

Thanks in advance
~Enno

Re: Weird behaviour with VALUE and SWITCH

nomssi — Mon, 08 Mar 2021 22:10:12 GMT

DATA(test) =  VALUE _test_t(
      ( txt = 'AAA' )             
      ( id = 'BB'  txt = 'BBB' )        
                 ( txt = 'CCC' ) ).

I guess you are using the short form described in this Horst Keller Post, allowing you to fill columns with the same value in subsequent lines.

Re: Weird behaviour with VALUE and SWITCH

EnnoWulff — Mon, 08 Mar 2021 22:34:30 GMT

Thanks jacques.nomssi for this idea! I firstly thought of this. but afik my code exactly fills 3 lines. I might be wrong though.

Re: Weird behaviour with VALUE and SWITCH

thalesvb — Mon, 08 Mar 2021 22:49:08 GMT

I toyed with it (7.52 trial) and found something else. Code below, moving "id = 'No' " part between later lines and that tells a bit more.

DATA(test) =  VALUE _test_t(
      ( txt = 'AAA' )              "Value for ID deleted!
      ( SWITCH #( 'E'
         WHEN 'E' THEN VALUE #( id = 'BB'  txt = 'BBB' )
                  ELSE VALUE #( id = 'bb'  txt = 'bbb' ) ) )
      ( txt = 'CCC' )
      ( txt = 'DDD' )
      ( id = 'No' txt = 'EEE' )
      ( txt = 'FFF' ) ).

Kernel had a hangover with that switch, it looks like a bug.

Re: Weird behaviour with VALUE and SWITCH

joltdx — Tue, 09 Mar 2021 04:58:19 GMT

This is fun! 🙂

I don't think it has anything do to with SWITCH though. It's probably something with the VALUE operator itself, or nested VALUEs, or something... It's reproducible with this code:

DATA(test) =  VALUE _test_t( (                     txt = 'AAA' )
                             ( VALUE #( id = 'BB'  txt = 'BBB' ) )
                             (                     txt = 'CCC' ) ).

   AAA  
BB BBB  
BB CCC

I guess the inner VALUE leaks it's id out to the outer?

Removing the inner VALUE, and it works as expected:

DATA(test_line) = VALUE _test( id = 'BB'  txt = 'BBB' ).
DATA(test) = VALUE _test_t( ( txt = 'AAA' )
                            ( test_line )
                            ( txt = 'CCC' ) ).

    AAA  
BB  BBB  
    CCC

Oddly enough, as you also noted, setting the id on the first line or actually any line before the nested VALUE also works as expected:

DATA(test) = VALUE _test_t( (                    txt = 'AAA' )
                            (          id = 'BB' txt = 'BBB' )
                            ( VALUE #( id = 'CC' txt = 'CCC' ) )
                            (                    txt = 'DDD' ) ).

    AAA  
BB  BBB  
CC  CCC
    DDD

Maybe it's affecting the superstructure? Because this is valid, and expected:

DATA(test) = VALUE _test_t( (           txt = 'AAA' )
                            ( id = 'BB' txt = 'BBB' )
                              id = 'CC'
                            (           txt = 'DDD' )
                            (           txt = 'EEE' )
                              id = 'FF'
                            (           txt = 'GGG' ) ).

    AAA  
BB  BBB  
CC  DDD  
CC  EEE  
FF  GGG

Re: Weird behaviour with VALUE and SWITCH

FredericGirod — Tue, 09 Mar 2021 06:42:39 GMT

The last one is very interesting

Re: Weird behaviour with VALUE and SWITCH

joltdx — Tue, 09 Mar 2021 07:06:32 GMT

It is, and it's quite useful. It's the short form documented under Alternative 1 here.

It also states that it is allowed to use VALUE line_type( ) inside the VALUE...

Re: Weird behaviour with VALUE and SWITCH

joltdx — Tue, 09 Mar 2021 07:09:54 GMT

Hah, that line reset the functionality again to a working state... 🙂

Re: Weird behaviour with VALUE and SWITCH

EnnoWulff — Tue, 09 Mar 2021 08:28:17 GMT

Thanks jorgen_lindqvist41 for "eliminating" SWITCH from the construct and confirming that I am not completely mad... 😉

Re: Weird behaviour with VALUE and SWITCH

EnnoWulff — Tue, 09 Mar 2021 08:32:22 GMT

Thanks thalesvb for also proving it is a bug.

Re: Weird behaviour with VALUE and SWITCH

BiberM — Tue, 09 Mar 2021 08:38:17 GMT

That does exist but to achieve this shouldn't the id Part be OUTSIDE the line brackets (on table type Level)?

Re: Weird behaviour with VALUE and SWITCH

joltdx — Tue, 09 Mar 2021 08:40:07 GMT

I can only confirm that you are not madder than me, but anytime you need help with that, just ping me... 🙂

Re: Weird behaviour with VALUE and SWITCH

EnnoWulff — Tue, 09 Mar 2021 09:20:03 GMT

Thanks for your offer! 😉 Still unsure if I will have to open a defect or if horst.keller will suddenly breach in... :]

Re: Weird behaviour with VALUE and SWITCH

EnnoWulff — Tue, 09 Mar 2021 09:49:42 GMT

Hey michael.biber2! yes that's right. see example of jorgen_lindqvist41

Re: Weird behaviour with VALUE and SWITCH

Sandra_Rossi — Tue, 09 Mar 2021 10:52:30 GMT

I looked at the generated byte code. We can see that it uses one work area that it appends repeatedly to the table for each new line, and does automatically the CLEAR of each field that is to be reinitialized if a value was set in the previous line but not in the new line. But it forgets to do the CLEAR after the VALUE #( ... ) line (I took the simplified example of Jörgen).

Re: Weird behaviour with VALUE and SWITCH

EnnoWulff — Tue, 09 Mar 2021 11:31:13 GMT

The big question: Is it a bug or a feature?

Re: Weird behaviour with VALUE and SWITCH

Sandra_Rossi — Tue, 09 Mar 2021 12:17:09 GMT

I don't think it's a feature ! 😄

Re: Weird behaviour with VALUE and SWITCH

abo — Tue, 09 Mar 2021 12:49:52 GMT

That depends on the seniority of the bug 😉

Re: Weird behaviour with VALUE and SWITCH

matt — Tue, 09 Mar 2021 15:56:04 GMT

Looking at the byte code. I already had very high respect for your technical abilities, but now...

I agree - it's a bug.

Re: Weird behaviour with VALUE and SWITCH

Sandra_Rossi — Tue, 09 Mar 2021 16:35:59 GMT

Matthew Billingham Not so complex 😉 (TAPP = table append, iclr = clear, mvqw = quick move, STCK = obscure stacking function / first code indicates a variant and next arguments are memory address references)

iclr 04  0019            
STCK 05  0000            
STCK 07  001A            

iclr 03  001A            
MOVE FF  0229  001C  001B
TAPP 20  0352  0019  001A

mvqw 04  0200  0010  00A4
MOVE FF  0229  001C  001F
TAPP 20  0352  0019  001A

iclr 00  0022            
MOVE FF  0229  001C  0021
TAPP 20  0352  0019  001A
STCK 06  0000